Office: (Office 2007) Bestimmte Werte aus Spalte darstellen mit Bedingung

Hallo meine Lieblings-Excel-Freunde :)

Eine neue kleine Aufgabe:

Ich hätte gerne in Spalte D alle Nummern aufgelistet, die zu Firma A gehören.
Das muss iwas mit ner Array Formel sein, wo in Zeile 1 erst der erste Werte ausgegeben wird und darunter dann der Rest..
Hab schon verschiedenes ausprobiert, aber irgendwie komm ich da nicht weiter

Viele Grüße
Robbi Rob

 

Hola,

als Matrixformel:

Code:

=WENNFEHLER(INDEX($B$2:$B$10;KKLEINSTE(WENN($A$2:$A$10="a";ZEILE($2:$10)-1);ZEILE(A1)));"")

Gruß,
steve1da

 

Mmh... wenn ich die Formel aber runterziehe, bleiben die anderen Felder leer.
Als Array funktioniert es dann allerdings ;)
Danke!

 

Hola,

deshalb schrieb ich "als Matrixformel" ,-)

Gruß,
steve1da

 

Ähm, aber Array ist doch MIT den geschweiften Klammern und Matrix OHNE?
Also wenn ich es dann als Matrixformel runterziehe, zeigt er mir nur die erste Zeile an.
Als Array (mit geschweiften Klammern) funktioniert es über alle.

{=WENNFEHLER(INDEX($B$2:$B$10;KKLEINSTE(WENN($A$2:$A$10="a";ZEILE($2:$10)-1);ZEILE(A1)));"")}

 

Hola,

ich nenne es Matrixformel, es heißt aber auch Array-Formel. Sogar Microsoft gibt beide Namen an ;-)

https://support.office.com/de-de/ar...ayformel-e43e12e0-afc6-4a12-bc7f-48361075954d
Von daher, alles gut ;-)

Gruß,
steve1da

 

Na gut, wenn sogar Microsoft das sagt...

Ich versuche jetzt seit gestern deine Formel in meine Tabelle(n) zu übernehmen und ich fühle mich grad echt dumm..
Was mache ich falsch??
In Tabelle 1 stehen halt die Daten und in 2 möchte ich die Auswertung haben.

Das Witzige ist, eben hatte ich noch 5 x den gleichen Wert hintereinander stehen und seitdem ich die Tabellen etwas umformatiert habe, steht dort gar nichts mehr drin.. bzw. vielleicht n Fehler (der ja ausgeblendet wird).
Hilfe??

Den Anhang Tabelle1.xlsx betrachten Den Anhang Tabelle2.xlsx betrachten

Viele Grüße
RobbiRob

 

Hola,

die Bereiche müssen gleich groß sein.

Code:

=WENNFEHLER(INDEX([Tabelle2.xlsx]Tabelle1!$N$2:$N$38;KKLEINSTE(WENN([Tabelle2.xlsx]Tabelle1!$K$2:$K$38=$A$1;ZEILE($2:$38)-1);ZEILE(A1)));"")

Gruß,
steve1da

 

Also wenn ich deine Formel bei mir so ins Beispiel eintrage, dann listet er zwar alle Nummern auf, aber lässt die doppelten trotzdem drin

 

Hola,

von doppelten war doch bislang nie die Rede.
Ersetze Zeile(A1) durch

zählenwenn($A$A1:A1;A1)

Gruß,
steve1da

 

Stimmt.., das hätte ich mal erwähnen können.. :D
Sorry

Die eingegebene Formel enthält einen Fehler?
(als Matrix versucht abzuschließen)

=WENNFEHLER(INDEX([Tabelle2.xlsx]Tabelle1!$N$2:$N$38;KKLEINSTE(WENN([Tabelle2.xlsx]Tabelle1!$K$2:$K$38=$A$1;ZEILE($2:$38)-1);zählenwenn($A$A1:A1;A1))));"")

 

Hola,

sorry, mein Fehler. Das wird so nicht hinhauen.
Ich denk mir was neues aus.

Gruß,
steve1da

 

Hola,

in Tabelle 2 als Hilfsspalte, z.B. ab R2):

Code:

=ZÄHLENWENNS($K$2:K2;K2;$N$2:N2;N2)

Diese Formel nach unten ziehen. Dann in Tabelle1, A2:

Code:

=WENNFEHLER(INDEX([Tabelle2.xlsx]Tabelle1!$N$2:$N$38;KKLEINSTE(WENN(([Tabelle2.xlsx]Tabelle1!$K$2:$K$38=A$1)*([Tabelle2.xlsx]Tabelle1!$R$2:$R$38=1);ZEILE($2:$38)-1);ZEILE(A1)));"")

Die Formel nach rechts und nach unten ziehen.

Gruß,
steve1da

 

Hallo,

ich würde es so lösen:

Arbeitsblatt mit dem Namen 'Tabelle1'
*	K	N	O
1	Firma	Nummer	*
2	Firma B	T03BP	1
3	Firma B	T036S	1
4	Firma B	T036S	2
5	Firma C	PKTE2	1
6	Firma C	PKTE2	2
7	Firma B	T036S	3
8	Firma D	T03VO	1

Zelle	Formel
O2	=ZÄHLENWENNS($K$1:K2;K2;$N$1:N2;N2)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Daten'
*	A	B	C
1	Firma A	Firma B	Firma C
2	PKKI2	T03BP	PKTE2
3	*	T036S	PKCTM
4	*	*	T036S
5	*	*	*
6	*	*	*

Zelle	Formel
A2	=WENNFEHLER(INDEX([Tabelle2.xlsx]Tabelle1!$N$2:$N$40;AGGREGAT(15;6;ZEILE([Tabelle2.xlsx]Tabelle1!$K2:$K$40)/([Tabelle2.xlsx]Tabelle1!$K$2:$K$40=A$1)/([Tabelle2.xlsx]Tabelle1!$O$2:$O$40=1);ZEILE(A1))-1);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Ganz übersehen, geht ja in 2007 nicht!

 

@steve1da: Alles klar, das funktioniert (als Matrix). Vielen Dank!

@BoskoBiati: trotzdem auch danke fürs probieren, leider hab ich nur die 2007 Version hier zur Verfügung.
Beruht sich dein Name eigentlich auf den Kartentrick? ;) (...kennt alles)