Office: Beschleunigen von VBA Excel Schleife

Helfe beim Thema Beschleunigen von VBA Excel Schleife in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo, hiermit noch ein paar zehntel rausgekitzelt. Code: Sub Test_xlph() Dim c As Long, r As Long Dim first_c As Long, first_r As Long Dim... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von pippsen, 21. September 2014.

Seite 2 von 3

XLPH

xlph

Beschleunigen von VBA Excel Schleife

Hallo,

hiermit noch ein paar zehntel rausgekitzelt.

Code:

Sub Test_xlph()
Dim c As Long, r As Long
Dim first_c As Long, first_r As Long

Dim avarInput As Variant
Dim avarOutput As Variant

first_c = 4
first_r = 2

With ActiveSheet
With .Range("A1").CurrentRegion

ReDim avarOutput(1 To .Rows.Count - first_r + 1, 1 To .Columns.Count - first_c + 1)
avarInput = .Value

For c = first_c To UBound(avarInput, 2)
For r = first_r To UBound(avarInput, 1)
Select Case avarInput(1, c)
' Vergl. = Ende_1 >> 1
Case avarInput(r, 2): avarOutput(r - 1, c - 3) = 1
' Vergl. = Ende_2 >> 3
Case avarInput(r, 3): avarOutput(r - 1, c - 3) = 3
' Vergl. zw. Ende_1 und Ende_2 >> 2
Case avarInput(r, 2) To avarInput(r, 3): avarOutput(r - 1, c - 3) = 2
End Select
Next r
Next c
.Cells(first_r, first_c).Resize(UBound(avarOutput), UBound(avarOutput, 2)).Value = avarOutput
End With

End With

Erase avarInput
Erase avarOutput

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 25. September 2014

#16
PIPPSEN

pippsen

Hallo zusammen,

vielen Dank, der Code funktioniert super. Denke das ich das auch verstanden habe.
Nur eine Frage habe ich noch: Wie kann ich für "arBer(r, c) = 1" anstelle einer "1" eine bestimmte Farbe zuweisen?

Vielen Dank und Gruß

Andreas

pippsen, 25. September 2014

#17
MC SANTA

Mc Santa

Hallo,

über einen Array kannst du keine Farbe zuweisen. Du müsstest dann wieder die Zellen direkt bearbeiten und hast dadurch wieder einen langsameren Code.
Mein Vorschlag wäre es daher, die Farbe über eine bedingte Formatierung, abhängig von 1, 2 oder 3, in die Zelle zu bringen. Dann machst du dir nicht den soeben gewonnenen Performance-Vorteil wieder zunichte *Smilie

Hilft dir dieser Ansatz weiter?
VG

Mc Santa, 25. September 2014

#18
XLPH

xlph

Beschleunigen von VBA Excel Schleife

Hallo,

versuche es hiermit:

Code:

Sub Test_xlph()
Dim c As Long, r As Long
Dim first_c As Long, first_r As Long

Dim avarInput As Variant
Dim avarOutput As Variant

first_c = 4
first_r = 2

With ActiveSheet
With .Range("A1").CurrentRegion

Intersect(.Cells, .Offset(first_r - 1, first_c - 1)).Interior.ColorIndex = xlColorIndexNone

avarInput = .Value

For c = first_c To UBound(avarInput, 2)
For r = first_r To UBound(avarInput, 1)
Select Case avarInput(1, c)
' Ende_1 = Vergl. >> Grün
Case avarInput(r, 2): .Cells(r, c).Interior.Color = vbGreen
' Ende_2 = Vergl. >> Rot
Case avarInput(r, 3): .Cells(r, c).Interior.Color = vbRed
' Ende_3 = Vergl. >> Gelb
Case avarInput(r, 2) To avarInput(r, 3): .Cells(r, c).Interior.Color = vbYellow
End Select
Next r
Next c
End With
End With

Erase avarInput

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 25. September 2014

#19
PIPPSEN

pippsen

Hi,

bedingte Formatierung ist sicherlich ein Lösungsansatz aber sicher nicht ideal. Der Grund ist dafür das ich die Farbe aus einer anderen Zelle übernehmen möchte.

Naja, dann muß ich mal schauen wie ich das mache.

Viele Grüße

pippsen, 25. September 2014

#20
PIPPSEN

pippsen

Hallo,

wenn ich den Bereich verändern wöllte, was müsste ich ändern?
Meine erste Zelle die ich einfärben möchte ist R5. Dann sollte

"first_c = 4" = 18
"first_r = 2" = 5

richtig?

Mein Start1 steht in Spalte F, das Ende1 in Spalte N und das Ende2 in Spalte O.

Welche Variable müsste ich da anpassen?

Viele Grüße

pippsen, 25. September 2014

#21
XLPH

xlph

Hallo,

an wen ist die Frage gerichtet?

xlph, 26. September 2014

#22
PIPPSEN

pippsen

Beschleunigen von VBA Excel Schleife

Hallo xlph,

ans Forum aber ich denke du würdest mir diese Frage sicherlich am einfachsten beantworten können, oder? Wollte nicht so unfreundlich sein explizit nur dich anzusprechen.

Viele Grüße

pippsen, 26. September 2014

#23
XLPH

xlph

Hallo,

wollte nur sicher gehen, dass ich nicht für den Mülleimer arbeite bzw.
für das Internet-Nirvana.

Lad noch mal die Datei hoch (die sich im Endstadium befindet).

xlph, 26. September 2014

#24
PIPPSEN

pippsen

Hi xlph,

du arbeitest definitiv nicht für den Mülleimer und ich versuche auch selber den Code zu verstehen, damit ich diesen umsetzen kann.

Im Anhang die Datei mit dem Startdatum, dem Enddaatum1 und Enddatum2. Im Endeffekt soll die Farbe aus Spalte E die Farbe sein mit der ich auch die Zellen fülle. Dies kann ich aber schon auslesen und machen.

Vielen Dank für deine großartige Hilfe!

pippsen, 26. September 2014

#25
XLPH

xlph

Hallo,

so?

Code:

Sub xlph()

Dim rngKW As Range
Dim rngFaerbung As Range

Dim lngLetzteZeile As Long
Dim lngLetzteSpalte As Long

Dim lngZeile As Long
Dim lngFarbe As Long

Dim varFundSpalte_EndMT As Variant
Dim varFundSpalte_EndBZ As Variant

Const clngKWZeile As Long = 3
Const clngErsteZeile As Long = 5

Const clngWhoSpalte As Long = 5
Const clngEndMTSpalte As Long = 14
Const clngEndBZSpalte As Long = 15

Const clngErsteKWSpalte As Long = 18

With Tabelle2

' Falls Blatt leer, Prozedur verlassen
If WorksheetFunction.CountA(.Cells) = 0 Then Exit Sub

' Dimensionen der Tabelle ermitteln
lngLetzteZeile = .Cells.Find(What:="*", LookIn:=xlFormulas, LookAt:=xlWhole, _
SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
lngLetzteZeile = WorksheetFunction.Max(clngErsteZeile, lngLetzteZeile)

lngLetzteSpalte = .Cells.Find(What:="*", LookIn:=xlFormulas, LookAt:=xlWhole, _
SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
lngLetzteSpalte = WorksheetFunction.Max(clngErsteKWSpalte, lngLetzteSpalte)

' KW-ZellBereich ermitteln
Set rngKW = .Range(.Cells(clngKWZeile, clngErsteKWSpalte), .Cells(clngKWZeile, lngLetzteSpalte))

' Faerbungs-Bereich säubern
.Range(.Cells(clngErsteZeile, clngErsteKWSpalte), .Cells(lngLetzteZeile, lngLetzteSpalte)).Interior.ColorIndex = xlColorIndexNone

For lngZeile = clngErsteZeile To lngLetzteZeile

' Nach 'End MT' und 'End BZ' suchen
varFundSpalte_EndMT = Application.Match(CLng(.Cells(lngZeile, clngEndMTSpalte).Value), rngKW, 0)
varFundSpalte_EndBZ = Application.Match(CLng(.Cells(lngZeile, clngEndBZSpalte).Value), rngKW, 0)

' Bei Fund von beiden => Zellen färben
If IsNumeric(varFundSpalte_EndMT) Then
If IsNumeric(varFundSpalte_EndBZ) Then
Set rngFaerbung = .Range(.Cells(lngZeile, CLng(varFundSpalte_EndMT) + clngErsteKWSpalte - 1), _
.Cells(lngZeile, CLng(varFundSpalte_EndBZ) + clngErsteKWSpalte - 1))
rngFaerbung.Interior.Pattern = xlGray50
rngFaerbung.Interior.Color = .Cells(lngZeile, clngWhoSpalte).Interior.Color
Set rngFaerbung = Nothing
End If
End If

Next
End With

Set rngKW = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 26. September 2014

#26
PIPPSEN

pippsen

Hallo xlph,

erst einmal vielen Dank für deine Hilfe und sorry für das späte Feedback.

Ja, der Code passt fast. Einziges Problem ist, das die Zellen vom Start bis End MT in der in der Farbe von Spalte E eingefärbt werden sollen und die restlichen Tage bis EndBZ in der selben Farbe mit einem Muster darüber.

Ich versuche in deinen Code einzusteigen und dies selber anzupassen, würde mich aber bei Hilfe freuen.

Viele Grüße

pippsen, 29. September 2014

#27
PIPPSEN

pippsen

Beschleunigen von VBA Excel Schleife

von pippsen

Hallo xlph,

erst einmal vielen Dank für deine Hilfe und sorry für das späte Feedback.

Ja, der Code passt fast. Einziges Problem ist, das die Zellen vom Start bis End MT in der in der Farbe von Spalte E eingefärbt werden sollen und die restlichen Tage bis EndBZ in der selben Farbe mit einem Muster darüber.

Ich versuche in deinen Code einzusteigen und dies selber anzupassen, würde mich aber bei Hilfe freuen.

Viele Grüße
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...konnte den Code anpassen und es wird ohne Probleme der Status eingetragen.

Dabei ist mir aber ein neues Problem aufgefallen. Ich kopiere die Datumsspalten aus einer anderen Tabelle wo diese mit "Wenn"Formeln berechnet werden. Dabei kann es sein das eine Formel auch ein "" leer bringt. Aber selbst wenn ich nur die Werte der Formel kopiere, der Inhalt nur scheinbar leer. Wie kann ich dies abfangen?

Zuletzt von einem Moderator bearbeitet: 12. Januar 2021

pippsen, 30. September 2014

#28
XLPH

xlph

Hallo,

siehe Datei.

xlph, 30. September 2014

#29
PIPPSEN

pippsen

Hallo xlph,

DANKE für deine grandiose Hilfe. Kannst du mir erklären, wie du die leeren Zellen nicht beachtest?

Kann ich mit dem Befehl Code:

Tabelle2.Range("G5:G85").Value = Tabelle1.Range("A1:A81").Value
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

auch Formate wie Farben dem anderen Tabellenblatt zuweisen? Oder gehen nur Werte?

Viele Grüße

pippsen, 1. Oktober 2014

#30

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 2 von 3

Thema:

Beschleunigen von VBA Excel Schleife

Die Seite wird geladen...

Beschleunigen von VBA Excel Schleife - Similar Threads - Beschleunigen VBA Excel
Suchfunktion beschleunigen
in Microsoft Word Hilfe
Suchfunktion beschleunigen: Hallo, ich habe ein sehr großes Word-Dokument in dem ich sehr oft suche. Die Suche starte ich i.d.R. vom Anfang des Dokuments weil ich dann sehr häufig eine Fundstelle direkt im Inhaltsverzeichnis...
Word beschleunigen bei großen Dokumenten
in Microsoft Word Hilfe
Word beschleunigen bei großen Dokumenten: Hallo, obwohl ich einen recht schnellen Rechner mit 16 GB RAM habe, kommt Word 2019 bei einem sehr großen Dokument (500 S.) an seine Grenzen. Beispielsweise erscheinen die Buchstaben beim tippen...
Beschleunigung von Arrayformeln
in Microsoft Excel Hilfe
Beschleunigung von Arrayformeln: Hallo Community, ich habe eine Datei in Excel 2016 (dienstlich) erstellt, in der die Berechnungen vermutlich durch Nutzung von Arrayformeln sehr langsam durchgeführt werden. Privat nutze ich...
Beschleunigen des ROI mit Business Intelligence
in Microsoft Excel Tutorials
Beschleunigen des ROI mit Business Intelligence: Beschleunigen des ROI mit Business Intelligence Excel 2019 Excel 2016 Mehr... Weniger Die Analyse von...
Ladezeiten Webbrowsersteuerelement beschleunigen.
in Microsoft Access Hilfe
Ladezeiten Webbrowsersteuerelement beschleunigen.: Hallo , Und danke für die Aufnahme in dieses Forum. Nun zu meiner Frage. In einem Formular verwende ich ein Webbrowsersteuerelement um ein Pdf Dokument anzuzeigen. Der Pfad zu der Datei wird aus...
Beschleunigung einer Abfrage
in Microsoft Access Hilfe
Beschleunigung einer Abfrage: Hallo, ich habe eine Abfrage mit 10 Feldern - darunter 2, in denen mehrere Tabellenfelder zusammengefasst werden - und 3 Feldern mit je einer Bedingung. Zwei der Bedingungen sind einfach, z. B....
Ativitätensuche in Kontakt beschleunigen
in Microsoft Outlook Hilfe
Ativitätensuche in Kontakt beschleunigen: Ich verwende Outlook 2010 auf einem älteren Notebook. Habe ca. 6.000 Kontakte drinnen. Ich öffne einen Kontakt. Klicke im Ribbon auf "Aktivitäten" Wähle bei Anzeigen "E-Mail" Im Fenster wird...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden