Office: Benutzerdefiniertes Anzeigen via VBA

Ich habe folgendes Problem.

Wenn ich in einem Makro eine Spalte benutzerdefiniert anzeigen möchte, dann funktioniert das via VBA Makro nur bedingt.

Code:

For i = 0 To 7
If leFrtag(Date + i) = 6 Then
hildat = (Date + i)
Exit For
End If
Next i
namfile = "<=" & hildat
'zpln2.Sheets(1).Rows("2:2").Select
'Selection.AutoFilter Field:=15, Criteria1:=namfile, Operator:=xlAnd
    
zpln2.Sheets(1).Range("O2").Select
    Selection.AutoFilter Field:=15, Criteria1:=namfile, Operator:= _
        xlAnd
Private Function leFrtag(str As Date) As Integer

    leFrtag = Weekday(str)
    'Debug.Print Switch(intWeekday = 1, "Sonntag", intWeekday = 2, _
        "Montag", intWeekday = 3, "Dienstag", intWeekday = 4, _
        "Mittwoch", intWeekday = 5, "Donnerstag", intWeekday = 6, _
        "Freitag", intWeekday = 7, "Samstag")
End Function

Der Fehler derzeit ist nun folgender. Via Makro wird soweit auch alles gesetzt, allerdings die Anzeige nicht richtig auf den veränderten Wert so angepasst, wie es eigentlich sein soll. Angezeigt wird dann einmal gar nichts mehr. Wenn ich im Debugmodus nach der Ausführung der Zeile in die Datei gehe und einfach nur benutzerdefiniert aufrufe und Enter drücke werden die Werte richtig angezeigt. Wie kann ich das richtig abändern, bzw. was mache ich da falsch??

 

Hallo,

die folgende SUB und die FUNCTION in ein und dasselbe allgem. Codemodul kopieren.
Ich habe nur die kritischen Stellen im Makro angepasst und mit Kommentaren versehen - den Rest habe ich unverändert belassen.

Code:

Public Sub NachDatum_Filtern()
  Dim I As Integer
  Dim NamFile As String
  Dim HilDat As Date
  
  For I = 0 To 7
    If leFrtag(Date + I) = 6 Then
      HilDat = (Date + I)
      Exit For
    End If
  Next I
  
  'HilDat muss offenbar ein Freitag sein
  
  'Filterkriterium (unbedingt USA-Datumsformat: MM/TT/JJJJ verwenden!!):
  NamFile = "<=" & Format(HilDat, "MM\/DD\/YYYY")
      
  'Filterung innerhalb der aktiven Arbeitsmappe im 1.Arbeitsblatt
  'Die Zelle O2 muss innerhalb einer Liste liegen
  'In der 15.Spalte dieser Liste wird ein Datumsfilter angewendet:
  'gefiltert (=angezeigt) werden Listenzeilen, deren Datumsangabe in ihrer 15.Spalte vor/bis HilDat liegt
  ActiveWorkbook.Sheets(1).Range("O2").AutoFilter Field:=15, Criteria1:=NamFile, Operator:=xlAnd
  
End Sub
Private Function leFrtag(str As Date) As Integer

    leFrtag = Weekday(str)
    'Um den Wochentag als Text auszugeben, genügt folgende Funktion:
    'Debug.Print Format(str, "DDDD")
    
End Function

 

Das war also der Schlüssel des Problems.

THX

Funktioniert nun wunderbar!