Office: (Office 2010) Automatische, sich selbst aktualisierende Auflistung mehrerer Tabellen

Hallo zusammen!

Ich habe folgendes Anliegen:

Ich habe eine Excel Datei mit insgesamt 16 verschiedenen Tabellenblättern. Alle Tabellenblätter sind gleich aufgebaut und auch die Kopfzeilen der Tabellen sind die gleichen.

Nun ist es mein Ziel auf einem 17. Tabellenblatt alle anderen 16 Tabellen untereinander aufzulisten. Das Problem besteht darin, dass die Tabellen fortlaufend weitergeführt werden. Das heißt ich weiß nicht wie lang die einzelnen Tabellen werden (dynamisch), möchte aber das auf dem 17 Tabellenblatt alle Daten untereinander aufgelistet werden (automatisch) um Dritten das Arbeiten mit der Datei einfach zu machen. Es besteht außerdem keine Redudanz, das bedeutet die Daten der einzelnen Tabellenblätter sind jeweils einmalig genannt.

Zum besseren Verständnis den Aufbau der Tabellen:

Spalte 1: Personal Nummer Spalte 2: Name Spalte 3: Vorname


Ich habe jetzt schon viele Stunden auf der Suche nach einer Lösung verbracht und bin mir zu 99% sicher, das eine Lösung mit den herkömlichen Tools von Excel nicht möglich scheint. Bezüglich VBA und Makros bin ich allerdings grün hinter den Ohren und werde dort wohl einige Male nachfragen müssen.

Ich hoffe die Community kann mir helfen!

LG Tim

 

Hi Tim,

sollen die Daten im zusammenfassenden Tabellenblatt nach Tabellenblättern geordnet untereinander aufgelistet werden oder z.B. aufsteigend sortiert nach Personal-Nummer? Was verstehst du unter "um Dritten das Arbeiten mit der Datei einfach zu machen" - sollen auf dem zusammenfassenden Tabellenblatt Daten zu den einzelnen Angaben ergänzt werden, die dann in den Einzelblättern ebenfalls erscheinen sollen? Oder sollen in den Einzelblättern Daten ergänzt werden, die dann auf dem zusammenfassenden Blatt angezeigt werden - ist das zusammenfassende Blatt also nur zur Übersicht gedacht? Weshalb benutzt du überhaupt 16 getrennte Tabellenblätter?

Du siehst, da gibt es noch eine ganze Reihe an Unklarheiten, die du erst einmal genauer erläutern müsstest. Hilfreich wäre vielleicht auch eine hochgeladene (anonymisierte) Beispielmappe.

Bis später,
Karin

 

Den Anhang 8670 betrachten

Hallo Karin,

entschuldige das ich so spät antworte, ich war den Monat nicht mehr im Lande. Vielen Dank für deine Antwort und ich ergänze hiermit meine Ausführungen.

Eine aufsteigende Sortierung nach Personalnummer wäre, wenn möglich, gar nicht schlecht aber nicht zwingend notwendig. Eine einfach Auflistung reicht. Auf dem zusammenfassenden Tabellenblatt sollen keine ergänzenden Angaben gemacht werden, sondern es soll lediglich die Auflistung der in den anderen Tabellenblättern vorhandenen Daten erfolgen. Genau so wenig sollen Daten automatisch auf den einzelnen Tabellenblättern ergänzt werden. Das zusammenfassenden Tabellenblatt dient lediglich zur Übersicht.
Die 16 einzelnen Tabellenblätter stehen jeweils für eine Abteilung, deshalb auch die Trennung. Die Frage nach Führungsintresse ist aber nicht auf eine Abteilung beschränkt.
Ich lade im Anhang eine Beispieldatei hoch und hoffe, dass du damit was anfangen kannst.

 

Hi,

Code:

Sub Zusammenfassung()
    Dim wksTab As Worksheet
    Dim wksZiel As Worksheet
    Dim lngZeile As Long
    Dim lngZiel As Long
    Dim rngStart As Range
    lngZiel = 2
    Set wksZiel = Worksheets("So soll es aussehen")
    For Each wksTab In Worksheets
        If InStr(wksTab.Name, "Abteilung") > 0 Then
            With wksTab
                Set rngStart = .Columns(4).Find("L & E Auffälligkeiten", lookat:=xlWhole)
                If Not rngStart Is Nothing Then
                    lngZeile = rngStart.Row + 2
                    If .Cells(lngZeile, 1) <> "" Then
                        Do
                            wksZiel.Cells(lngZiel, 1) = .Cells(lngZeile, 1)
                            wksZiel.Cells(lngZiel, 2) = .Cells(lngZeile, 2)
                            wksZiel.Cells(lngZiel, 3) = .Cells(lngZeile, 3)
                            wksZiel.Cells(lngZiel, 4) = .Cells(lngZeile, 6)
                            wksZiel.Cells(lngZiel, 5) = .Cells(lngZeile, 7)
                            lngZiel = lngZiel + 1
                            lngZeile = lngZeile + 1
                        Loop While .Cells(lngZeile, 1) <> ""
                    End If
                End If
            End With
        End If
    Next wksTab
End Sub

Bis später,
Karin

 

Hallo Karin,

in der Beispieldatei, die ich hochgeladen habe, ist das Makro nahezu perfekt. Es macht genau das was es soll.
Da ich leider nur sehr begrenzte VB Kenntnisse habe muss ich allerdings noch mal etwas fragen.
In der richtigen Datei sind die Abteilungen benannt. Das bedeutet sie heißen nicht Abteilung 1, Abteilung 2,...., Abteilung 16, sondern haben alle Namen. Ich weiß deshalb nicht genau, wie ich die Zeile If InStr(wksTab.Name, "Abteilung") > 0 Then umschreiben muss, damit das Makro in der richtigen Datei ordnungsgemäß arbeitet. Kannst du mir da vielleicht noch einen Hinweis geben.

Ich bedanke mich hier schon recht herzlich für deine Mühe!

Liebe Grüße
Tim

 

Hi Tim,

mit der Codezeile wird geprüft, ob der Tabellenname den Teilstring "Abteilung" enthält, und wenn das in der Originalmappe nicht der Fall ist weil die Namen völlig anders lauten, dann muss diese Codezeile geändert werden - das hast du richtig erkannt. Es gibt auch die Möglichkeit, ein Tabellenblatt mit einem bestimmten Namen einfach auszuschließen - das wäre bei dir das Tabellenblatt "So soll es Aussehen" (Name musst du selbstverständlich anpassen) und der Code müsste dann so lauten:

Code:

        If wksTab.Name <> "So soll es Aussehen" Then

Bis später,
Karin

 

Hi Karin,

funktioniert mit der Änderung auch in der richtigen Datei einwandfrei!
Eine letzte Frage habe ich noch.
Ist es möglich den Code so zu schreiben, dass, wenn in den Spalten "Interesse äußert sich durch" und "Einschätzung der Führungskraft" nichts steht, betroffene Mitarbeiter nicht mit aufgelistet werden?

Liebe Grüße
Tim

 

Hi Tim,

ergänze innerhalb der Do-Schleife noch eine Abfrage, ob beide Spalten einen Inhalt haben:

Code:

                        Do
                            [COLOR=#0000ff]If .Cells(lngZeile, 6) <> "" And .Cells(lngZeile, 7) <> "" Then[/COLOR]
                                wksZiel.Cells(lngZiel, 1) = .Cells(lngZeile, 1)
                                wksZiel.Cells(lngZiel, 2) = .Cells(lngZeile, 2)
                                wksZiel.Cells(lngZiel, 3) = .Cells(lngZeile, 3)
                                wksZiel.Cells(lngZiel, 4) = .Cells(lngZeile, 6)
                                wksZiel.Cells(lngZiel, 5) = .Cells(lngZeile, 7)
                                lngZiel = lngZiel + 1
                            [COLOR=#0000ff]End If[/COLOR]
                            lngZeile = lngZeile + 1
                        Loop While .Cells(lngZeile, 1) <> ""

Bis später,
Karin

 

Hi Karin,

es funktioniert jetzt alles genau wie es soll. Vielen vielen Dank für deine Mühe, ich hoffe ich lerne es auch noch so mit Excel umzugehen wie du!