Office: (Office 365) Bedingte Formatierung mit Zeitersparnis erstellen?

Helfe beim Thema Bedingte Formatierung mit Zeitersparnis erstellen? in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo liebe Gemeinde, ich habe eine Frage bezüglich der "bedingten Formatierung". In meinem Kalender habe ich jeweils eine Spalte für meine Freundin... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von der-user, 21. November 2022.

  1. Bedingte Formatierung mit Zeitersparnis erstellen?


    Hallo liebe Gemeinde,

    ich habe eine Frage bezüglich der "bedingten Formatierung".

    In meinem Kalender habe ich jeweils eine Spalte für meine Freundin und mich. Neben der jeweiligen Spalte (Person 1 und Person 2) ist jeweils noch eine Spalte, um dort mittels Buchstabenkombination das jeweilige Feld und das dazugehörige Feld aus der Spalte Person farblich zu markieren. Dies mache ich in der Regel über die bedingte Formatierung. Ich möchte nun aber nicht für 4 verschiedene Farben in 48 Spalten die bedingte Formatierung mit der Formel à la [=$C5="DR"] eintippen für die verschiedenen Bereiche definieren.

    Gibt es eine intelligente / schnelle Variante die bedingte Formatierung in Abhängigkeit (siehe Bild Spalte C gehöhrt zu Spalte B und Spalte E gehört zu Spalte D) zu erzeugen?
     
    der-user, 21. November 2022
    #1
  2. RPP63_neu hat Ahnung
    Moin!
    So etwas (alle Tage des Jahres) schreibt man ja auch untereinander und filtert bei Bedarf den angezeigten Monat.
    Hilft auch bei Auswertungen ungemein!

    Gruß Ralf
     
    RPP63_neu, 21. November 2022
    #2
    1 Person gefällt das.
  3. Moin Ralf,
    danke für deine Antwort.
    Ja, die Darstellung des Kalenders habe ich aus geschmacklichen Gründen so gewählt, damit wir die Monate entsprechend im Zweifel auch ausdrucken können. Praktikabel für Excel ist es wohl nicht zu 100%.
    Aber dem Kommentar nach, ist die bedingte Formatierung wohl nicht so einfach möglich, oder? Ist wohl "fleißarbeit"... Bedingte Formatierung mit Zeitersparnis erstellen? :confused:

    Gruß Daniel
     
    der-user, 21. November 2022
    #3
  4. RPP63_neu hat Ahnung

    Bedingte Formatierung mit Zeitersparnis erstellen?

    Ich schrieb ja bereits:
    Dafür gibt es den Autofilter, der praktischerweise gleich einen Monatsfilter beinhaltet.
     
    RPP63_neu, 21. November 2022
    #4
    1 Person gefällt das.
  5. lupo1
    lupo1 Tutorial Guru
    Über =TEILERGEBNIS() kann man trotz Autofilter im Titel auch den Monat wiedergeben, wie es hier auf dem Foto ist. Sogar die Anzahl Arbeitstage des Monats kann man damit dorthin summieren.
     
    1 Person gefällt das.
  6. HKindler
    HKindler hat Ahnung
    Obwohl ich meinen Vorrednern recht gebe, verstehe ich dein Anliegen. Mangels Beispieldatei nur das prinzipielle Vorgehen: Du brauchst je Code bzw. Farbe zwei Bedingungen. Zunächst markierst du eine Zelle einer Person, z.B. B5. Jetzt legst du eine bed.Form. an. Diese bekommt die Formel =C5="CR". Damit legst du die Farbe fest, die erscheinen soll, wenn die rechte Nachbarzelle den Wert "CR" hat. Jetzt erweiterst du "Bezieht sich auf" auf alle Personen-Spalten (B:B;D:D;...) Dasselbe Spiel machst du mit C5. Auch hier lautet die Formel =C5="CR". Hier wird die Farbe festgelegt, wenn diese Zelle den Wert "CR" hat. Der Bezug wird nun auf alle Code-Zellen (C:C;E:E;...) erweitert.

    Wenn du eine gerade Zahl Spalten pro Monat hättest, also die 1.Person im Januar in Spalte B und im Februar in Spalte J und nicht I stehen würde, könnte man mit einer bed.Form arbeiten mit der Formel: =WENN(ISTUNGERADE(SPALTE());B5="CR";C5="CR")
     
    HKindler, 22. November 2022
    #6
    1 Person gefällt das.
  7. Exl121150 Erfahrener User
    Hallo,

    ich habe dir das Makro "BedingtePersonenformate()" geschrieben. Es fügt auf Basis deiner angeführten Buchstaben in den Codespalten die bedingten Formate für die Zellhintergrundfärbung ein. Da du sinniger Weise die Spaltenbuchstaben weggeblendet hast, weiß ich allerdings nicht genau, wie viele Spalten du pro Monat verwendest - ich bin von 8 Spalten ausgegangen (also Spalte A:H für Januar, Spalte I:P für Februar, usw.), d.h. dass die Spalte für die WE/FT-Codierung als versteckte/ausgeblendete 8. Monatsspalte enthalten ist.
    Außerdem habe ich die ärgerlichen Verbundzellen in den Monatsüberschriften entfernt und durch zentrierte Überschriften ersetzt.
    Das Makro sieht dann wie folgt aus:
    Code:
    'Ermittelt die bedingten Formatierungen Januar-Dezember
    'für Person1 bzw. Person2 auf Basis der Code-Spalten
    '
    Sub BedingtePersonenformate()
    '
        Dim xSp As String, rngMonat As Range
        Dim Sp As Integer, Mo As Integer
      
        Set rngMonat = Range("$B$5:$C$35,$D$5:$E$35") 'Bed.Bereiche für Januar
        For Mo = 1 To 12
          For Sp = 1 To 2
             With rngMonat.Areas(Sp)
                xSp = "$" & Split(Split(.Address, ":")(1), "$")(1) 'Spaltenbuchstaben aus Bereichadresse ermitteln
                With .FormatConditions
                  With .Add(Type:=xlExpression, Formula1:=FormelAnpassen("=ODER($C5='GT';$C5='U')", xSp))
                      .SetLastPriority
                      .Interior.Color = RGB(255, 192, 0)    'FF C0 00 - Orange
                      .StopIfTrue = False
                  End With
                  With .Add(Type:=xlExpression, Formula1:=FormelAnpassen("=ODER($C5='DR';$C5='A';$C5='SD')", xSp))
                      .SetLastPriority
                      .Interior.Color = RGB(0, 176, 240)    '00 B0 F0 - Blau
                      .StopIfTrue = False
                  End With
                  With .Add(Type:=xlExpression, Formula1:=FormelAnpassen("=($C5='P')", xSp))
                      .SetLastPriority
                      .Interior.Color = RGB(146, 208, 80)   '92 D0 50 - Grün
                      .StopIfTrue = False
                  End With
                  With .Add(Type:=xlExpression, Formula1:=FormelAnpassen("=($C5='O')", xSp))
                      .SetLastPriority
                      .Interior.Color = RGB(255, 255, 0)    'FF FF 00 - Gelb
                      .StopIfTrue = False
                  End With
                End With '.FormatConditions
             End With 'rngMonat.Areas(Sp)
          Next Sp
          Set rngMonat = rngMonat.Offset(0, 8) 'Bed.Bereiche für Februar, März, ...: "$J$5:$K$35,$L$5:$M$35", "$R$5:$S$35,$T$5:$U$35", ...
        Next Mo
    '
    End Sub
    '
    'Ersetzt in "Formel" die Hochkommas ' durch doppelte Anführungszeichen "",
    'Ersetzt in "Formel" die Spaltenbuchstaben $C durch einen neuen Spaltenbuchstaben Spalte
    '
    Private Function FormelAnpassen(Formel As String, Spalte As String) As String
       FormelAnpassen = Replace(Replace(Formel, "'", Chr$(34) & Chr$(34)), "$C", Spalte)
    End Function
    
     
    Exl121150, 22. November 2022
    #7
    1 Person gefällt das.
  8. Bedingte Formatierung mit Zeitersparnis erstellen?

    Hallo Exl121150,

    vielen Dank für deine Hilfe! Das ist fantastisch!!!!

    Sonnige Grüße
     
    der-user, 26. November 2022
    #8
  9. Ich musste deinen Code etwas anpassen, aber ansonsten funktioniert dieser wunderbar.
    Da ich von MS immer eine Warnung erhalten habe, wenn ich deine Datei geöffnet habe, habe ich den Code einfach kopiert. Auch wenn der Code in deiner Datei einwandfrei funktionierte, bedurfte es einer Anpassung, damit es auch in meiner Datei funktioniert. Ich musste bei der letzten Private Function ein "Chr$(34)" und das "&" entfernen, so dass der Code nun wie folgt ausschaut.
    Code:
    Private Function FormelAnpassen(Formel As String, Spalte As String) As String
       FormelAnpassen = Replace(Replace(Formel, "'", Chr$(34)), "$C", Spalte)
    End Function
    Damit auch die farbliche Anpassung an den Wochenenden bzw. Feiertage umgesetzt wird, habe ich jeweils noch die Prorität auf
    Code:
    .SetFirstPriority
    umgeschrieben.

    Nochmals vielen Dank!
     
    der-user, 3. Dezember 2022
    #9
  10. Exl121150 Erfahrener User
    Hallo,
    was die Funktion "FormelAnpassen(..)" betrifft, hast du natürlich recht. Ich bin hier auf die Heimtücke mit den Anführungszeichen hereingefallen.
    Ich wollte im Makro die Formelausdrücke übersichtlicher gestalten, denn sonst hätte ich überall dort, wo in den Formelausdrücken des Makros jetzt ein einzelnes Hochkomma steht, jeweils 2 Anführungszeichen setzen müssen,
    also statt FormelAnpassen("=ODER($C5='GT';$C5='U')", xSp)
    hätte ich schreiben müssen: FormelAnpassen("=ODER($C5=""GT"";$C5=""U"")", xSp)
    VBA hätte dann aus den je 2 Anführungszeichen ein einzelnes Anführungszeichen gemacht und hätte dieses dann im bedingten Format für Formeln gespeichert.
    Da ich die Formeln jedoch über VBA manipulierte und in die endgültige Gestalt brachte, hätte ich die einzelnen Hochkommas nur durch je 1 Anführungszeichen ersetzen dürfen - du hast meinen Irrtum dankenswerterweise richtig erkannt und auch korrekt berichtigt. - Danke.
     
    Exl121150, 3. Dezember 2022
    #10
  11. HKindler
    HKindler hat Ahnung
    Hi,

    kleiner Tipp: nimm irgendein anderes Zeichen, das in der Formel nicht vorkommt. Z.B. „#“.
    Das nimmst du während der ganzen Manipulationen am String. Ganz am Ende machst du dann ein String = Replace(String, "#", Chr(34))
     
    HKindler, 3. Dezember 2022
    #11
Thema:

Bedingte Formatierung mit Zeitersparnis erstellen?

Die Seite wird geladen...
  1. Bedingte Formatierung mit Zeitersparnis erstellen? - Similar Threads - Bedingte Formatierung Zeitersparnis

  2. Bedingte Formatierung funktioniert nicht

    in Microsoft Excel Hilfe
    Bedingte Formatierung funktioniert nicht: Hallo, ich habe eine Excel Datei erstellt und es funktioniert alles, bis auf eine bedingte Formatierung. Ich verstehe einfach nicht wieso. Habe in der Liste schon andere Formatierungen, die sehr...
  3. Externe Mails mit bedingter Formatierung farbig hervorheben

    in Microsoft Outlook Hilfe
    Externe Mails mit bedingter Formatierung farbig hervorheben: Hallo zusammen! Ich möchte externe Mails (also Mails von Versendern, die nicht von der Domain @geanvas.com kommen) in meinem Posteingang farbig hervorheben. Dazu habe ich in der bedingten...
  4. Bedingte Formatierung, Leere Zelle ab best. Zeit einfärben und bei Eintrag Farbe weg.

    in Microsoft Excel Hilfe
    Bedingte Formatierung, Leere Zelle ab best. Zeit einfärben und bei Eintrag Farbe weg.: Guten Tag, ich habe, eigentlich, ein simples Problem und bekomme einfach nicht die Funktion korrekt geschrieben. Ich würde gerne eine Bedingte Formatierung durchführen für eine Zelle, die Bezug...
  5. (Access) bedingte Formatierung im Textfeld funktioniert nicht

    in Microsoft Access Hilfe
    (Access) bedingte Formatierung im Textfeld funktioniert nicht: vier Felder werden beim Öffnen eines Formulars bedingt formatiert. Das funktioniert bei den Prozentfeldern (rote Schriftfarbe bei Wert<1, grüne Schriftfarbe bei Wert >=1). Bei den anderen Feldern...
  6. Bedingte Formatierung aktuelles Jahr Zelle Färben

    in Microsoft Excel Hilfe
    Bedingte Formatierung aktuelles Jahr Zelle Färben: Hallo zusammen, hoffe ihr könnt mir weiterhelfen. Habe eine Tabelle in der ich ein bestimmtes Datum eingetragen habe (z.B. 20.11.2023) und hätte gern das immer das Aktuelle Jahr Grün markiert ist....
  7. Bedingte Formatierung

    in Microsoft Excel Hilfe
    Bedingte Formatierung: Ich habe eine Zelle A1 mit einer bestimmten Formatierung F1 (Hintergrund blau, Schrift weiß, fett) Ich möchte die Zelle B1 genau wie Zelle A1 formatieren, wenn eine "1" in der Zelle B1 ist. Geht...
  8. Excel bedingte Formatierung - höchster und zweithöchster Wert

    in Microsoft Excel Hilfe
    Excel bedingte Formatierung - höchster und zweithöchster Wert: Hallo zusammen, ich habe eine Tabelle, in der soll der Höchte Wert farbig markiert werden, das ist ja kein Problem. Nun versuche ich jedoch folgendes: Wenn ( höchster Wert > zweithöchter Wert +...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden