Office: automatische mail an email senden

hallo liebe leute,
ich habe da mal ein kleines problem, ich möchte gerne das wenn ein wert (geb-datum)= datum ("heute") ist automatisch eine mail mit der dazu gehörigen zelle an eine mail addy versenden wird.
da ich neuling und abolut keine ahnung haben bin ich auf eure hilfe angewiesen.
1000 dank im voraus

 

Hallo excelloser,
so ein Problem kann nicht durch ein paar simple Formeln gelöst werden, sondern muss in VBA programmiert werden. Nachfolgend der VBA-Code einer abgespeckten Version, um eine mögliche Lösung zu demonstrieren:

Code:

Option Explicit

Public Sub EMail_ListenVersand()
  Dim Heute As Date
  Dim Zelle As Range, Liste As Range
  Dim EMailAdr$, Betreff$, EMailBlatt$, BodyTxt$
  Const olMailItem = 0
'
  Dim myOutlook As Object, MailItem As Object
  Set myOutlook = CreateObject("Outlook.Application")
  myOutlook.Session.Logon
'
  Heute = ActiveSheet.Cells(1, 1).Value   'Zelle A1: Heutedatum
  Set Liste = ActiveCell.CurrentRegion
'
  For Each Zelle In Liste.Columns(1).Cells
    With Zelle
      If .Value = Heute Then              'Spalte1: Datumskriterium
      
        EMailAdr$ = .Offset(0, 1).Value   'Spalte2: Adresse
        Betreff$ = .Offset(0, 2).Value    'Spalte3: Betreff
        EMailBlatt$ = .Offset(0, 3).Value 'Spalte4: Blattname für BodyText
        BodyTxt$ = GetBodyText(EMailBlatt$)
'
        Set MailItem = myOutlook.CreateItem(olMailItem)
        With MailItem
          .Subject = Betreff$
          .To = EMailAdr$
          .Body = BodyTxt$
          .Send
        End With
        Set MailItem = Nothing
 '
      End If
    End With
  Next Zelle
'
  myOutlook.Session.Logoff
  myOutlook.Quit
  Set myOutlook = Nothing
End Sub
Function GetBodyText(Blatt$) As String
  Dim Zl As Range, Sp As Range, BodyTxt$
  
  BodyTxt$ = ""
  For Each Zl In ActiveWorkbook.Worksheets(Blatt$).UsedRange.Rows
    For Each Sp In Zl.Columns
      BodyTxt$ = BodyTxt$ & Sp.Cells(1, 1).Value & vbTab
    Next Sp
    BodyTxt$ = BodyTxt$ & vbCrLf
  Next Zl
  GetBodyText = BodyTxt$
End Function

Voraussetzungen:Es muss Outlook auf dem PC installiert sein.
Prozedere:
1) Obigen VBA-Code mit der Maus selektieren, Strg+C drücken, nach EXCEL wechseln, Alt+F11 drücken (Aufruf des VBA-Code-Editors), im Menü 'Einfügen - Modul' klicken, um ein neues Programm-Modul-Fenster aufzurufen;
in dieses hineinklicken und die Tasten Strg+V drücken, um den kopierten Code einzufügen.
2) Aus den VBA-Editor in das Datenblatt1 wechseln.
3) Im Datenblatt1 in Zelle A1 das Heute-Datum eingeben (oder die Formel '=HEUTE()').
4) Unterhalb von Zelle A1 durch mindestens 1 Leerzeile getrennt den Bereich mit den E-Mail-Adressen wie folgt anlegen:
- in Spalte1: Datum; falls dieses Datum mit dem Datum in A1 übereinstimmt, wird das E-Mail aus dieser Zeile versandt;
- in Spalte2: die E-Mail-Adresse
- in Spalte3: eine Betreff-Angabe
- in Spalte4: der Name des Excel-Arbeitsblattes, in dem der Body-Text des E-Mails enthalten ist. Dadurch ist es möglich, dass mehreren E-Mails auf einfache Weise der gleiche Text zugeordnet wird und ferner kann man in den E-Mails mehrzeiligen Text unterbringen. Der Body-Text in den einzelnen Arbeitsblättern sollte hauptsächlich in Spalte A eingegeben werden; Text in Spalte B etc. wird jeweils durch ein Tabulatorzeichen getrennt; Text in verschieden Zeilen dagegen durch Cr-Lf-Zeichen (=Wagenrücklauf+Zeilenvorschub).
5) Das Ganze als EXCEL-Datei (Erweiterung '*.xlsm') speichern.
6) Start des E-Mail-Versandes:
Wurden vorgenannte Daten eingegeben, setzt man die aktive Zelle irgendwo in obigen 4-spaltigen Bereich, klickt in der Multifunktionsleiste auf 'Ansicht', Gruppe 'Makros' auf Schalter 'Makros' und selektiert in der Makroliste 'EMail_ListenVersand', klickt auf Schalter 'Ausführen', wartet solange, bis die Umrahmung für die aktive Zelle erscheint - dann müsste der E-Mail-Versand durchgeführt sein.

Gruß Exl121150

 

hallo Exl121150

vielen lieben dank für deine mühe konnte das leider noch nicht ausprobieren aber sowie ich zweit haben setze ich mich ran und probieren es.
denke mal hast mir da viel arbeit erspart

danke gruss marco