Office: (Office 2016) Button mit Hyperlink

Hallo Forum, hallo Beverly

ich schon wieder der Mampfred.
Für meine Übungen habe ich eine Mappe("Praxisbeispiele"). Für jede Übung ein Tabellenblatt.
Das erste Tabellenblatt ist als Inhaltsverzeichnis vorgesehen. Über eine Schleife lese ich die Namen der einzelnen Tabellenblätter ein und versehe sie mit einem Link. Soweit so gut.
in einem zweiten Schritt erhält jedes Tabellenblatt noch einen HomeButton, der mit einem Link zum Inhaltsverzeichnis versehen werden soll.
Hier mein erstes Problem: Wie muss der Link aussehen?
Der Codeteil

Code:

Address:="Inhaltsverzeichnis"

erzeugt eine Fehlermeldung: "Datei konnte nicht gefunden werden."

zweites Problem: Wenn das Inhaltsverzeichnis aktualisiert wird, wird ein neuer HomeButton über den bereits vorhandenen Button gelegt. Wie kann man das verhindern?

Kann mir jemand helfen?

Vielen Dank schon mal für euer Verständnis einem VBA-Rookie, der lernwillig ist, zu unterstützen.

der Mampfred

 

Hi,

weshalb muss es ein Link sein? Erstelle einfach ein kleines Makro der Art:

Code:

Sub Zurueck()
    Application.Goto reference:=Worksheets("Inhaltsverzeichnis").Range("A1")
End Sub

und weise dieses Makro dem erstellen Button zu.

Wenn neue Blätter dazukommen, wird mit deinem Code nicht nur ein neuer Button in den bereits vorhandenen Blättern erstellt sondern sie werden im Blatt Inhaltsverzeichnis auch noch einmal eingetragen. Wenn du jedoch vorher erst prüfst, ob sie bereits vorhanden sind und sie übergehst, falls dem so ist, wird das Problem mit dem erneuten Einfügen eines Buttons und auch die Mehrfachauflistung im Blatt Inhaltsverzeichnis verhindert.
Außerdem kannst du das Erstellen der Hyperlinks in Spalte B gleich beim Eintrag der Blattnamen erledigen.

All dies berücksichtigt ergibt das folgenden Code (plus das oben gepostete Makro):

Code:

Sub Sammlungen()
    Dim rngBlatt As Range
    Dim wsTabBlatt As Worksheet
    Dim lngZaehler As Long
    Dim picHome As Picture
    With Worksheets("Inhaltsverzeichnis")
        For Each wsTabBlatt In Sheets
            If wsTabBlatt.Name <> "Inhaltsverzeichnis" Then
                Set rngBlatt = .Columns(2).Find(wsTabBlatt.Name, lookat:=xlWhole, LookIn:=xlFormulas)
                If rngBlatt Is Nothing Then  '<== Blatt ist noch nicht vorhanden
                    lngZaehler = .Cells(Rows.Count, 2).End(xlUp).Row + 1  '<== erste freie Zeile in Spalte B
                    .Cells(lngZaehler, 2) = wsTabBlatt.Name
                    .Cells(lngZaehler, 2).Hyperlinks.Add _
                        Anchor:=.Cells(lngZaehler, 2), Address:="", _
                        SubAddress:=wsTabBlatt.Name & "!A1"
                    lngZaehler = lngZaehler + 1
                    With wsTabBlatt.pictures.Insert("L:\Office Anwendungen\Excel\Bilder\house-green-home-button.png")
                        .Top = 0
                        .Left = 0
                        .Width = 50
                        .OnAction = "Zurueck"  '<== Makro dem Bild zuweisen
                    End With
                End If
            End If
        Next wsTabBlatt
    End With
End Sub

---

 

Hi Beverly, hi Forum

ich glaube ich habe schon einmal gesagt"Du bist die Beste!"
Das kann ich nur wiederholen.Vielen Dank
Für heute habe ich dann genug Stoff zum Nacharbeiten.
Das Teil läuft jetzt super, genau wie ich es mir vorgestellt habe.

Nochmals vielen Dank. Bis demnächst beim nächsten Problem. Bleib gesund.

der Mampfred