Office: (Office 365) Brauche mal Hilfe bei ja/nein auswahl

Also hängt es von der Haarfarbe des Vorgesetzen ab?

 

Moin!

Hier eine kleine VBA-Lösung (der Code gehört in die Tabelle!), die mit nur einer Spalte und ohne Tastatur auskommt: Ein Doppelklick in Spalte 1 (=A) wechselt je nach aktuellem Inhalt zum nächsten: weiß, grün, rot, weiß ....

Code:

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Cancel = True

If Target.Column = 1 Then 'ANPASSEN
    Select Case Target.Interior.Color
        Case vbWhite
            Target.Interior.Color = vbGreen
            Target.Value = "gn"
        Case vbGreen
            Target.Interior.Color = vbRed
            Target.Value = "rt"
        Case vbRed
            Target.Interior.Color = vbWhite
            Target.Value = "ws"
    End Select
End If

'passt die Spaltenbreite an ihren Inhalt an und zentriert ihn
Columns(1).AutoFit
Columns(1).HorizontalAlignment = xlCenter

End Sub

Viel Spaß und Gruß an den Chef mit den grünen Haaren ;-)

 

Moin!
Nur ergänzend zum sinnvollen Code:
Range.Interior.Color = vbWhite
hat die meist unerwünschte "Unart", die Gitternetzlinien zu überdecken, heißt unsichtbar zu machen.
Deshalb sollte man zusätzlich folgendes setzen:
Range.Interior.Pattern = xlNone
Außerdem verwende ich gerne ein With-Statement, wenn es Sinn macht:
Der Code vom Bastler würde dann wie folgt aussehen:

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Cancel = True
With Target
  If .Column = 1 Then 'ANPASSEN
    With .Interior
      Select Case .Color
        Case vbWhite
          .Color = vbGreen
          .Parent.Value = "ja"
        Case vbGreen
          .Color = vbRed
          .Parent.Value = "nein"
        Case vbRed
          .Color = vbWhite
          .Pattern = xlNone
          .Parent.Value = ""
      End Select
    End With
  End If
End With
'passt die Spaltenbreite an ihren Inhalt an und zentriert ihn
Columns(1).AutoFit
Columns(1).HorizontalAlignment = xlCenter
End Sub

Gruß Ralf

 

Moin Ralf,
herzlichen Dank für den Tipp mit Pattern! Lässt mich künftig weniger Borders malen
Die doppelte With-Konstruktion ist natürlich erheblich eleganter als meine Fleißarbeit ...

Dann hätte man unten aber auch noch With Columns(1) nutzen können

Schönen Tach auch!

 

Hi,

folgender Code entspricht wohl eher dem, was ursprünglich gefordert war.

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
With Target
    If .Column = 9 Or .Column = 10 Then
        If .Value = "" Then
            .Value = "X"
            .Offset(, 1 + 2 * (.Column = 10)).ClearContents
        Else
            .ClearContents
            .Offset(, 1 + 2 * (.Column = 10)) = "X"
        End If
        Cancel = True
    End If
End With
End Sub

Wobei ich mich eher Detlef anschließen würde und Ja/Nein in einer einzigen Spalte schreiben würde. Am besten mit Ja/Nein aus einem Dropdown der Datenüberprüfung.

EDIT:
Wenn ich per VBA eine Hintergrundfarbe lösche, dann mit

Code:

Cells(1,1).Interior.ColorIndex = xlColorIndexNone

Ja, ColorIndex sollte man eigentlich nicht verwenden, aber das ist auch die einzige Gelegenheit, bei der ich das mache.