Office: (Office 2003) Bestelldaten in Arbeitsmappe Stammdaten übernehmen

Hallo,
Bitte um VBA Hilfe,

Aus der Arbeitsmappe Bestelldaten.xls (variabler Dateiname) soll der markierte Bereich mit dynamischer Zeilenlänge
in die Arbeitsmappe Stammdaten.xls an das Ende der Datenbank via VBA angefügt werden.

Beispiel Dateien liegen bei

Vielen Dank für die Hilfe
Gruß Derhard

 

Hallo zusammen,
kann niemand helfen?

Gruß Derhard

 

Hallo

eine Möglichkeit

zu starten aus der Datei "Bestelldaten"

Code:

Sub test()
    Dim lngZiel As Long
    Range("A2:F8").Copy
'   Pfad anpassen
    Workbooks.Open Filename:="C:\Users\Tom\Downloads\Stammdaten.xls"
    With Workbooks("Stammdaten.xls").Sheets("Tabelle1")
        lngZiel = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("A" & lngZiel).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    End With
    Application.CutCopyMode = False
    Workbooks("Stammdaten.xls").Close True
End Sub

MfG Tom

 

Hallo Tom,
Vielen Dank für deine Hilfe!
Dein Makro für die Bestelldaten von A2:F8 wie im Beispiel funktioniert soweit.
Aber der Bestellbereich hat immer eine dynamische Zeilenlänge!!
D.h. der kann auch mal von A2: F50 oder oder liegen!

Wie müsste dann das Makro auf einen dynamische Datengröße optimiert werden???

Gruß Derhard

 

Hallo

in der Annahme dass es keine leeren Zellen in dem Bereich gibt

Code:

Sub test()
    Dim lngZiel As Long
    Dim lngLetzte As Long
    lngLetzte = Cells(Rows.Count, "F").End(xlUp).Row
    Range("A2:F" & lngLetzte).Copy
'   Pfad anpassen
    Workbooks.Open Filename:="C:\Users\Tom\Downloads\Stammdaten.xls"
    With Workbooks("Stammdaten.xls").Sheets("Tabelle1")
        lngZiel = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("A" & lngZiel).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    End With
    Application.CutCopyMode = False
    Workbooks("Stammdaten.xls").Close True
End Sub

MfG Tom

 

Hallo Tom,
Vielen Vielen Dank für Deine Hilfe!

Jetzt ist es super!

Gruß Derhard