Office: Brauche dringend Eure Hilfe! WENN-Funktion nötig?

Hallo!

Ich bräuchte dringend mal Hilfe von ein paar kompetenten Fachleuten!



Und zwar habe ich eine Spalte mit jedem Datum des Jahres, also 365 Zeilen (hier gekürzt)
In jeder Zeile steht ein Geldbetrag X, in EINER anderen Zelle ein Betrag Y, den ich nicht unterschreiten darf.

Ich möchte in eine Zelle eintragen, dass ich einen bestimmten Betrag brauche, und Excel soll das dazugehörige Datum ausgeben, wann das Geld verfügbar ist, ohne dass ich Betrag Y unterschreite!

Also: Zum Beispiel Zelle G8 überprüfen -> FALSCH, also G9 überprüfen... Das ganze dann 365 mal.

Ich hab's mit einer WENN-Funktion versucht, aber man kann ja nur 7 verschachteln. Und da ich ein waschechter Laie bin....


Über Hilfe wär ich wirklich sehr dankbar!
Hab auch nochmal meine bisherige Tabelle bereitgestellt...


MfG
Alex

 

Hallo,

ich verstehe leider nicht, was Deine Formel in K1 bewirken soll.
Willst Du alle Tage des Jahres abfragen, ob ein "+" in Spalte J steht? In einer wenn-Formel wird immer der Befehl der ersten Übereinstimmung ausgeführt. In Deinem Beispiel also "01.06.2007".
Was soll in K1 genau angezeigt werden?

 

Ja, genau so war es ja auch gedacht. Aber wie gesagt, normalerweise hab ich ja 365 Zeilen, müsste also mit meiner Vorgehensweise 365 (!!!) WENN-Funktionen verschachteln, da der gewünschte Betrag ja nicht immer unter den ersten 7 Zeilen ist!!
Außerdem sollte Excel idealerweise alle Tage vor "heute()" ausschließen!

In K1 soll also das Datum stehen, in dessen Zeile der gewünschte Betrag rauskommt. Bei meinem Beispiel wäre das also das Datum von A13, weil in G13 die 1000€ verfügbar sind...


MfG
Alex

 

Hallo!

Ich hab's jetzt so verstanden:
Du suchst den ersten (in der Zukunft liegenden!) Zeitpunkt, an dem ein Betrag aus Spalte G größer ist als die Summe aus E1 und I1 ?
Wenn dem so ist dann teste mal diese Formel in K1

=INDEX(A:A;MIN(WENN(A8:A20>=HEUTE();WENN(G8:G20>E1+I1;ZEILE(8:20)))))
Achtung Matrixformel: Die Eingabe der Formel mit der Tastenkombination Strg+Shift+Enter abschließen!

Dabei musst du aber darauf achten, dass deine Datümer aus Spalte A auch als ECHTE Datümer formatiert sind! In deiner Beispieldatei ist das nämlich NICHT der Fall.

 

@ schatzi: Klappt genauso, wie ich es wollte!!!!!!! wohin soll ich das Geld überweisen?? :mrgreen: :mrgreen:

Ich hab jetzt mal für jeden Tag eine Zeile genommen und die Formel abgeändert, sieht dann so aus:

"=INDEX(A:A;MIN(WENN(A8:A372>=HEUTE();WENN(G8:G372>E1+I1;ZEILE(8:372)))))"


So, jetzt mal was Kompliziertes!! :mrgreen:
Wenn ich jetzt zum Beispiel 2 Zeilen hab mit dem selben Datum (beispielsweise weil ich 2 Kontoeingänge hab), muss ich dann die Formel selbst auf "373" abändern? Oder kann man das auch automatisieren?

Und kann man mit einbeziehen lassen, dass man den Betrag von E1+I1 über mehrere Tage braucht, sodass Excel mir ausgibt, wann E1+I1 solange zusammenhängend (z.B. 30 Tage) verfügbar ist??


Ich weiß, klingt ein bisschen verwirrend....


MfG
Alex

 

Hallo!

Die erste "Neue" ist einfach:
Du kannst den Bereich von Anfang an großzügig festlegen, z.B.
=INDEX(A:A;MIN(WENN(A8:A1000>=HEUTE();WENN(G8:G1000>E1+I1;ZEILE(8:1000)))))
Je größer der angegebene Bereich, desto länger rechnet die Formel allerdings auch, daher würde ich nicht "maßlos" übertreiben bei der Bereichsangabe...

Die zweite "Neue" klingt nicht ganz so einfach...
Verstehe ich das richtig:
Du möchtest in einer Zelle eine Tagesanzahl vorgeben, z.B. "30"
Nun suchst du den ersten (in der Zukunft liegenden) Bereich, in dem an ALLEN Tagen JEWEILS mehr als (E1+I1) Geld vorhanden ist.
Ist dem so?

Wenn das mit einer Formel überhaupt möglich ist, dann wird das aber bestimmt ein ganz schöner Apparillo...

 

:cry: Manchmal denke ich, ich bin nicht lebensfähig... :mrgreen:

Deshalb hast du ja "Spezialist" als Bezeichnung, mmh??
Aber du hast es schon richtig verstanden, genau so dachte ich mir das!


MfG
Alex

 

Hallo!

Hab' schon mal "vorgebastelt"...
Ich bin mir allerdings nicht sicher, ob die Formel wirklich in allen Fällen richtig rechnet:
Die Tagesanzahl wird in L4 vorgegeben.
Dann müsste (eigentlich) diese Formel das Anfangsdatum des Bereiches ausgeben:

=INDEX(A8:A1000;MIN(WENN(A8:A1000>=HEUTE();WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(G7;ZEILE(1:993);;L4);">"&E1+I1)=L4;ZEILE(1:993)))))
Achtung Matrixformel: Die Eingabe der Formel mit der Tastenkombination Strg+Shift+Enter abschließen!

Voraussetzung dafür ist, dass deine Datümer aufsteigend sortiert sind.
Wenn kein passender Bereich gefunden wird, dann wird das Datum aus A8 ausgegeben.
Teste mal ein bisschen herum, ob sie wirklich korrekt arbeitet.

 

KLAPPT!!!!!!!!!!!!!!!! Besten Dank!!!!!!!!!!
Jetzt steht zwar 01.01.2007 da, wenn der Betrag zu hoch ist, aber damit kann ich leben......

Sobald ich noch was ändern will/muss, würd ich mich nochmal vertrauensvoll an dich wenden... @ schatzi

:mrgreen: :mrgreen: :mrgreen: KLASSE FORUM!!!

 

Du kannst auch einen Fehlerablfang einbauen, aber dadurch wird's nicht gerade kürzer:

=WENN(MIN(WENN(A8:A1000>=HEUTE();WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(G7;ZEILE(1:993);;L4);">"&E1+I1)=L4;ZEILE(1:993))));INDEX(A8:A1000;MIN(WENN(A8:A1000>=HEUTE();WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(G7;ZEILE(1:993);;L4);">"&E1+I1)=L4;ZEILE(1:993)))));"nix gefunden")

 

Ich lass es jetzt erstmal so, solange es funktioniert! Danke trotzdem...

 

Aaaahhhh, Hilfe!!!

@ schatzi:

Wenn ich jetzt in 3 Zeilen immer dasselbe Datum habe (z. B. wegen 3 Zahlungseingängen), dann zählt jede einzelne Zeile als verschiedenen Tag, nicht als den selben!!!!

MfG
Alex

P.S.: Hab die aktuelle Version nochmal drangehängt. Problem ist dann ab A282 (02.10.2007). Jede Zeile zählt Excel als neuen Tag.

 

Hallo!

Ich glaube, ich hab's jetzt unter Zuhilfenahme zweier Extraspalten (AA und AB) lösen können:

Schreibe in AA1
=INDEX(A:A;KKLEINSTE(WENN(A$8:A$500>=HEUTE();WENN(G$8:G$500>E$1+I$1;ZEILE($8:$500)));ZEILE(A1)))
Achtung Matrixformel: Die Eingabe der Formel mit der Tastenkombination Strg+Shift+Enter abschließen!
Schreibe in AB1
=ZÄHLENWENN(BEREICH.VERSCHIEBEN(G$7;VERGLEICH(AA1;A$8:A$500;);;VERGLEICH(AA1+K$2+1%;A$8:A$500;1)-VERGLEICH(AA1;A$8:A$500;));">"&E$1+I$1)>=VERGLEICH(AA1+K$2+1%;A$8:A$500;1)-VERGLEICH(AA1;A$8:A$500;)
KEINE Matrixformel!

Kopiere diese beiden Formeln bis ca. Zeile 500 runter.

Schreibe in K1
=INDEX(AA:AA;VERGLEICH(WAHR;AB:AB;))
KEINE Matrixformel!

Nun müsste es passen.
Puh...

 

Wer ist der Beste????



SCHATZI!!!! :mrgreen: :mrgreen: