Office: Brüche mit kleinen Bruchzahlen

Hallo zusammen,
ich suche eine Lösung, Brüche in Excel mit kleinen Bruchzahlen darzustellen - ähnlich wie bei der Autokorrektur in Word.
Zur Illustration eine kleine Beispieldatei mit allen Anforderungen.
Gruß und DANKE!

 

Hallo yorcky,

Mit folgende Formel in E2 kann ich Deine Anforderungen realisieren. Allerdings sind dann die Ergebniswerte keine Zahlenwerte mehr sondern reine Textwerte. Rechnen solltest Du also weiter mit den Zahlenwerten in Spalte A.

=WENN(A2="";"";WENN(KÜRZEN(RUNDEN(4*A2; )/4;)=0;""&WECHSELN(VORZEICHEN(A2);1;"");KÜRZEN(RUNDEN(4*A2; )/4;))&" "&WECHSELN(ZEICHEN(WAHL(VERGLEICH(1+REST(RUNDEN(4*A2; )/4;1);{1;1,25;1,5;1,75};0);32;188;189;190));" ";" "))

und diese nach unten kopieren.

 

Hi,

zu spät, Werner war schneller. Aber will nicht für die Tonne gearbeitet haben und habe eine leicht andere Lösung:

Code:

=LET(a;A2;b;RUNDEN(4*a;)/4;c;WENN(b<0;"-";"");d;ABS(b);e;KÜRZEN(d;0);f;REST(d;1);c&WENN(e;e&" ";"")&WAHL(f*4+1;WIEDERHOLEN(" ";3);"¼";"½";"¾"))

den Faktor bei WIEDERHOLEN nach deinen Wünschen anpassen.
Oder auch

Code:

=LET(a;A2;b;RUNDEN(4*a;)/4;c;WENN(b<0;"-";"");d;ABS(b);e;KÜRZEN(d;0);f;REST(d;1);c&WENN(e;e&" ";"")&WENN(f;ZEICHEN(187+f*4);UNIZEICHEN(8192)))

Hier UNIZEICHEN(8192) anpassen. Die folgenden Zeichen 8193 etc. sind unterschiedlich breite Leerräume.

 

Hallo Helmut,

allerdings kann meine Formel selbst in einer noch antiquarischen Excelversion als meine XL2010 eingesetzt werden, während ich Deine Formel noch nicht einmal testen kann, weil ich neben Xl2010 nur noch XL2016 im Einsatz habe.

 

Hi,

die Formel lässt sich leicht auf ein veraltetes Excel anpassen: nur den letzten Term von LET() verwenden und dort alle "a" durch "A2", alle "b" durch "RUNDEN(4*a;)/4" ersetzen (hier das "a" auch ersetzen) etc. Ist eine reine Fleißarbeit.

Da fällt mit gerade ein: statt RUNDEN(4*a)/4 kann man auch VRUNDEN(a;0,25) verwenden.

 

Hallo Helmut,

ich brauch es nicht testen, ich glaube es Dir ja auch so und wenn man VRUNDEN() in der Formel einsetzt, würde ich dort 1/4 anstelle 0,25 einsetzen.

 

Moin!
Denke ich zu einfach?
Warum nicht einfach das Zahlenformat # ?/? in einer TEXT() nebst kleiner Wechselorgie nutzen?
=WECHSELN(WECHSELN(WECHSELN(TEXT(RUNDEN(4*A2; )/4;"# ?/?");"1/4";"¼");"1/2";"½");"3/4";"¾")


Gruß Ralf

 

Noch eine Anmerkung, warum ich nicht VRUNDEN() genommen habe.
Aus der Funktionshilfe:

Statt RUNDEN(4*A2; )/4
müsste dann VRUNDEN(A2;VORZEICHEN(A2)*1/4)
genommen werden.
Dann ist mir das "ungelenke" RUNDEN() lieber.

 

Hallo Ralf,

nein Du denkst nicht zu einfach, sondern richtig.
Meine auf die Schnelle zusammengestoppelte Formel liefert außerdem bei negativen Vorzeichen und -1/4 bzw -3/4 falsche Werte.

 

Guten Morgen an alle Excel-Experten!
Ganz herzlichen Dank für Eure Antworten! Ich bin sehr dankbar für Euer Schwarmwissen. Von einigen Formeln habe ich bislang noch nie gehört.
Gruß, Jürgen
P.S. Und ja, der kleine Fehler von Dir, neopa C, ist mir sogar auch schon aufgefallen... ;-)