Office: Bilder über UserForm im Tabellenblatt einfügen.

Hallo zusammen,
ich habe folgendes Problem. Ich habe eine Vegleichstabelle für die Arbeit erstellt.
Also man kann Über ein Formular Daten über ein bestimmtes Produkt auf eine Exceltabelle übertragen.
Jetzt möchte mein Chef das ich auf ein Produktbild in das Formular lade das sich anschließend auch in die Exceltabelle überträgt und dort gespeichert werden soll. Ich habe leider keine Idee mehr wie ich das Anstellen soll.
Ich hoffe Ihr könnt mir Bitte helfen.

 

Hi,

wenn du die Bilder in das UserForm einfügst, fügst du es doch aus irgendeinem Verzeichnis ein. Speichere Pfad und Bildname z.B. in der Tag-Eigenschaft des UserForms - so nach dem Prinzip:

Code:

UserForm.Tag = Pfad & Bildname

und wenn du das Bild dann in die Tabelle "übertragen" willst, sind dir Bildname und Pfad bekannt und du kannst dieses Bild dann ganz normal ins Tabellenblatt einfügen - nach diesem Prinzip:

Code:

Worksheets("Tabelle1").Pictures.Insert(UserForm.Tag)

Die Tag-Eigenschaft wurde extra für Programmierer geschaffen, damit darin Informationen, die für den weitern Codeablauf notwendig sind, sozusagen "temporär zwischengespeichert" werden können, ohne dass man sie irgendwo im Tabellenblatt ablegen muss. Jedes Steuerelement auf einem Userform besitzt diese Eigenschaft.

Bis später,
Karin

 

Hallo Karin,
danke erstmal für die schnelle Antwort. Doch leider komm ich damit nicht weiter.
Der user der das Bild ins Formular einfügt hat nicht die entsprechenden Exelkenntisse um das ich sage mal so kompliziert zu machen.
Er soll die Daten und ein Produktbild in das Formular einfügen und es dann an die Exceltabelle schicken.
Dabei fungiert ein excelbaltt als eine Art Datenbank in der das alles gespeichert werden soll.
wäre es Hilfreich wenn ich dir das Projekt mal zuschicke?
Achso ich verwende Office 2010

Gruß Frank

 

Hi Frank,

"so kompliziert" ist die einzige Möglichkeit, dein Vorhaben zu realisieren und doch nicht wirklich kompliziert. Der User muss dabei doch gar nichts machen außer einen OK-Button (oder etwas in der Art) zu drücken. Derjenige, der den Code für das Einfügen des Bildes ins UserForm programmiert hat, sollte doch in der Lage sein, den von mir geposteten Code zu übernehmen und an die Stelle zu bringen, wo das gewählte Bild aus dem betreffenden Verzeichnis ins Tabellenblatt eingefügt werden soll.

Du solltest auch bedenken, dass Excel nicht als Datenbank geeinget ist, insbesondere wenn es um die Ablage von Bildern geht - da erhöht sich der Speicherbedarf derart, dass man schon bald nicht mehr mir der Datei arbeiten kann. Zu empfehlen wäre da eher, das man ein Hyperlink zum betrefenden Bild auf der Festplatte im Tabellenblatt erstellt und damit das Bild bei Bedarf öffnen kann.

Bis später,
Karin

 

Hallo Karin,
dass ganze habe ich zusammen gebaut. Aber ich komme einfach nicht weiter bei dem Thema Bild einfügen.
Es soll später möglich sein, dass derjenige der ein neues Produkt anlegen möchte einfach nur die Technischen Daten in die dafür
vorgesehene Textfelder einfügt und das dazugehöriges Bild zu diesem Produkt. Ich muss davon ausgehen das der Benutzer wenig bis keine Ahnung hat in Excel. Das mit den Textfeldern und automatischen einfügen in das Tabellenblatt habe ich hinbekommen.
Vielleicht kannst du mir ein Beispiel dazu machen. Das wäre natürlich echt super.

Gruß Frank

 

Hi Frank,

estelle auf dem UserForm ein Bildsteuerelement (Image). Mit folgendem Code kannst du ein Bild aus einem Verzeichnis in dieses Bildsteuerelement laden:

Code:

Image1.Picture = LoadPicture("C:\Test\Bild.jpg")

Gleichzeitig schreibst du den Bildnamen einschließlich Pfad in die Tag-Eigenschaft (am einfachsten ins Bildsteuerelement)

Code:

Image1.Tag = "C:\Test\Bild.jpg"

Das Bild dann ins Tabellenblatt einfügen geht so:

Code:

ActiveSheet.Pictures.Insert(Image1.Tag)

Bis später,
Karin

 

Hallo Karin,
ich werde es gleich versuchen, wollte mich aber schon mal für die schnelle Hilfe bei Dir bedanken.
Ich werde dir dann schreiben ob es funktioniert hat.

Gruß
Frank

 

Ich komm einfach nicht weiter ich häng dir mal mein excel an und vielleicht kannst du mir sagen wo mein Problem liegt.
Ich bin mir sicher das deine Anweisungen richtig sind.

 

Ich komm einfach nicht weiter ich häng dir mal mein excel an und vielleicht kannst du mir sagen wo mein Problem liegt.
Ich bin mir sicher das deine Anweisungen richtig sind.
Den Anhang 6725 betrachten Den Anhang 6726 betrachten

 

Mein Excel kann aus einem Bild leider keine Arbeitsmappe erstellen, außerdm sind deine Angaben zum "WAS nicht geht" ganz und gar nicht hilfreich, folglich kann ich nur raten: in meinem Code heißt das Bildsteuerelement Image1, auf deinem UserForm dagegen imgImage1.

Bis später,
Karin

 

Ich habe hier mal meine Exceldatei angehängt

 

Irgendwie musst du doch das Bild auswählen und ins Image laden - das fehlt komplett bei dir. Du könntest dazu z.B. das Doppelklick-Ereignis des Images verwenden, um das Verzeichnis mit den Bildern zu öffnen und das Bild auszuwählen und ins Image einzufügen:

Code:

Private Sub imgImage1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
   ' Bild auswählen und Pfad und Bildname in tag schreiben
   imgImage1.Tag = GetFile
   ' Bild ins Image einfügen
   imgImage1.Picture = LoadPicture(imgImage1.Tag)
   ' UserForm aktialisieren damit Bild angezeigt wird (kann einen Augenblick dauern)
   fmlDateneingabe.Repaint
End Sub

' Bild auswählen
Function GetFile() As String
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = False
        .Filters.Add "Images", "*.gif; *.jpg; *.jpeg"
        .ButtonName = "Bild laden"
        .Title = "Bild auswählen"
        .Show
        If .SelectedItems.Count = 0 Then
            GetFile = ""
        Else
            GetFile = .SelectedItems(1)
        End If
    End With
End Function

Der Code für das Einfügen des ausgewählten Bildes gehört dann in den Code des Buttons "Senden" (ich habe den betreffenden Teil-Code kommentiert):

Code:

Private Sub cmdSenden_Click()
'Fügt die eingetragende werte in das Tabellenblatt Schließt das Formular fmlDateneingabe
   Dim intErsteLeereZeile As Long
   With ActiveSheet
       intErsteLeereZeile = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
       .Cells(intErsteLeereZeile, 1).Value = Me.txtWägebereich.Value
       .Cells(intErsteLeereZeile, 2).Value = Me.txtTeilung.Value
       .Cells(intErsteLeereZeile, 3).Value = Me.txtMindeslast.Value
       .Cells(intErsteLeereZeile, 4).Value = Me.txtTarahöchstlast.Value
       .Cells(intErsteLeereZeile, 5).Value = Me.txtLastaufnahme.Value
       .Cells(intErsteLeereZeile, 6).Value = Me.txtAnzeige.Value
       .Cells(intErsteLeereZeile, 7).Value = Me.txtAnzeigeBedienfeld.Value
       .Cells(intErsteLeereZeile, 8).Value = Me.txtAnzeigeKundenseite.Value
       .Cells(intErsteLeereZeile, 9).Value = Me.txtDisplayinformationen.Value
       .Cells(intErsteLeereZeile, 10).Value = Me.txtBedientastaturFreiProgrammierbar.Value
       .Cells(intErsteLeereZeile, 11).Value = Me.txtBedientastatur.Value
       .Cells(intErsteLeereZeile, 12).Value = Me.txtSelbstbedienungstastatur.Value
       .Cells(intErsteLeereZeile, 13).Value = Me.txtSchnellbedienungstastatur.Value
       .Cells(intErsteLeereZeile, 14).Value = Me.txtDirektartikeltaste.Value
       .Cells(intErsteLeereZeile, 15).Value = Me.txtProgrammierbareDatenProPlu.Value
       .Cells(intErsteLeereZeile, 16).Value = Me.txtBetriebssysthem.Value
       .Cells(intErsteLeereZeile, 17).Value = Me.txtEinsatzmöglichkeiten.Value
       .Cells(intErsteLeereZeile, 18).Value = Me.txtThermobondrucker.Value
       .Cells(intErsteLeereZeile, 19).Value = Me.txtThermoetikettenDrucker.Value
       .Cells(intErsteLeereZeile, 20).Value = Me.txtThermoLinerlessDrucker.Value
       .Cells(intErsteLeereZeile, 21).Value = Me.txtDatenspeicher.Value
       .Cells(intErsteLeereZeile, 22).Value = Me.txtSchnittstelle.Value
       .Cells(intErsteLeereZeile, 23).Value = Me.txtBerichteAuswertung.Value
       .Cells(intErsteLeereZeile, 24).Value = Me.txtEichfähigesPosterminal.Value
       .Cells(intErsteLeereZeile, 25).Value = Me.txtWeiterLeistungsmerkmale.Value
       .Cells(intErsteLeereZeile, 26).Value = Me.txtLizenzenSoftware.Value
       .Cells(intErsteLeereZeile, 27).Value = Me.txtTemperaturbereich.Value
       .Cells(intErsteLeereZeile, 28).Value = Me.txtBetriebsspannung.Value
       .Cells(intErsteLeereZeile, 29).Value = Me.txtEigengewicht.Value
       .Cells(intErsteLeereZeile, 30).Value = Me.txtSchutzart.Value
       .Cells(intErsteLeereZeile, 31).Value = Me.txtStromaufnahme.Value
       .Cells(intErsteLeereZeile, 32).Value = Me.txtNetzfrequenz.Value
       .Cells(intErsteLeereZeile, 33).Value = Me.txtName.Value
       ' ein Bild wurde ins Image geladen und Name steht in der Tag-Eigenschaft
       If imgImage1.Tag <> "" Then
         ' ausgewähltes Bild ins Tabellenbltt einfügen
         .Pictures.Insert (imgImage1.Tag)
         ' bezieht sich auf das eingefügte Bilde
         With .Pictures(.Pictures.Count)
           ' Position Oberkante = Oberkant erste leere Zeile
           .Top = .Parent.Rows(intErsteLeereZeile).Top
           ' Position links = Spalte 34 Linke Kante
           .Left = .Parent.Columns(34).Left
         End With
      End If
   End With
   Unload fmlDateneingabe
End Sub

Bis später,
Karin

 

Hallo Karin,
vielen vielen Dank für Deine Hilfe, ich habe deine Änderungen übernommen
und jetzt kommt die Meldung Fehler beim Kompilieren: Unzulässiger oder nicht ausreichend
definierter verweis

 

Hi,

kann ich nicht nachvollziehen - bei mir kommt der Fehler nicht.

Bis später,
Karin

 

Hi,
ich habe deine Anweisungen Kopiert und eingefügt und bei mir kommt diese Meldung
Ich hänge die nochmal die Datei an, vielleicht stehe ich heute einfach zusehr auf dem Schlauch um meine Fehler zu finden
Gruß Frank