Office: Bestimmte Bereiche markieren und kopieren

hugobär · 30. Januar 2010

Hi,

ich will, dass der User über eine InputBox eingeben kann, welcher Bereich einer Tabelle in ein neues Tabellenblatt kopiert werden soll. Bei den Spalten soll nur zwischen Spalte D, E und F gewählt werden können. Die Spalten B, N und O sollen immer ab der eingegebenen Zeile kopiert werden.
Wenn z.B. Zeile 20 und Spalte 5 eingegeben wird, dann sollen die Daten ab B20, E20, N20 und O20 in ein neues Tabellenblatt kopiert werden. Dabei sollen die Werte ab B20 in Spalte A, E20 in Spalte B, N20 in Spalte C und O20 in Spalte D kopiert werden.
Wie geht das?
Ich habs mal so versucht, aber weiter komme ich nicht. Kann mir bitte jemand weiterhelfen und eventuell den Code ein bisschen ausbauen?

Code:

Sub kopieren()
Dim spalte As Integer
Dim zeile As Integer
Dim Startzelle As Integer

spalte = InputBox("Spalten-Nr. eingeben!", "Spalten-Nr.", "1")
zeile = InputBox("Zeilen-Nr. eingeben!", "Zeilen-Nr.", "1")
Startzelle = Cells(zeile, spalte).Activate

Range(Range("B" & zeile), Range("B" & zeile).End(xlDown)).Copy
Range(Range("N" & zeile), Range("N" & zeile).End(xlDown)).Copy
Range(Range("O" & zeile), Range("O" & zeile).End(xlDown)).Copy
Range(Range(Startzelle), Range(Startzelle).End(xlDown)).Copy

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

jinx · 1. Februar 2010

Moin, hugobär,

versuch´s mal so:

Code:

Sub kopieren()
Dim spalte As Integer
Dim zeile As Integer
Dim wsActive As Worksheet
Dim wsNew As Worksheet
' Dim Startzelle As Integer 'müsste als Range dimensioniert und "ge"Set"tet" werden

spalte = Application.InputBox(prompt:="Spalten-Nr. eingeben!", Title:="Spalten-Nr.", Default:=1, Type:=1)
If spalte = 0 Then Exit Sub
zeile = Application.InputBox(prompt:="Zeilen-Nr. eingeben!", Title:="Zeilen-Nr.", Default:=1, Type:=1)
If zeile = 0 Then Exit Sub

Set wsActive = ActiveSheet
Set wsNew = Worksheets.Add(after:=Worksheets(Worksheets.Count))
With wsActive
.Range(.Range("B" & zeile), .Range("B" & zeile).End(xlDown)).Copy Destination:=wsNew.Range("A1")
.Range(.Range("N" & zeile), .Range("N" & zeile).End(xlDown)).Copy Destination:=wsNew.Range("B1")
.Range(.Range("O" & zeile), .Range("O" & zeile).End(xlDown)).Copy Destination:=wsNew.Range("C1")
.Range(.Cells(zeile, spalte), .Cells(zeile, spalte).End(xlDown)).Copy Destination:=wsNew.Range("D1")
End With

Set wsNew = Nothing
Set wsActive = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

hugobär · 1. Februar 2010

Wow, das ging ja schnell *boah Und das ist genau das was ich brauche!!!
Vielen Dank!

Office: Bestimmte Bereiche markieren und kopieren

Bestimmte Bereiche markieren und kopieren

Bestimmte Bereiche markieren und kopieren

Bestimmte Bereiche markieren und kopieren - Similar Threads - Bestimmte Bereiche markieren

Nur markierte Zellen kopieren und wieder einfügen

Per Makro bestimmten Bereich per PDF unter bestimmten Pfad speichern.

Bedingte Formatierung für einen bestimmten Bereich

Prüfung ob Wert in Spalte mit Wert aus bestimmtem Bereich übereinstimmt

Auswählen bestimmter Zellen oder Bereiche

Subtraktion des niedrigsten Wertes vom höchsten Wert aus einem bestimmten Bereich

Summieren in bestimmten Bereichen