Office: (Office 365) Bereich kopieren und einfügen

Hallo zusammen,

Ich würde gerne, nachdem ich eine Pos. eingetragen habe (tabelle1) zeile 15 bis 46 mittels VPA den Bereich kopieren und in ein neues Blatt kopieren , danach löschen und dasselbe von vorne.

gibt es hier eine möglichkeit dies zu machen?

Vielen Dank

 

Hallo,

das müsstest du schon etwas präzisieren. Fertige Makros in dem Sinne gibt es nicht, das muss schon individuell angepasst werden.

 

Hi,

ich nehme an du meinst, dass die Zeilen bei jedem Kopiervorgang fortlaufend untereinander kopiert und nach dem Kopieren die Zeilen in der Originaltabelle gelöscht werden sollen?? Dann nach diesem Prinzip (Code gehört ins Codemodul des Tabellenblattes):

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim lngLetzte As Long
    If Target.Cells(1).Address(0, 0) = "A1" Then  '<== Adresse der Eingabezelle anpassen
        If Target <> "" Then
            With Worksheets("Tabelle2") '<== Name der Zieltabelle anpassen
                lngLetzte = IIf(IsEmpty(.Cells(Rows.Count, 1)), .Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
                Rows("15:46").Copy .Cells(lngLetzte + 1, 1)
                Rows("15:46").ClearContents
            End With
        End If
    End If
End Sub

Sobald in A1 etwas eingetragen wird, wird der Code gestartet. Es werden die Zeilen 15:46 nach Tabelle2 kopiert und an die bereits vorhandenen Zeilen unten angefügt. Anschließend werden die Zeilen in der Ausgangstabelle geleert.

---

[/parsehtml

 

Hallo,

Vielen Dank für diese tolle Lösung,
würde das statt A1 auch mit einem Button gehen?
Eine Frag hätt ich noch, ich würde gerne die Sachen kopieren aber rein nur die Zahlen?=

Vielen Dank

 

Hi,

weise dieses Makro der Schaltfläche zu:

Code:

Sub Kopieren()
    Dim lngLetzte As Long
    With Worksheets("Tabelle2") '<== Name der Zieltabelle anpassen
        lngLetzte = IIf(IsEmpty(.Cells(Rows.Count, 1)), .Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
        Rows("15:46").Copy  '<== Zeilen kopieren
        .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlValues  '<== Werte einfügen
        Rows("15:46").ClearContents
    End With
End Sub

Code gehört in ein Standardmodul, dann kannst du es einer Schaltfläche zuweisen.

---

 

Vielen Lieben Dank für die Hilfe/Durchführung.
Alles gute :)