Office: Brüche mit kleinen Bruchzahlen

Helfe beim Thema Brüche mit kleinen Bruchzahlen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, ich suche eine Lösung, Brüche in Excel mit kleinen Bruchzahlen darzustellen - ähnlich wie bei der Autokorrektur in Word. Zur... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von yorcky2, 13. Dezember 2022.

  1. yorcky2 Neuer User

    Brüche mit kleinen Bruchzahlen


    Hallo zusammen,
    ich suche eine Lösung, Brüche in Excel mit kleinen Bruchzahlen darzustellen - ähnlich wie bei der Autokorrektur in Word.
    Zur Illustration eine kleine Beispieldatei mit allen Anforderungen.
    Gruß und DANKE!
     
  2. neopa C hat Ahnung
    Hallo yorcky,

    Mit folgende Formel in E2 kann ich Deine Anforderungen realisieren. Allerdings sind dann die Ergebniswerte keine Zahlenwerte mehr sondern reine Textwerte. Rechnen solltest Du also weiter mit den Zahlenwerten in Spalte A.

    =WENN(A2="";"";WENN(KÜRZEN(RUNDEN(4*A2; )/4;)=0;""&WECHSELN(VORZEICHEN(A2);1;"");KÜRZEN(RUNDEN(4*A2; )/4;))&" "&WECHSELN(ZEICHEN(WAHL(VERGLEICH(1+REST(RUNDEN(4*A2; )/4;1);{1;1,25;1,5;1,75};0);32;188;189;190));" ";" "))

    und diese nach unten kopieren.
     
    Zuletzt bearbeitet: 13. Dezember 2022
  3. HKindler
    HKindler hat Ahnung
    Hi,

    zu spät, Werner war schneller. Aber will nicht für die Tonne gearbeitet haben und habe eine leicht andere Lösung:
    Code:
    =LET(a;A2;b;RUNDEN(4*a;)/4;c;WENN(b<0;"-";"");d;ABS(b);e;KÜRZEN(d;0);f;REST(d;1);c&WENN(e;e&" ";"")&WAHL(f*4+1;WIEDERHOLEN(" ";3);"¼";"½";"¾"))
    den Faktor bei WIEDERHOLEN nach deinen Wünschen anpassen.
    Oder auch
    Code:
    =LET(a;A2;b;RUNDEN(4*a;)/4;c;WENN(b<0;"-";"");d;ABS(b);e;KÜRZEN(d;0);f;REST(d;1);c&WENN(e;e&" ";"")&WENN(f;ZEICHEN(187+f*4);UNIZEICHEN(8192)))
    Hier UNIZEICHEN(8192) anpassen. Die folgenden Zeichen 8193 etc. sind unterschiedlich breite Leerräume.
     
    HKindler, 13. Dezember 2022
    #3
  4. neopa C hat Ahnung

    Brüche mit kleinen Bruchzahlen

    Hallo Helmut,

    allerdings kann meine Formel selbst in einer noch antiquarischen Excelversion als meine XL2010 eingesetzt werden, während ich Deine Formel noch nicht einmal testen kann, weil ich neben Xl2010 nur noch XL2016 im Einsatz habe.
     
  5. HKindler
    HKindler hat Ahnung
    Hi,

    die Formel lässt sich leicht auf ein veraltetes Excel anpassen: nur den letzten Term von LET() verwenden und dort alle "a" durch "A2", alle "b" durch "RUNDEN(4*a;)/4" ersetzen (hier das "a" auch ersetzen) etc. Ist eine reine Fleißarbeit.

    Da fällt mit gerade ein: statt RUNDEN(4*a)/4 kann man auch VRUNDEN(a;0,25) verwenden.
     
    HKindler, 13. Dezember 2022
    #5
  6. neopa C hat Ahnung
    Hallo Helmut,

    ich brauch es nicht testen, ich glaube es Dir ja auch so und wenn man VRUNDEN() in der Formel einsetzt, würde ich dort 1/4 anstelle 0,25 einsetzen.
     
  7. Moin!
    Denke ich zu einfach? Brüche mit kleinen Bruchzahlen *;)*
    Warum nicht einfach das Zahlenformat # ?/? in einer TEXT() nebst kleiner Wechselorgie nutzen?
    =WECHSELN(WECHSELN(WECHSELN(TEXT(RUNDEN(4*A2; )/4;"# ?/?");"1/4";"¼");"1/2";"½");"3/4";"¾")
    Brüche mit kleinen Bruchzahlen upload_2022-12-13_13-1-12.png

    Gruß Ralf
     
    Zuletzt bearbeitet: 13. Dezember 2022
    RPP63_neu, 13. Dezember 2022
    #7
    1 Person gefällt das.
  8. Brüche mit kleinen Bruchzahlen

    Noch eine Anmerkung, warum ich nicht VRUNDEN() genommen habe.
    Aus der Funktionshilfe:
    Statt RUNDEN(4*A2; )/4
    müsste dann VRUNDEN(A2;VORZEICHEN(A2)*1/4)
    genommen werden.
    Dann ist mir das "ungelenke" RUNDEN() lieber.
     
    RPP63_neu, 13. Dezember 2022
    #8
  9. neopa C hat Ahnung
    Hallo Ralf,

    nein Du denkst nicht zu einfach, sondern richtig.
    Meine auf die Schnelle zusammengestoppelte Formel liefert außerdem bei negativen Vorzeichen und -1/4 bzw -3/4 falsche Werte.
     
  10. yorcky2 Neuer User
    Guten Morgen an alle Excel-Experten!
    Ganz herzlichen Dank für Eure Antworten! Ich bin sehr dankbar für Euer Schwarmwissen. Von einigen Formeln habe ich bislang noch nie gehört.
    Gruß, Jürgen
    P.S. Und ja, der kleine Fehler von Dir, neopa C, ist mir sogar auch schon aufgefallen... ;-)
     
Thema:

Brüche mit kleinen Bruchzahlen

Die Seite wird geladen...
  1. Brüche mit kleinen Bruchzahlen - Similar Threads - Brüche Bruchzahlen

  2. Brüche nicht kürzen

    in Microsoft Excel Hilfe
    Brüche nicht kürzen: Liebes Forum! Ich habe eine bestehende Excel Tabelle (Excel 2000) wo ich in in vielen Zellen Brüche eingetragen habe (also 700/6300). Da dies in einer Zelle eingetragen ist wird es auch gleich...
  3. Anzeigen von Zahlen als Brüche

    in Microsoft Excel Tutorials
    Anzeigen von Zahlen als Brüche: Anzeigen von Zahlen als Brüche Excel für Microsoft 365 Excel 2019 Excel 2016 Excel 2013 Excel 2010 Excel 2007 Mehr... Weniger...
  4. Anzeigen von Datums-, Zeit- und Währungsangaben, Brüchen und Prozentsätzen

    in Microsoft Excel Tutorials
    Anzeigen von Datums-, Zeit- und Währungsangaben, Brüchen und Prozentsätzen: Anzeigen von Datums-, Zeit- und Währungsangaben, Brüchen und Prozentsätzen Excel für Microsoft 365 für Mac Excel 2019 für Mac Excel 2016 für Mac Excel für Mac 2011...
  5. aus 1/2 einen Bruch darstellen ??

    in Microsoft Excel Hilfe
    aus 1/2 einen Bruch darstellen ??: Hallo! Gibt es die Möglichkeit, wenn ich einen Bruch in ein Feld schreiben möchte (als Text) dass der so dargestellt wird, wie in Word. EXCEL 2016 Danke im Voraus für einen Hinweis! 348479
  6. Zähler und Nenner eines Bruches getrennt nutzen

    in Microsoft Excel Hilfe
    Zähler und Nenner eines Bruches getrennt nutzen: Hallo, weiß jemand wie ich in Excel nur mit dem Zähler eines Bruches weiterrechnen kann. Also wenn der Bruch z.B. 217/3 ist soll mit 217 gerechnet werden und in einem anderen Fall soll dann mit 3...
  7. Brüche verändern Größe im Text

    in Microsoft Word Hilfe
    Brüche verändern Größe im Text: Hallo, ich habe ein Problem beim Darstellen von Brüchen in Word 2010. Wenn ich einen Bruch als Formel ohne Text erstelle, dann ist dieser groß und lesbar. Sobald ich jetzt aber eine Nummerierung...
  8. Frage zur Darstellung von Brüchen in WORD

    in Microsoft Word Hilfe
    Frage zur Darstellung von Brüchen in WORD: Hallo, ich möchte/muss aufgrund eines einheitlichen Darstellungsschemas verschiedene Werte in Brüchen darstellen also zB: Alter "50 bis 70/65" wobei "50 bis 70" über dem Bruchstrich und "65"...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden