Office: (Office 2016) Bild mit Text aus Zelle verknüpfen

Helfe beim Thema Bild mit Text aus Zelle verknüpfen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Guten Tag Ihr Lieben Ich würde gerne mal wieder auf Eure hochgeschätzte Hilfe zugreifen. Ich habe eine Datei in dem ich ALLE Puzzles (ca. 250 Stück )... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Elguano, 22. November 2021.

  1. Elguano Erfahrener User

    Bild mit Text aus Zelle verknüpfen


    Guten Tag Ihr Lieben
    Ich würde gerne mal wieder auf Eure hochgeschätzte Hilfe zugreifen.
    Ich habe eine Datei in dem ich ALLE Puzzles (ca. 250 Stück ) meiner Frau eingegeben habe. Das habe ich im "Blatt" ""ALLE PUZZLES"" wie folgt eingegeben.
    In Zelle A1 steht z.B. 1000-C-102754-1 - Charles Bridge at Night (CASTORLAND).
    Das bedeutet:
    1000 steht für die Anzahl der Puzzleteile
    -C-102754-1 steht für die Artikelnummer
    - Charles Bridge at Night steht für den Namen des Puzzles
    (CASTORLAND) ist der Hersteller des Puzzles.

    In Zelle A2 ist das Bild des Puzzles eingefügt.

    Jetzt möchte ich aus dieser Tabelle die Bilder mit den dazugehörigen Texten in folgende Blätter Automatisch übernehmen.
    erstens in ein Blatt mit dem jeweiligen Hersteller
    zweitens in einem Blatt mit der jeweiligen Anzahl der Puzzleteile.
    Zur Zeit erledige ich das per kopieren und einfügen.

    Jetzt meine Frage.
    Ist es möglich das Bild mit dem Text zu verknüpfen und gleichzeitig in das richtige Blatt zu übergeben?
    Wenn möglich bitte ohne VBA.

    Eine Beispieldatei habe ich für Eure Überlegungen angehängt
    Ich würde mich sehr freuen und wäre Euch sehr Dankbar wenn Ihr eine möglichkeit kennt. Denn so wie ich es jetzt mache ist es sehr Zeitaufwändig.
    Mit freundlichen Grüßen
    Ralf B. aus B. an der E.
     
  2. Elguano Erfahrener User
    Guten Tag Ihr Lieben
    Ich bin Verwundert, dass in diesem Thema bisher noch überhaupt keine Antwort von Euch gekommen ist.
    Gibt es wirklich keine Möglichkeit mein Vorhaben zu verwirklichen?
    Ich wäre auch mit einer VBA Lösung zufrieden. Nur würde ich dafür dann auch noch eine Anleitung benötigen um z.B. Hersteller oder Puzzleteilmenge anpassen zu können.
    Oder ist dieses Problem schon in einem anderen Thread gelöst worden das ich nicht gefunden habe?
    Wäre Nett wenn Ihr mich Aufklären könntet.

    Ich Grüße Euch freundlichst
    Ralf B. aus B. an der E.
     
  3. Beverly
    Beverly Erfahrener User
    Hi,

    hier eine Möglichkeit:
    Code:
    Sub BilderEinfuegen()
        Dim lngLetzte As Long
        Dim shaShape As Shape
        Dim strTab As String
        Application.ScreenUpdating = False
        For Each shaShape In Worksheets("ALLE PUZZLES").Shapes
            strTab = Left(shaShape.Name, InStr(shaShape.Name, "-") - 1)
            shaShape.Copy
            With Worksheets(strTab & "er")
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                .Cells(lngLetzte, 1) = shaShape.TopLeftCell.Offset(-1, 0)
            End With
            strTab = Mid(shaShape.Name, InStr(shaShape.Name, "(") + 1)
            strTab = Application.Substitute(strTab, ")", "")
            With Worksheets(strTab)
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                .Cells(lngLetzte, 1) = shaShape.TopLeftCell.Offset(-1, 0)
            End With
        Next shaShape
        Application.ScreenUpdating = True
    End Sub
    
    Du musst aber unbedingt sicherstellen, dass in der Tabelle mit allen Puzzles jedes Bild in der Zelle unterhalb der Zelle mit dem Namen liegt. Es muss dabei nicht direkt mit deren Oberkante beginnen, aber es darf NICHT in die Zelle mit dem Namen hineinragen, weil der Code davon ausgeht, dass der Text eben in der Zelle OBERHALB des Bildes steht.


    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  4. Elguano Erfahrener User

    Bild mit Text aus Zelle verknüpfen

    Guten Abend Karin
    Zuerst bedanke ich mich bei Dir für Deine Antwort. Ich hatte schon fast den Glauben daran verloren dass mir auch diesmal geholfen werden kann.
    Was ich garantieren kann ist, dass alle Bilder in der Zeile unter der Zeile sind in der der Text zum Bild steht.
    Wie ich aber in meiner zweiten Anfrage geschrieben habe, habe ich so gut wie keine Erfahrung mit VBA. Was ich weis ist, dass ich mit Alt+F11 in den VBA Bereich komme.
    Dort habe ich auf der linken Seite alle Tabllenblätter die in der Datei vorhanden sind. Hier habe ich den Code in die Tabelle4 (Castorland) eingefügt. Wenn ich den Code nun über die Schaltfläche mit dem grünen Pfeil ablaufen lasse kommt sofort folgende Meldung:
    Laufzeitfehler '5':
    Ungültiger Prozeduraufruf oder ungültiges Argument
    .
    Jetzt stellt sich mir die Frage: Mache ich etwas falsch und wenn ja was muss ich machen um den Fehler los zu werden?

    Kannst Du mir das Plausibel machen?

    Vielen Dank für Deine Hilfe
    Ralf B. aus B. an der E.
     
  5. Beverly
    Beverly Erfahrener User
    Hi Ralf,

    wenn du im VBA-Editor mit Alt+F11 bist, dann im Register: Einfügen -> Modul und Code dann dort einfügen. Verwende diesen Code:

    Code:
    Sub BilderEinfuegen()
        Dim lngLetzte As Long
        Dim shaShape As Shape
        Dim strTab As String
        Application.ScreenUpdating = False
        For Each shaShape In Worksheets("ALLE PUZZLES").Shapes
            ' geänderte Zeile
            strTab = Left(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "-") - 1)
            shaShape.Copy
            With Worksheets(strTab & "er")
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                .Cells(lngLetzte, 1) = shaShape.TopLeftCell.Offset(-1, 0)
            End With
            ' geänderte Zeile
            strTab = Mid(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "(") + 1)
            strTab = Application.Substitute(strTab, ")", "")
            With Worksheets(strTab)
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                .Cells(lngLetzte, 1) = shaShape.TopLeftCell.Offset(-1, 0)
            End With
        Next shaShape
        Application.ScreenUpdating = True
    End Sub
    
    Ich hatte zuerst alle Bilder durch ein anderes Makro nach dem Zellinhalt oberhalb jedes Bildes umbenennen lassen und hatte dann (im Code aus meinem vorhergehenden Beitrag) den Namen des Bildes zugrunde gelegt, um das betreffende Tabellenblatt zu ermitteln (in den Codezeilen strTab = ....). Danach hatte ich mir überlegt, dass die Umbenennung gar nicht erforderlich ist, sondern dass man gleich den Zelleninhalt oberhalb des Bildes verwenden kann, dabei aber vergessen, dies im Code auch entsprechend zu ändern - deshalb der Fehler. Im jetzigen Code habe ich die betreffenden Zeilen geändert und anstelle shaShape.Name wird nun shaShape.TopLeftCell.Offset(-1, 0) verwendet.


    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  6. Elguano Erfahrener User
    N`Abend Karin
    Leider hakt es auch jetzt noch.
    Ich habe wie Du geschrieben hast jetzt ein Modul in der Liste wo auch die Tabellen stehen.
    Wenn ich den Code ablaufen lasse wird diese Zeile in gelb markiert.

    strTab = Left(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "-") - 1)

    Die Fehlermeldung bleibt das gleiche.
    Wenn ich mit der Maus auf die Zeile gehe wird mir ein "Wert" angezeigt.
    strTab = "ALDI"
    Das ist der Name der ersten Tabelle.
    Mehr tut sich leider nichts.

    Wenn Du noch nicht aufgeben möchtest, dann stehe ich Dir gerne weiter zur Verfügung.
    Ich würde Dir aber auch die OriginalDatei zusenden wenn Du Dir sicher bist dass es Dir etwas besser Hilft.
    Allerdings ist die 41,4 MB groß!!!
    Sende mir einfach eine E-Mail an folgende Adresse.
    ralfheinzb@aol.com

    Mit bestem Dank
    Ralf B. aus B. an der E.
     
  7. Beverly
    Beverly Erfahrener User
    Hi Ralf,

    Das Problem liegt darin, dass dieses Bild (und vielleicht noch weitere) die zitierte Bedingung nicht erfüllt und mit seiner Oberkante nicht auf der Zelle UNTERHALB der Zelle mit dem Text liegt sondern AUF der Zelle mit dem Text, sodass Excel dadurch den Tabellennamen aus der leeren Zelle oberhalb des Textes extrahieren will, was natürlich nicht geht und deshalb den Fehler auslöst. Dass strTab einen Wert hat ist einfach damit zu erklären, dass die Variable noch aus dem vorhergehenden Schleifendurchlauf belegt ist.

    Ich habe den Code so angepasst, dass zuerst geprüft wird, ob in der Zelle oberhalb ein Text steht - wenn ja, dann den Tabellennamen daraus extrahieren; wenn nein, dann aus der Zelle extrahieren auf der das Bild mit seiner Oberkante liegt:

    Code:
    Sub BilderEinfuegen()
        Dim lngLetzte As Long
        Dim shaShape As Shape
        Dim strTab As String
        Dim strName As String
        Application.ScreenUpdating = False
        For Each shaShape In Worksheets("ALLE PUZZLES").Shapes
            '***** geändert
            If shaShape.TopLeftCell.Offset(-1, 0) <> "" Then
                strTab = Left(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "-") - 1)
                strName = shaShape.TopLeftCell.Offset(-1, 0)
            Else
                strTab = Left(shaShape.TopLeftCell, InStr(shaShape.TopLeftCell, "-") - 1)
                strName = shaShape.TopLeftCell
            End If
            '**************
            shaShape.Copy
            With Worksheets(strTab & "er")
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                ' geändert
                .Cells(lngLetzte, 1) = strName
            End With
            '***** geändert
            If shaShape.TopLeftCell.Offset(-1, 0) <> "" Then
                strTab = Mid(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "(") + 1)
                strName = shaShape.TopLeftCell.Offset(-1, 0)
            Else
                strTab = Mid(shaShape.TopLeftCell, InStr(shaShape.TopLeftCell, "(") + 1)
                strName = shaShape.TopLeftCell
            End If
            '**************
            strTab = Application.Substitute(strTab, ")", "")
            With Worksheets(strTab)
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                If .Cells(lngLetzte, 1) <> "" Then lngLetzte = lngLetzte + 13
                .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                ' geändert
                .Cells(lngLetzte, 1) = strName
            End With
        Next shaShape
        Application.ScreenUpdating = True
    End Sub
    


    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  8. Elguano Erfahrener User

    Bild mit Text aus Zelle verknüpfen

    Guten Abend Karin
    Ich habe den Code vor ein paar Minuten erst ausprobieren können, weil ich Weihnachtsdeko anbringen musste.
    Folgendes ist mir aufgefallen.
    1. In allen Blättern (es sind bisher 29) werden Bilder mit dem dazugehörigen Text übergeben.Bild mit Text aus Zelle verknüpfen *:)*

    2. Es werden aber nicht alle Bilder übergeben. Bild mit Text aus Zelle verknüpfen :(Vielleicht muss ich da nochmal überprüfen ob die Bilder auch wirklich unter der Textzelle stehen. Oder kann es noch an was anderem liegen?

    3. Da ich auch Bilder im Hochformat habe, werden die nachfolgenden Texte und Bilder im Hintergrund angelegt. Da gehe ich mal davon aus, dass Du hier eine Zeilenzahl von 13 angegeben hast. Kann man das für die Hochformatbilder anpassen? Wenn nicht, dann muss ich eben an diesen Stellen 7 Zeilen händisch einfügen.

    4. Es werden immer alle Texte und Bilder neu angehängt.Bild mit Text aus Zelle verknüpfen :(Bild mit Text aus Zelle verknüpfen :( Das ist aber nicht gut, weil ich ja die Liste nur mit neuen Bildern die noch nicht in "ALLE PUZZLES" eingearbeitet sind übergeben und ""anhängen"" möchte. Kann man hier eine Vergleichsroutine einfügen oder eine vorherige Löschung der Texte und Bilder vornehmen?

    5. Was kann ich tuen um den Code ""automatisch"" ablaufen zu lassen ohne jedesmal in den VBA Sektor gehen zu müssen?
    Riesen SORRY!!! Ich hatte ja erwähnt, dass ich nur beschränkte Kenntnisse von VBA habe.

    6. Wenn ich den Code ablaufen lasse, bleibt Er an dieser Zeile stehen.
    With Worksheets(strTab & "er") Die Aufgabe wurde aber wohl erledigt.

    Bis hierhin muss ich Dir schreiben, dass Du eine gute Arbeit gemacht hast. Ich gehe mal davon aus, dass wir die kleinen "Mängel" auch noch beheben können.

    Schönen Dank für Deine Mühe die Du Dir für mich gemacht hast.

    Schönes Wochenende
    Ralf B. aus B. an der E.
     
  9. Beverly
    Beverly Erfahrener User
    Hi Ralf,

    dass du immer neue Bilder anfügen willst, davon war bisher nicht die Rede gewesen - habe ich nun eingebaut.
    In deiner hochgeladenen Mappe gab es nur Bilder im Querformat - woher sollte man wissen, dass es auch welche im Hochformat gibt? Ist jetzt berücksichtigt.
    Weshalb nicht alle Bilder übernommen werden, dazu kann ich nichts sagen, könnte möglicherweise daran liegen dass es sehr viele Bilder sind. Vielleicht hilft, wenn du das Makro mehrmals laufen lässt - bereits vorhandene Bilder werden jetzt ja übersprungen.
    Dass der Code in der Zeile stehen bleibt - dazu kann ich auch nichts sagen, wenn er keinen Fehler auslöst.

    Um das Makor nicht aus dem VBA-Editor starten zu müssen gehe ins Register: Entwicklertools -> Befehltsgruppe: Steuerelemente und füge eine Schaltfläche aus den Formular-Steuerelementen ins Tabellenblatt ein. Wähle dann das Makro BilderEinfügen aus und drücke Ok.

    Code:
    Sub BilderEinfuegen()
        Dim lngLetzte As Long
        Dim shaShape As Shape
        Dim strTab As String
        Dim strName As String
        Dim rngSuche As Range
        Application.ScreenUpdating = False
        For Each shaShape In Worksheets("ALLE PUZZLES").Shapes
            If shaShape.Name <> ActiveSheet.Shapes(Application.Caller).Name Then
                If shaShape.TopLeftCell.Offset(-1, 0) <> "" Then
                    strTab = Left(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "-") - 1)
                    strName = shaShape.TopLeftCell.Offset(-1, 0)
                Else
                    strTab = Left(shaShape.TopLeftCell, InStr(shaShape.TopLeftCell, "-") - 1)
                    strName = shaShape.TopLeftCell
                End If
                shaShape.Copy
                With Worksheets(strTab & "er")
                    Set rngSuche = .Columns(1).Find(strName, lookat:=xlWhole)
                    If rngSuche Is Nothing Then
                        lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                        If .Cells(lngLetzte, 1) <> "" Then
                            If .Shapes(.Shapes.Count).Height < .Shapes(.Shapes.Count).Width Then
                                lngLetzte = lngLetzte + 13
                            Else
                                lngLetzte = lngLetzte + 19
                            End If
                        End If
                        .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                        .Cells(lngLetzte, 1) = strName
                    End If
                End With
                If shaShape.TopLeftCell.Offset(-1, 0) <> "" Then
                    strTab = Mid(shaShape.TopLeftCell.Offset(-1, 0), InStr(shaShape.TopLeftCell.Offset(-1, 0), "(") + 1)
                Else
                    strTab = Mid(shaShape.TopLeftCell, InStr(shaShape.TopLeftCell, "(") + 1)
                End If
                strTab = Application.Substitute(strTab, ")", "")
                With Worksheets(strTab)
                    Set rngSuche = .Columns(1).Find(strName, lookat:=xlWhole)
                    If rngSuche Is Nothing Then
                        lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                        If .Cells(lngLetzte, 1) <> "" Then
                            If .Shapes(.Shapes.Count).Height < .Shapes(.Shapes.Count).Width Then
                                lngLetzte = lngLetzte + 13
                            Else
                                lngLetzte = lngLetzte + 19
                            End If
                        End If
                        .Cells(lngLetzte + 1, 1).PasteSpecial Paste:=xlAll
                        .Cells(lngLetzte, 1) = strName
                    End If
                End With
            End If
        Next shaShape
        Application.ScreenUpdating = True
    End Sub

    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  10. Elguano Erfahrener User
    Guten Tag Karin
    Für die fehlenden Informationen muss ich mich wirklich tu tiefst Entschuldigen. Darüber habe ich beim erstellen des Themas nicht nachgedacht. Ich hoffe, dass mir solche Fehler nicht mehr passieren.
    Ich habe heute aber kaum noch Zeit den neuen Code zu testen. Werde das aber so schnell wie möglich machen.
    Ich bin ja sehr Froh, dass es überhaupt funktioniert Bilder an anderer Stelle automatisch zu übergeben. Das erspart mir dann doch viel Zeit.
    Ich werde mich wieder hier melden wenn ich alles getestet habe.
    Bis dahin wünsche ich Dir eine angenehme Zeit.
    Mit freundlichen Grüßen
    Ralf B. aus B. an der E.
     
  11. Elguano Erfahrener User
    Guten Morgen Karin
    Mit bedauern muss ich Dir schreiben, dass der neue Code in meiner Datei nicht läuft. Es wird mir folgende Meldung angezeigt:
    Laufzeitfehler '-2147352571(80020005)':
    Das Element mit dem angegebenen Namen wurde nicht gefunden.

    Diese Zeile wird gelb markiert:
    If shaShape.Name <> ActiveSheet.Shapes(Application.Caller).Name Then
    Leider bekomme ich die Datei nicht so klein, dass ich Sie übersichtlich hochladen könnte (von 41,1 MB auf 2,3 MB verkleinert

    Mit lieben Grüßen
    Ralf B. aus B. an der E.
     
  12. Beverly
    Beverly Erfahrener User
    Hi Ralf,

    ich hatte doch geschrieben, dass du eine Schaltfläche erstellen und das Makro damit verknüpfen sollst. Das hast du offensichtlich nicht gemacht und folglich startet das Makro nicht über diese Schaltfläche. Deshalb kann der Code sie nicht finden, denn mit ActiveSheet.Shapes(Application.Caller) wird das aufrufende Steuerelement (also die Schaltfläche, mit der es verknüpft ist) angesprochen.
    Wenn du den Code natürlich weiterhin aus dem VBA-Editor oder über das Register: Ansicht -> Befehlsgruppe: Makros starten willst, musst du diese Zeile (und das dazu gehörende End If) löschen.


    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  13. Elguano Erfahrener User

    Bild mit Text aus Zelle verknüpfen

    Guten Abend Karin
    Wieder muss ich mich bei Dir Entschuldigen. Was ich hiermit aus vollem Herzen mache.
    Ich habe jetzt Deine Anweisung in die Tat umgesetzt. Und siehe da!!!! Es funktioniert über die Schaltfläche.
    Siehe es mal als Anfängerfehler meinerseits.
    Auch wenn ich die Aktion mehrfach ausführe, werden keine Vorhandenen Texte und Bilder an die Blätter doppelt übergeben.
    Diese Aufgabe hast Du, auch wenn ich es Dir nicht leicht gemacht habe, mit Bravur erledigt.
    Woran ich jetzt noch arbeiten muss ist, das nicht alle Texte und Bilder übergeben werden. (Alle ab Zeile 1323) und einige in niedrigeren Zeilen. Insgesamt 60 Stück.
    Ich versuche jetzt mal eine neue Datei zu erstellen und diese Texte und Bilder (neue Bilder) dort einzugeben.
    Bin mal gespannt ob es dann funktioniert.
    Ich bin jedenfalls Glücklich, dass es für mein Vorhaben eine Lösung gibt.
    Für Deine wirklich gute Arbeit zolle ich Dir meinen größten Respekt.
    Wenn Du mir Erlaubst das ich hier nochmal Nachfrage ob jemand eine Idee hat warum nicht alle Texte und Bilder übergeben werden, würde ich das hiermit gerne tuen. Vielleicht kann ich mir dann ja auch wieder viel Arbeit und Zeit sparen.
    Hiermit Entlaste ich Dich von der Aufgabe. Bedanke mich nochmals für Deine Gedult, Ausdauer, Freundlichkeit und nicht zuletzt sehr gute Arbeit.

    Mit freundlichen Grüßen
    Ralf B. aus B. an der E.
     
  14. Beverly
    Beverly Erfahrener User
    Hi Ralf,

    mich würde auch interessieren, weshalb nicht alle Bilder/Texte kopiert werden. Lade doch mal eine Mappe mit Bildern hoch, die übergeben und welchen die nicht übergeben werden und mache die nicht kopierten irgendwie kenntlich (z.B. ein rotes X in Spalte B) - vielleicht kann man ja irgendwie erkenen, wodurch sie sich voneinander unterscheiden.


    Bild mit Text aus Zelle verknüpfen GrußformelBild mit Text aus Zelle verknüpfen Beverly's Excel - Inn
     
  15. Elguano Erfahrener User
    Hi Karin
    Dein Wunsch ist mir Befehl.
    Habe eine MINI Datei erstellt für 6 Bilder.
    Alle Bilder in Spalte A werden übergeben.
    Alle Bilder in Spalte C werden nicht übergeben.
    In Zelle F1 ALLE PUZZLES ist die Schaltfläche für den Code abzuspielen.
    In dem Ja Nein Blatt sind alle Texte hinterlegt. * steht für "Wird übergeben". ? steht für "Wird nicht übergeben".
    Bin mal gespannt ob das zu lösen ist.
    Was ich seit meiner letzten Antwort ausprobiert habe, schreibe ich vielleicht später mal. Hat aber auch keinen Erfolg gebracht.
    Bis später
    Ralf B. aus B. an der E.
     
Thema:

Bild mit Text aus Zelle verknüpfen

Die Seite wird geladen...
  1. Bild mit Text aus Zelle verknüpfen - Similar Threads - Bild Text Zelle

  2. Eingefügtes Bild in einer Tabelle verschiebt den Text

    in Microsoft Word Hilfe
    Eingefügtes Bild in einer Tabelle verschiebt den Text: Guten Abend, ich habe eine Tabelle, die aus einem einzigen Feld besteht und in diesem Feld steht ein Zahl. Die Tabelle hat das Layout, dass der Text "zentriert ausgerichtet" ist. Die Zahl...
  3. Video: Umbrechen von Text um Bilder

    in Microsoft Excel Tutorials
    Video: Umbrechen von Text um Bilder: Video: Umbrechen von Text um Bilder Excel für Microsoft 365 Word für Microsoft 365 Outlook für Microsoft 365 PowerPoint für Microsoft 365 Excel 2019...
  4. Eingebettete Bilder in E-Mails oder Feldern im Rich-Text-Format werden ausgeblendet oder ...

    in Microsoft Outlook Tutorials
    Eingebettete Bilder in E-Mails oder Feldern im Rich-Text-Format werden ausgeblendet oder ...: Eingebettete Bilder in E-Mails oder Feldern im Rich-Text-Format werden ausgeblendet oder falsch ausgerichtet Outlook für Microsoft 365 Mehr... Weniger...
  5. Umbrechen von Text und Verschieben von Bildern in Word

    in Microsoft Word Tutorials
    Umbrechen von Text und Verschieben von Bildern in Word: Umbrechen von Text und Verschieben von Bildern in Word Word für Microsoft 365 Word für das Web Word 2019 Word 2016 Word 2013 Mehr... Weniger...
  6. Einfügen von gescanntem Text oder Bildern in Word

    in Microsoft Word Tutorials
    Einfügen von gescanntem Text oder Bildern in Word: Einfügen von gescanntem Text oder Bildern in Word Word für Microsoft 365 Word 2019 Word 2016 Word 2013 Mehr... Weniger...
  7. Schräger Text - siehe Bild

    in Microsoft PowerPoint Hilfe
    Schräger Text - siehe Bild: Hallo zusammen, [ATTACH] ich möchte einen ähnlichen Effekt erzielen, wie in Indesign, siehe Bild. Text soll schräg nach oben laufen, vorne aber vertikal ausgerichtet sein. Ich möchte...
  8. Text umd das Bild fließen lassen PowerPoint Mac 2011

    in Microsoft PowerPoint Hilfe
    Text umd das Bild fließen lassen PowerPoint Mac 2011: Hallöle :) ich muss ein Poster erstellen! Die Basis für mein Poster ist gelegt! Damit habe ich auch kein Problem. Ich scheitere jedes Mal beim Einfügen des Bildes! Ich möchte meinen Text...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden