Office: Benötige Hilfe bei Wenn-dann-sonst-Verschachtelung

Hallo Forum,

ich habe mich jetzt hier, nachdem ich zuvor schon reichlich gute Informationen aus diesem Board gezogen habe, hier in der Hoffnung auf Hilfe angemeldet.

Ich habe vor, einen Jahres-Schichtdienstkalender zu erstellen, und zwar ohne die Verwendung von Makros. Einen "ewigen" Kalender, der mir Datum und Wochentag automatisch anzeigt und bei dem man die Jahreszahl auf Knopfdruck ändern kann, habe ich bereits geschafft.

Es gibt insgesamt vier Schichten: Frühschicht, Spätschicht, Nachtschicht und frei. Es gibt auch vier Gruppen, so das jede Gruppe mit einer Schicht beschäftigt ist. Die Gruppen können ebenfalls auf Knopfdruck durchgeschaltet werden.

Ich habe auch schon eine Formel hinbekommen, die das ganze für mich ausrechnet und entsprechend die Schichten auf dem Kalender verteilt. Zumindest für jede Gruppe einzeln. Ich könnte also Problemlos vier Dateien erstellen (für jede Gruppe einen).

Ich möchte aber alles in einer Datei haben (eben zum Durchschalten).

So sieht meine Formel (für Gruppe 4) aus:

Code:

Gruppe 4:
=WENN($N$1=4;WENN(ODER(REST(C3;28)=0;REST(C3;28)=1;REST(C3;28)=2;REST(C3;28)=3;REST(C3;28)=25;REST(C3;28)=26;REST(C3;28)=27);"F";WENN(ODER(REST(C3;28)=6;REST(C3;28)=7;REST(C3;28)=8;REST(C3;28)=16;REST(C3;28)=17;REST(C3;28)=18;REST(C3;28)=19);"S";WENN(ODER(REST(C3;28)=9;REST(C3;28)=10;REST(C3;28)=11;REST(C3;28)=12;REST(C3;28)=20;REST(C3;28)=21;REST(C3;28)=22);"N";"-"))))

Kurze Erläuterung: in feld N1 steht die Gruppennummer. In Feld C3 steht das Datum, für welches die ausgerechnete Schicht gültig ist (die Formel steht also in Feld C4). Die 28 bei REST ist die Zahl der Schichten, nach dem 28ten Tag gehts wieder von vorn los.

Die Formel funktionert. Aber wenn ich diese Formel mit denen für die anderen verbinde, meckert Excel, ich würde zu viele Argumente verwenden.

Der Vollständigheit halber hier noch die restlichen Formeln:

Code:

Gruppe 1:
=wenn($N$1=1;WENN(ODER(REST(C3;28)=4;REST(C3;28)=5;REST(C3;28)=6;REST(C3;28)=7;REST(C3;28)=8;REST(C3;28)=9;REST(C3;28)=10);"F";WENN(ODER(REST(C3;28)=13;REST(C3;28)=14;REST(C3;28)=15;REST(C3;28)=23;REST(C3;28)=24;REST(C3;28)=25;REST(C3;28)=26);"S";WENN(ODER(REST(C3;28)=0;REST(C3;28)=1;REST(C3;28)=16;REST(C3;28)=17;REST(C3;28)=18;REST(C3;28)=19;REST(C3;28)=27);"N";"-"))))

Code:

Gruppe 2:
=wenn($N$1=2;WENN(ODER(REST(C3;28)=11;REST(C3;28)=12;REST(C3;28)=13;REST(C3;28)=14;REST(C3;28)=15;REST(C3;28)=16;REST(C3;28)=17);"F";WENN(ODER(REST(C3;28)=2;REST(C3;28)=3;REST(C3;28)=4;REST(C3;28)=5;REST(C3;28)=20;REST(C3;28)=21;REST(C3;28)=22);"S";WENN(ODER(REST(C3;28)=6;REST(C3;28)=7;REST(C3;28)=8;REST(C3;28)=23;REST(C3;28)=24;REST(C3;28)=25;REST(C3;28)=26);"N";"-"))))

Code:

Gruppe 3:
=wenn($N$1=3;WENN(ODER(REST(C3;28)=18;REST(C3;28)=19;REST(C3;28)=20;REST(C3;28)=21;REST(C3;28)=22;REST(C3;28)=23;REST(C3;28)=24);"F";WENN(ODER(REST(C3;28)=27;REST(C3;28)=0;REST(C3;28)=1;REST(C3;28)=9;REST(C3;28)=10;REST(C3;28)=11;REST(C3;28)=12);"S";WENN(ODER(REST(C3;28)=2;REST(C3;28)=3;REST(C3;28)=4;REST(C3;28)=5;REST(C3;28)=13;REST(C3;28)=14;REST(C3;28)=15);"N";"-"))))

Wäre echt super, wenn mir irgendjemand dabei helfen könnte. Hab schon ein paar Versuche mit =oder bzw. =und hinter mir, hat aber auch nicht richtig geklappt.

Vielen Dank im Voraus.

/edit: Mir fällt gerade noch ein, die Datei erstelle ich zwar mit Excel 2010, aber auf dem PC auf der Arbeit läuft nur Excel 2003, und dazu muss sie am Ende auch kompatibel sein.

 

Hallo,

da bei einer Verknüpfung der 4 Formeln die Limits von Excel überschritten sind, würde ich das Ganze mal über einen sinnvollen Plan gestalten. Hier mal drei Ansätze, einmal ohne Hilfstabellen, 2x mit:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1														4
2
3			23		-
4					-
5					-
6
7		1	2	3	4			1	2	3	4
8	N	0	7	14	21		0	N	-	S	F
9	N	1	8	15	22		1	N	-	S	F
10	-	2	9	16	23		2	-	S	N	F
11	-	3	10	17	24		3	-	S	N	F
12	F	4	11	18	25		4	F	S	N	-
13	F	5	12	19	26		5	F	S	N	-
14	F	6	13	20	27		6	F	N	-	S
15	F	7	14	21	0		7	F	N	-	S
16	F	8	15	22	1		8	F	N	-	S
17	F	9	16	23	2		9	F	-	S	N
18	F	10	17	24	3		10	F	-	S	N
19	-	11	18	25	4		11	-	F	S	N
20	-	12	19	26	5		12	-	F	S	N
21	S	13	20	27	6		13	S	F	N	-
22	S	14	21	0	7		14	S	F	N	-
23	S	15	22	1	8		15	S	F	N	-
24	N	16	23	2	9		16	N	F	-	S
25	N	17	24	3	10		17	N	F	-	S
26	N	18	25	4	11		18	N	-	F	S
27	N	19	26	5	12		19	N	-	F	S
28	-	20	27	6	13		20	-	S	F	N
29	-	21	0	7	14		21	-	S	F	N
30	-	22	1	8	15		22	-	S	F	N
31	S	23	2	9	16		23	S	N	F	-
32	S	24	3	10	17		24	S	N	F	-
33	S	25	4	11	18		25	S	N	-	F
34	S	26	5	12	19		26	S	N	-	F
35	N	27	6	13	20		27	N	-	S	F

Zelle	Formel
E3	=VERWEIS(REST(C3+28-(N1-1)*7;28);{0;1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21;22;23;24;25;26;27};{"N";"N";"-";"-";"F";"F";"F";"F";"F";"F";"F";"-";"-";"S";"S";"S";"N";"N";"N";"N";"-";"-";"-";"S";"S";"S";"S";"N"})
E4	=INDEX($H$9:$K$35;REST(C3;28)+1;N1)
E5	=INDEX(A8:A35;VERGLEICH(REST(C3;28);INDEX($B$8:$E$8;;N1):INDEX($B$35:$E$35;;N1);0))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Gruß

Edgar

 

Recht herzlichen Dank, ich habe es jetzt mit deiner E3-Formel gelöst. Da wäre ich im Leben nicht drauf gekommen, obwohl ich mir die Verweisfunktion bereits angeguckt hatte...