Office: (Office 2016) Brauche Hilfe für VBA Code zum löschen von Duplikaten!

Hallo ,wie in der Überschrift bereits zu sehen ist ,brauche ich Hilfe für einen VBA Code.
Ich bin bin ein absoluter Neuling in Sachen Forenbeiträge und Excel. Daher bitte ich um Verständnis.
Zu meinen Problem:

Ich habe eine Excel liste, in der bei zwei Spalten keine Duplikate eingetragen werden sollen. Die Gültigkeitsprüfung wird schon
für eine Bedingung verwendet.Deswegen möchte ich das Ganze mit VBA lösen.
ich habe folgenden Code welcher funktioniert

Code:

Set Rueckgabe = Range("E3:E151")
If Target.Value = "" Then Exit Sub
If Target.Cells.Count > 1 Then Exit Sub
If Intersect(Rueckgabe, Target) Is Nothing Then Exit Sub
If WorksheetFunction.CountIf(Rueckgabe, Target.Value) > 1 Then
    MsgBox ("Doppelter Eintrag nicht zulässig")
    Target.Value = ""
    Target.Select
End If

soweit so gut . Ich möchte das ganze aber auch für den Bereich C3:C151 haben. Deswegen habe ich das Ganze kopiert
und die Variable geändert.

Code:

Set Rueckgabe = Range("E3:E151")
If Target.Value = "" Then Exit Sub
If Target.Cells.Count > 1 Then Exit Sub
If Intersect(Rueckgabe, Target) Is Nothing Then Exit Sub
If WorksheetFunction.CountIf(Rueckgabe, Target.Value) > 1 Then
    MsgBox ("Doppelter Eintrag nicht zulässig")
    Target.Value = ""
    Target.Select
End If

Set Ausgabe = Range("C3:C151")
If Target.Value = "" Then Exit Sub
If Target.Cells.Count > 1 Then Exit Sub
If Intersect(Ausgabe, Target) Is Nothing Then Exit Sub
If WorksheetFunction.CountIf(Ausgabe, Target.Value) > 1 Then
    MsgBox ("Doppelter Eintrag nicht zulässig")
    Target.Value = ""
    Target.Select
End If

Wie gesagt der erste Code funktioniert, nur beim zweiten passiert Garnichts. Ich hoffe dass Ihr mir helfen könnt.

MFG Tim

 

Hi Tim,

versuche es mal so:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count = 1 Then
        If Target <> "" Then
            If Not Intersect(Target, Range("E3:E151")) Is Nothing Then
                If Application.CountIf(Range("E3:E151"), Target.Value) > 1 Then
                    MsgBox ("Doppelter Eintrag nicht zulässig")
                    Application.EnableEvents = False
                    Application.Undo
                    Application.EnableEvents = True
                End If
            ElseIf Not Intersect(Target, Range("C3:C151")) Is Nothing Then
                If Application.CountIf(Range("C3:C151"), Target.Value) > 1 Then
                    MsgBox ("Doppelter Eintrag nicht zulässig")
                    Application.EnableEvents = False
                    Application.Undo
                    Application.EnableEvents = True
                End If
            End If
        End If
    End If
End Sub

Bis später,
Karin

 

Hallo Karin. Vielen dank für die schnelle Antwort!
Ich habe den Code eingefügt und er funktioniert so wie er es soll.
Dankeschön

MFG Tim