Office: Besprechungseinladung von Excel nach Outlook

hi,
möchte aus einer Excel-Mappe einen Termin nach Outlook schieben, das funktioniert auch ganz gut.
Nun möchte ich (z.Bsp. aus Spalte 4) die Emailadresse für den Gast nutzen.
Bekomme dies aber nicht so recht hin.

Anbei der Script (hab mir hier schon Einiges zusammengeklickt)
:shock:
viele Dank vorab



Sub CommandButton1_Click()


Dim OutApp As Object, apptOutApp As Object

Range("A3").Select
'Beginn der Daten

Do Until ActiveCell.Value = ""


Set OutApp = CreateObject("Outlook.Application")
Set apptOutApp = OutApp.CreateItem(1)
With apptOutApp

.Start = Format(ActiveCell.Value, "dd.mm.yyyy") & " " & Format(ActiveCell.Offset(0, 3).Value, "hh:mm")
'Beginn des Termins, Datum und Uhrzeit in verschiedenen Zellen

.Subject = ActiveCell.Offset(0, 2)
'Betreff

.Duration = ActiveCell.Offset(0, 5)
'Dauer, in Minuten wenn fix

.body = "Sehr geehrter Geschäftspartner," & vbCrLf & vbCrLf & _
"dies ist ein Test" & vbCrLf & _
"wollen mal sehen ob´s klappt"

'Notizen

'Mailadresse


.Location = ActiveCell.Offset(0, 6)
'Ort des Termins
.Categories = "FH-Besuche"
'Kategorie zuschreiben
'.Categories = ActiveCell.Offset(0, x)


.ReminderSet = False
'Erinnerung setzen
.ReminderMinutesBeforeStart = 43200
'Anzahl Minuten, bei welcher die Erinnerung vor dem Termin erscheint
.ReminderPlaySound = True
'Wird Erinnerungston abgespielt


.Save

End With
ActiveCell.Offset(1, 0).Select
Set apptOutApp = Nothing
Set OutApp = Nothing

Loop

MsgBox "Termine erfolgreich an Outlook übertragen!"
'Dialogfenster nach erfolgreichem Ausführen

Cells(1, 7) = Date & " " & Time
'Trägt das letzte Übertragdatum in eine Zelle ein

End Sub

 

will denn keiner helfen?

 

Hallo,

zuerst eine Bemerkung zur Eigenschaft ".Start":

Das kann man offenbar so machen, weil anscheindend dieser String als Datum/Uhrzeit erkannt wird. Man kann's auch einfach machen:

Code:

.Start = ActiveCell.Value + ActiveCell.Offset(0,3).Value

Was Dein eigentliches Anliegen betrifft, bin ich mir nicht im Klaren, wo Du die E-Mail-Adresse platziert haben willst: in der .Location oder im .Body?
Angenommen, die Gast-E-Mail-Adresse befinde sich in Offset(0,1):
dann müsste die Angabe für die Location-Eigenschaft lauten:

Code:

.Location = ActiveCell.Offset(0,1).Hyperlinks(1).address

bzw. ähnlich für die .Body-Eigenschaft, wenn sie dort an den bereits bestehenden Body-Inhalt angehängt werden soll:

Code:

.Body = .Body & " " & ActiveCell.Offset(0,1).Hyperlinks(1).address

 

hi Exl121150,

besten Dank für Deine Hilfe.
Was ich meine:

Wenn man bei Outlook einne Termin plant, kann man hierfür Personen einladen (Button "Teilnehmer einladen"). Und genau hier will ich die Email-Adresse aus z.Bsp. Zelle 0,4 einfügen.

Geht das? Mit Deinen Beispielen leider nicht :cry:

Und weißt Du auch wie man die Beschriftung ändert (geschäftlich blau, privat grün, etc.)

 

Hallo,

wenn ich's genauer mitgeteilt bekommen hätte:
in diesem Fall die Add-Methode der .Recipients-Eigenschaft verwenden, also:

Code:

.Recipients.Add ActiveCell.Offset(0,1).Hyperlinks(1).Address

(ausgehend von meinen Annahmen im letzten Posting).

Die ".Recipients.Add AdressString" sooft ausführen als Empfänger (=Teilnehmer) vorhanden sind.

Dabei verträgt lt. Microsoft-Hilfe der "AdressString" folgenden Inhalt:

 

cool & 1000Dank :lol:

jetzt muß ich noch rausbekommen, wie Outlook die Einladung selbständig versendet...

 

hab es mit dem automatischen Senden sein gelassen, dafür .Display eingesetzt.

Bin noch auf der Suche :roll: nach Ändern der Kalenderbeschriftung in Outlook via VBA, ich denke ein paar Feinheiten gibt es bestimmt noch.
Falls euch was einfällt - nur zu ;-)
Das fertige VBA sieht nun so aus:

Sub CommandButton1_Click()


Dim OutApp As Object, apptOutApp As Object

Range("A3").Select
'Beginn der Daten

Do Until ActiveCell.Value = ""


Set OutApp = CreateObject("Outlook.Application")
Set apptOutApp = OutApp.CreateItem(1)
With apptOutApp

.Start = Format(ActiveCell.Value, "dd.mm.yyyy") & " " & Format(ActiveCell.Offset(0, 3).Value, "hh:mm")
'Beginn des Termins, Datum und Uhrzeit in verschiedenen Zellen

.End = Format(ActiveCell.Value, "dd.mm.yyyy") & " " & Format(ActiveCell.Offset(1, 3).Value, "hh:mm")
'Ende des Termins

.Subject = ActiveCell.Offset(0, 2)
'Betreff

'.Duration = ActiveCell.Offset(0, 5)
'Dauer, in Minuten wenn fix



.Body = "Sehr geehrter Geschäftspartner," & vbCrLf & vbCrLf & _
"dies ist ein Test" & vbCrLf & _
"wollen mal sehen ob´s klappt"

'Notizen


.RequiredAttendees = ActiveCell.Offset(0, 4)
'Mailadresse

.Location = ActiveCell.Offset(0, 6)
'Ort des Termins

.Categories = "FH-Besuche"
'Kategorie zuschreiben
'.Categories = ActiveCell.Offset(0, x)


.ReminderSet = False
'Erinnerung setzen
.ReminderMinutesBeforeStart = 43200
'Anzahl Minuten, bei welcher die Erinnerung vor dem Termin erscheint
.ReminderPlaySound = True
'Wird Erinnerungston abgespielt


.Save

.Display
'Termin öffnen in Outlook


End With
ActiveCell.Offset(1, 0).Select
Set apptOutApp = Nothing
Set OutApp = Nothing

Loop

' MsgBox "Termine erfolgreich an Outlook übertragen!"
'Dialogfenster nach erfolgreichem Ausführen

Cells(1, 7) = Date & " " & Time
'Trägt das letzte Übertragdatum in eine Zelle ein

End Sub

 

Hallo,

o.a. Lösung habe ich bei mir auch erfolgreich ausprobiert.
Einen Erweiterungswunsch hätte ich aber noch.
In der Zelle mit den "Attendees" sind mehrere Adressaten durch Semikolon getrennt angegeben. U.a. auch ein bei uns in der Firma gebräuchlicher allgemeiner Postkorb (d.h., mehrere Personen können dort Mails und Kalendereinträge erstellen, bearbeiten, abschicken etc.).
Es werden jedoch nur für den ersten Attendee Einträge erzeugt.
Geht das nur für einen Empfänger oder welche Möglichkeit gibt es da ?

Danke
Gruss
skipper

 

Hallo!

In der Outlook-VBA-Hilfe ist Folgendes zu lesen:

woraus folgt, dass die Attendees in der Recipients-Auflistung anzufügen sind und zwar mit der .Add-Methode und mit .Type-Eigenschaft kann ihr Typ spezifiziert werden. Um das zu verdeutlichen, sei folgendes Code-Beispiel aus der Outlook-VBA-Hilfe angeführt:

Code:

	Dim myOlApp As New Outlook.Application
	Dim myItem as Outlook.AppointmentItem
	Dim myRequiredAttendee As Outlook.Recipient
	Dim myOptionalAttendee As Outlook.Recipient
	Dim myResourceAttendee As Outlook.Recipient
	
	Set myItem = myOlApp.CreateItem(olAppointmentItem)
	myItem.MeetingStatus = olMeeting
	myItem.Subject = "Strategy Meeting"
	myItem.Location = "Conference Room B"
	myItem.Start = #9/24/2003 1:30:00 PM#
	myItem.Duration = 90
	Set myRequiredAttendee = myItem.Recipients.Add "Nate Sun"
	myRequiredAttendee.Type = olRequired
	Set myOptionalAttendee = myItem.Recipients.Add "Kevin Kennedy"
	myOptionalAttendee.Type = olOptional
	Set myResourceAttendee = myItem.Recipients.Add"Conference Room B"
	myResourceAttendee.Type = olResource
	myItem.Send

Zum vorstehenden Code sei angemerkt: Damit er funktioniert, muss über VBA-Menü > Extras > Verweise... > Verfügbare Verweise
die "Microsoft Outlook XX.0 Object Library" als verfügbar angehakt sein!!

 

also dann über .OptionalAttendees = ActiveCell.Offset(Zelle)

Gibt es eine Übersicht über die Outlook VBA Objekte?

 

Hallo,

1) in Outlook die Tastenkombination Alt+F11 drücken, um in den VBA-Editor zu gelangen
2) dann die Funktionstaste F2 drücken (bzw. VBA-Menü > Ansicht > Objektkatalog), um den Objektkatalog anzuzeigen
3) In der linken oberen Ecke des Objektkataloges gibt es 2 Comboboxen, wobei Du in der oberen der beiden die Auswahl "Outlook" triffst
4) Daraufhin wird Dir im Fenster darunter eine 2-geteilte Liste links mit den Klassen und rechts mit den jeweils dazugehörigen Elementen (Eigenschaften, Methoden, Ereignisse, Aufzählungen, etc.) angezeigt.
5) Bei Auswahl eines Elementes (im rechten Teilfenster) und Drücken der F1-Taste wird die dazugehörige Microsoft-Hilfe angezeigt.

Vorgenanntes Prozedere funktioniert in allen Microsoft-Office-Programmen völlig gleich. Es gibt somit hier Information ohne Ende.

Über VBA-Menü > Ansicht kann man noch weitere Fenster einblenden (Projekt, Eigenschaften, Code, Direktbereich, etc.)