Office: (Office 2013) Automatischer PDF Druck (VBA)

Helfe beim Thema Automatischer PDF Druck (VBA) in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen Vielleich kann mir ja jemand helfen, damit ich weniger Arbeit habe. :-) Im Arbeitsblatt einer Excel-Datei würde ich gern Folgendes... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Taad79, 16. Dezember 2015.

  1. Taad79 User

    Automatischer PDF Druck (VBA)


    Hallo zusammen

    Vielleich kann mir ja jemand helfen, damit ich weniger Arbeit habe. :-)

    Im Arbeitsblatt einer Excel-Datei würde ich gern Folgendes automatisieren:

    Alle Zeilen ausblenden, wo in dem Bereich D18:D60 ein x steht.
    Dann für den Bereich H1:O60 ein PDF erzeugen.
    Dieses soll in den Ordner abgelegt werden, der in Zelle A4 steht.
    Der Speichername des Dokuments soll sich aus den Zellen H10 und M5 zusammensetzen.

    Dies soll für alle Mandanten gemacht werden. Dazu muss jede einzelne Mandantennummer, die in dem Bereich Q1:AX1 stehen, nacheinander in die Zelle J12 kopiert werden.

    Bei einem Fehler, einem leeren Feld im Bereich Q1:AX1 oder einer Mandantennummer=0 soll kein PDF erzeugt werden, sondern der nächste Mandant genommen werden - bis alle durch sind.

    Jeder Loop beginnt mit dem Kopieren der Mandantennummer, dann Zeilen ausblenden, PDF erzeugen und speichern - next.

    Kann mir da jemand helfen? Überfordert definitiv meine Fähigkeiten.

    Danke und Gruss

    Taad
     
  2. Exl121150 Erfahrener User
    Hallo,

    kopiere folgendes VBA-Makro in ein allgemeines Codemodul:
    Code:
    Option Explicit
    
    Public Sub MandantenListe_Drucken()
      Dim Mandant As Range
      Dim KritZelle As Range, KritBereich As Range
      Dim PfadPDF As String, DateiPDF As String
      
      With ActiveSheet
      
        On Error GoTo NaechsterMandant
        Set KritBereich = .Range("D18:D60")
        
        'Für alle Mandanten im Mandantenbereich:
        For Each Mandant In .Range("Q1:AX1").Cells
          If Mandant.Value <> 0 Then
              'Für alle Mandanten, die nicht 0 oder leer sind:
              
              'Kopiere Mandantennummer:
              .Range("J12").Value = Mandant.Value
              
              'Blende alle Zeilen aus, die in KritBereich ein "x" haben;
              'alle anderen Zeilen blende (wieder) ein:
              For Each KritZelle In KritBereich.Cells
                With KritZelle
                  .EntireRow.Hidden = .Value = "x"
                End With
              Next KritZelle
              
              'Lege Druckbereich fest = Bereich, der in die PDF-Datei ausgegeben wird:
              .PageSetup.PrintArea = "$H$1:$O$60"
              
              'Ermittle Pfad der PDF-Datei - dieser MUSS existieren:
              PfadPDF = .Range("A4").Value
              If Right(PfadPDF, 1) <> "\" Then PfadPDF = PfadPDF & "\"
              'Ermittle den Dateinamen der PDF-Datei:
              DateiPDF = .Range("H10").Value & .Range("M5").Value
              'Erzeuge die PDF-Datei:
              .ExportAsFixedFormat Type:=xlTypePDF, Filename:=PfadPDF & DateiPDF, _
                   Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                   IgnorePrintAreas:=False, OpenAfterPublish:=False
          End If
    NaechsterMandant:
        Next Mandant
        
        'Blende alle Zeilen wieder ein, falls welche noch ausgeblendet sind:
        For Each KritZelle In KritBereich.Cells
          KritZelle.EntireRow.Hidden = False
        Next KritZelle
        
      End With 'ActiveSheet
      
    End Sub
    
     
    Exl121150, 19. Dezember 2015
    #2
  3. Taad79 User
    Danke! Hat super geklappt!

    LG, Taad
     
Thema:

Automatischer PDF Druck (VBA)

Die Seite wird geladen...
  1. Automatischer PDF Druck (VBA) - Similar Threads - Automatischer PDF Druck

  2. Power Point automatisch als Pdf speichern VBA

    in Microsoft Excel Hilfe
    Power Point automatisch als Pdf speichern VBA: Hallo Excel-Community, wir haben ein kleines VBA-Problem. Vielleicht kann uns ja jemand weiterhelfen. Folgendes Problem: Wir haben eine Excel-Datei die mit Power Point verknüpft ist. Das heißt,...
  3. Pivot mit verschieden Filtern automatisch als PDF speichern

    in Microsoft Excel Hilfe
    Pivot mit verschieden Filtern automatisch als PDF speichern: Hallo zusammen, ich hab hier in diesem Forum schon viele tolle und nützliche Tips gefunden. Dank dafür. Aktuell habe ich folgendes Problem. Ich habe eine Pivot-Tabelle, in der ich einen Filter...
  4. automatisch PDF erstellen, speichern und E-Mail versenden

    in Microsoft Excel Hilfe
    automatisch PDF erstellen, speichern und E-Mail versenden: Hallo an alle, ich führe in einer Excel-Datei (Excel 2016) Stundenkonten von Mitarbeitern. Um mir die monatliche Klickarbeit zu ersparen, habe ich angefangen, mich mit Makros zu beschäftigen. Ich...
  5. PDF-Druck mit automatischer Vergabe des Namens

    in Microsoft Excel Hilfe
    PDF-Druck mit automatischer Vergabe des Namens: Hallo alle zusammen, ich hab folgendes Problem: Ich habe in einer Arbeitsmappe eine ganze reihe von Arbeitsblätter die ich mittels VBA ausdrucken lassen will. Da die einzelnen Dokumente in...
  6. Excel beim Speichern automatisch PDF erzeugen/ersetzen

    in Microsoft Excel Hilfe
    Excel beim Speichern automatisch PDF erzeugen/ersetzen: Hallo zusammen, ich möchte, dass nach dem Ändern und Speichern einer Excel-Datei automatisch eine PDF, die in einem anderen Ordner liegt, erstellt/ersetzt wird. Eigentlich würde ich das gerne mit...
  7. PDF automatisch drucken

    in Microsoft Outlook Hilfe
    PDF automatisch drucken: Hallo zusammen, ich hab eine kleine Frage vielleicht kann mir einer von euch weiterhelfen. Ich bekomme auf Arbeit Mails bei denen ein Auftrag als PDF-Datei angehängt ist. Der wird...
  8. Excel bestimmte Tabellenblätter mittels Schaltfläche (VBA) drucken/ pdf drucken

    in Microsoft Excel Hilfe
    Excel bestimmte Tabellenblätter mittels Schaltfläche (VBA) drucken/ pdf drucken: Hallo zusammen, ich habe folgendes Problem und hoffe ihr könnt mir hierbei helfen. Ich möchte folgende Schaltflächen evtl. mit Steuerelement Toolbox und VBA generieren: 1. Tabellenblatt...
Schlagworte:

Users found this page by searching for:

  1. excel pdf drucken mithilfe von namensmanager

    ,
  2. pdf drucken excel makro

    ,
  3. excel vba drucken in pdf

    ,
  4. vba pdf drucken,
  5. excel makro pdf druck
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden