Office: CheckBoxen umbenennen

Hallo liebe Gemeinde,

Ich habe folgendes Problem:
ich kann meine CheckBoxen nicht umbenennen. da kommt dann immer eine Fehlermeldung:

"Laufzeitfehler 438, Objekt unterstützt diese Eigenschaft nicht...."

Soweit funktioniert bisher der Code, nur wenn ich den Namen anspreche steigt er aus.
Für eine weitere Verarbeitung brauche ich aber die Namen der Checkboxen, weiß aber im Moment nicht weiter.


und so sieht mein Code aus:
Sub checkBox()
Dim rngJahr As Range
Dim rngMonat As Range
Dim j As Integer
Dim m As Integer
Dim S As Object
Dim T As Object

Dim shpCHK As Object
'erstmal alle vorhandenen CHK löschen
For Each shpCHK In ActiveSheet.Shapes
If shpCHK.Name Like "Check*" Then
shpCHK.Delete
End If
Next

Set rngJahr = ActiveSheet.Range("A1:A1000")
Set rngMonat = ActiveSheet.Range("C1:C1000")

With ActiveSheet

For j = 1 To rngJahr.Rows.Count

If rngJahr.Cells(j, 1).Value "" Then

Set S = .OLEObjects.Add(ClassType:="Forms.CheckBox.1", Link:=False, _
DisplayAsIcon:=False, Left:=.Cells(j, 5).Left, _
Top:=.Cells(j, 5).Top).Object
S.Caption = rngJahr.Cells(j, 1).Value & "alle"
S.Name = "Check" & rngJahr.Cells(j, 1).Value
End If

Next j

For m = 1 To rngMonat.Rows.Count

If rngMonat.Cells(m, 1).Value "" Then

Set T = .OLEObjects.Add(ClassType:="Forms.CheckBox.1", Link:=False, _
DisplayAsIcon:=False, Left:=.Cells(m, 6).Left, _
Top:=.Cells(m, 6).Top, Width:=ActiveCell.Width, Height:=ActiveCell.Height).Object
T.Caption = ""
T.Name = "Check" & rngMonat.Cells(m, 1).Value
End If

Next m

End With


End Sub

vielen Dank schon mal im Voraus
und Gruß Ute

:)

 

Hallo,

so besser?

Sub checkBox()
Dim rngJahr As Range
Dim rngMonat As Range
Dim j As Long
Dim m As Long
Dim S As OLEObject
Dim T As OLEObject

Dim shpCHK As OLEObject

'erstmal alle vorhandenen CHK löschen
For Each shpCHK In ActiveSheet.OLEObjects
If shpCHK.Name Like "Check*" Then
shpCHK.Delete
End If
Next

Set rngJahr = ActiveSheet.Range("A1:A1000")
Set rngMonat = ActiveSheet.Range("C1:C1000")

With ActiveSheet

For j = 1 To rngJahr.Rows.Count

If rngJahr.Cells(j, 1).Value <> "" Then

Set S = .OLEObjects.Add(ClassType:="Forms.CheckBox.1", Link:=False, _
DisplayAsIcon:=False, Left:=.Cells(j, 5).Left, _
Top:=.Cells(j, 5).Top)
S.Object.Caption = rngJahr.Cells(j, 1).Value & "alle"
S.Name = "Check" & rngJahr.Cells(j, 1).Text
End If

Next j

For m = 1 To rngMonat.Rows.Count

If rngMonat.Cells(m, 1).Value <> "" Then

Set T = .OLEObjects.Add(ClassType:="Forms.CheckBox.1", Link:=False, _
DisplayAsIcon:=False, Left:=.Cells(m, 6).Left, _
Top:=.Cells(m, 6).Top, Width:=ActiveCell.Width, Height:=ActiveCell.Height)
T.Object.Caption = ""
T.Name = "Check" & rngMonat.Cells(m, 1).Text
End If

Next m

End With


End Sub

 

Hallo,
ne leider nicht, kommt die gleiche Fehlermeldung.

 

Hallo,

kann ich nicht nachvollziehen. Mein Code läuft ohne Fehlermeldung durch und legt entsprechend den Einträgen in Spalte A und C die Checkboxen an.

Teste mal mit meiner Mappe:

 

Hallo Nepomuk,
Sorry, mein Fehler.
Da hab ich mich jetzt von dem Eigenschaftenfenster verarschen lassen. Wenn ich mir die Namen im Debug.Print ausgeben lasse, ist alles so wie es sein soll.
Ich danke Dir und wünsche ein sonniges Wochenende

Gruß Ute

 

Hallo Ute,

dann lad mal deine Mappe mit ein paar Testdaten hoch.

 

Hallo Nepumuk,

ich hatte erst noch selber nach einer Lösung gesucht, nehme jetzt aber liebend gerne das Angebot an

Gruß Ute

 

Hallo Ute,

der Code in deiner Testmappe läuft ohne Fehlermeldung bei mir durch und die Checkboxen werden erstellt.

 

Hallo Nepumuk,
ich habe jetzt alle Sonderzeichen entfernt, nun klappt es. Ich Danke dir für Deine Mühe.

Gruß Ute