Office: (Office 365) Bild löschen auch wenn es nicht vorhanden ist?! Code funktioniert nicht mehr..

Hallo Leute,

Habe ein Macro in Benutzung das jetzt über Monate gut funktioniert hat und jetzt kam anscheint ein update und es funktioniert nicht mehr,

wobei ich es mir nicht erklären kann, weil es an einem anderen PC mit der gleichen Office 365 Version immer noch funktioniert.

Aber vielleicht hat ja wer eine Idee wie ich das funktionierender umstellen könnte wenn es hier wohl kompatibelitätsprobleme gibt.
Also fakt ist in dem Sheet „Original Values“ können Bilder sein, _P1_, _P2_, ... aber es kann auch sein das keine drin sind, deshalb hatte ich das Macro einfach so geschrieben und es lief auch ewig..
Jetzt bekomme ich einen Run-time 1004, item with specified name wasn’t found..
Hab auch jetzt schon stunden drum herum gegoogelt, aber nichts gefunden..

Vielleicht hat hier ja einer eine Idee, das wäre mega..

Vielen Dank,

Lizz

Code:

Private Sub RemovePictures()

    On Error Resume Next

    Sheets("Original Values").Select
    Range("A1").Select

    ActiveSheet.Shapes.Range(Array("_P1_")).Delete
    ActiveSheet.Shapes.Range(Array("_P2_")).Delete
    ActiveSheet.Shapes.Range(Array("_P3_")).Delete
    ActiveSheet.Shapes.Range(Array("_P4_")).Delete
    ActiveSheet.Shapes.Range(Array("_P5_")).Delete
    ActiveSheet.Shapes.Range(Array("_P6_")).Delete

    Range("A1").Select

    On Error GoTo 0  

End Sub

 

Hi Lizz,

so sollte kein Fehler auftreten, weil die Bilder nur dann gelöscht werden können wenn sie auch tatsächlich vorhanden sind:

Code:

Private Sub RemovePictures()
    Dim shaShape As Shape
    With Sheets("Original Values")
        For Each shaShape In .Shapes
            Select Case shaShape.Name
                Case "_P1_", "_P2_", "_P3_", "_P4_", "_P5_", "_P6_"
                    shaShape.Delete
            End Select
        Next shaShape
    End With
End Sub

---

 

Super, das klappt wie ne 1.. den code kann ich sicher gut noch gebrauchen :)

 

Hi Karin,
die Idee Select Case als Alternative zu einem Rudel On error resume next zu nutzen, finde ich ziemlich genial.
Danke dafür!
Schöne Grüße

 

Hi Karin,
ich habe Deine Idee noch mal etwas weitergedacht und hier ein Snippet eingestellt, mit dem man die Shapes noch einfacher löschen kann. Außerdem kann man über left/mid/right die Shapes (im Idealfall per Schleife strukturiert benannt) auch noch gezielter filtern.
Schöne Grüße