Office: Code von 32-Bit auf 64-Bit umschreiben

Faultier_1982 · 7. Juni 2014

Hallo

Ich habe vor längerer Zeit einen Code aus dem Internet gefunden, mit dem ich in einer neuen Aplication eine Arbeitsmappe öffnen kann.

Jetzt stelle ich fest, dass dieser Code auf ein System mit 32-Bit ausgelegt wurde. Da ich jetzt aber ein 64-Bit System mit mit 64-Bit Office müsste man einen Teil des Codes umschreiben. ich wüsste jetzt aber nicht, wie ich anfangen müsste.

Code:

Private Declare Function GetClassName Lib "user32.dll" Alias "GetClassNameA" ( _
ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long
Private Declare Function EnumWindows Lib "user32.dll" ( _
ByVal lpEnumFunc As Long, _
ByVal lParam As Long) As Boolean
Private Declare Function EnumChildWindows Lib "user32.dll" ( _
ByVal hWndParent As Long, _
ByVal lpEnumFunc As Long, _
ByVal lParam As Long) As Long
Private Declare Sub IIDFromString Lib "ole32.dll" ( _
ByVal lpsz As String, _
ByRef lpiid As GUID)
Private Declare Sub AccessibleObjectFromWindow Lib "oleacc.dll" ( _
ByVal hwnd As Long, _
ByVal dwId As Long, _
ByRef riid As GUID, _
ByRef ppvObject As Any)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bin um jeden Vorschlag dankbar....

Gruß

:)

EarlFred · 9. Juni 2014

Hallo Gruß,

in einer neuen Aplication eine Arbeitsmappe öffnen
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

dafür braucht man doch diesen ganzen Krempel nicht!?

Beschreib doch mal in 2 Sätzen mehr, was Du denn mit dem Code bezweckst. Nach Deiner Beschreibung klingt das nach 2-3 Zeilen Code und nicht mehr.

Grüße
EarlFred

Faultier_1982 · 9. Juni 2014

Hallo

JA meine Beschreibung war natürlich nur sehr oberflächlich.

Also.....
Ich habe im Taskmanager eine Task geplant, das zu einer bestimmten Uhrzeit eine Datei öffnet "Automatik.xlsm" die dann eine Excel-Datei "Internet.xlsm" öffnen soll um etwas aus dem Internet zu kopieren.

Das Problem dabei ist, dass es sein kann, dass diese Datei "Internet.xlsm" bereits geöffnet ist und deshalb nicht noch mal geöffnet werden darf. Eine normalen Abfrage, ob die Datei bereits geöffnet ist, war nicht möglich, weil die Datei, die über den Taskmanager geöffnet wird in einer anderen "Aplikation" geöffnet wurde und deshalb nicht erkennt, dann in einer anderen Applikation diese Datei bereits geöffnet ist.

Deshalb brauchte ich den Code, der alle Excel-Dateien erkennt, die geöffnet sind und die geöffnete Datei anspricht, wenn sie bereits offen ist.

Wenn es eine einfacherere Lösung gibt, würde ich mich natürlich freuen.....

Gruß

Nepumuk · 9. Juni 2014

Hallo,

kann es nicht testen, sollte aber so passen:

Code:

Private Declare PtrSafe Function GetClassNameA Lib "user32.dll" ( _
ByVal hwnd As LongPtr, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long
Private Declare PtrSafe Function EnumWindows Lib "user32.dll" ( _
ByVal lpEnumFunc As LongPtr, _
ByVal lParam As LongPtr) As Long
Private Declare PtrSafe Function EnumChildWindows Lib "user32.dll" ( _
ByVal hWndParent As LongPtr, _
ByVal lpEnumFunc As LongPtr, _
ByVal lParam As LongPtr) As Long
Private Declare PtrSafe Sub IIDFromString Lib "ole32.dll" ( _
ByVal lpsz As String, _
ByRef lpiid As GUID)
Private Declare PtrSafe Sub AccessibleObjectFromWindow Lib "oleacc.dll" ( _
ByVal hwnd As LongPtr, _
ByVal dwId As Long, _
ByRef riid As GUID, _
ByRef ppvObject As Any)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

EarlFred · 9. Juni 2014

Hallo Gruß,

das geht über
Code:

Set gesMappe = GetObject(, "pfad&dateiname")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

solange wir vom gleichen Rechner sprechen, auf dem die Datei offen ist: Wenn offen, wird die Datei auch in anderen Excel-Instanzen gefunden, andenfalls geöffnet.
Über das Objekt ist die Mappe auch ansprech- und steuerbar

Grüße
EarlFred

Nepumuk · 9. Juni 2014

Hallo,

Wenn offen, wird die Datei auch in anderen Excel-Instanzen gefunden
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Aber nur wenn die Mappe in der zuerst geöffneten Excel-Instanz geladen ist. Denn nur auf die kannst du per GetObject zugreifen.

EarlFred · 10. Juni 2014

\@Nepumuk,
das gilt für die Instanz selbst. Bei einer Mappe greift diese Einschränkung interessanterweise nicht: Sie wird in jeder beliebigen Instanz gefunden.

In der Codezeile war allerdings ein Fehler (man sollte in meinem Alter nichts aus dem "Kopf" schreiben *wink.gif*). Richtig ist:
Code:

Set gesMappe = GetObject("pfad&dateiname")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Um sicherzugehen, dass ich nicht auf dem Holzweg bin, habe ich folgenden Code zum Testen hergenommen:
Code:

Option Explicit

Sub test()
Dim i As Byte, Vorgabe As Byte
Dim xlsApp(0 To 4) As Excel.Application
Dim wbGefunden As Workbook

'anpassen - beliebige Testmappe
Const cStrTestfile As String = "C:\temp\test.xls"

For i = 0 To 4
Set xlsApp(i) = New Excel.Application
Next i

For Vorgabe = 0 To 4
xlsApp(Vorgabe).Workbooks.Open (cStrTestfile)

Set wbGefunden = GetObject(cStrTestfile)
If Not wbGefunden Is Nothing Then
wbGefunden.Close savechanges:=False
Debug.Print "Gefunden in Instanz " & Vorgabe
End If
Set wbGefunden = Nothing
Next Vorgabe

For i = 0 To 4
xlsApp(i).Quit
Set xlsApp(i) = Nothing
Next i

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Faultier_1982 · 10. Juni 2014

Das hört sich ja gut an, Ich habe in der Regel nur eine Instanz geöffnet und über den Taskmanager würde die zweite Instanz geöffnet werden.

Dann könnte man abfragen, ob in der ersten Instanz bereit die Arbeitsmappe offen ist und dort dann das gewünschte Makro starten.
Und wenn nicht offen, dann eben in der zweiten Instanz öffnen und Makros starten.

Wäre so wäre es möglich oder wie müsste man es dann machen???

Gruß

EarlFred · 10. Juni 2014

Hallo Gruß,

Dann könnte man abfragen, ob...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

genau das macht die eine Codezeile, wie beschrieben. Weitere "Abfragen" sind nicht nötig. Einschränkungen: Wie vor genannt. Zusätzlich prüfen sollte man, ob die Datei auf einem anderen Rechner offen ist (falls möglich) und ob die Datei am angegebenen Pfad überhaupt existiert.

Auch wenn die vorgeschlagene Codezeile noch zu korrigieren war, stimmt diese Anmerkung weiterhin:

Über das Objekt ist die Mappe auch ansprech- und steuerbar
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Um die Prozedur "Startemich" im Modul "Modul1" der gesuchten Mappe auszuführen:
Code:

Option Explicit

Sub so()

Dim gesMappe As Excel.Workbook
Set gesMappe = GetObject("C:\temp\test.xls")

'bei Bedarf
gesMappe.Application.Visible = True
gesMappe.Windows(1).Visible = True

gesMappe.Application.Run gesMappe.Name & "!Modul1.startemich"

'weiterer Code

Set gesMappe = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Faultier_1982 · 12. Juni 2014

Hallo

Welche der Zeilen prüft ob die Arbeitsmappe in einer anderen Instanz bereits geöffnet ist und was genau prüfen oder machen die beiden Zeilen "bei Bedarf

Wo kann man denn eine genauere Beschreibung darüber nachlesen?

Gruß

Faultier_1982 · 14. Juni 2014

Hallo

Bin schon recht weit gekommen mit meinem Code, was jetzt noch nicht klappt ist, dass ich die Datei, die mit GetObject geöffnet wurde, am ende des Codes wieder automatisch schließen lasse.

Ich habe es so bereits versucht, aber ohne Erfolg:
Code:

gesMappe.Close savechanges:=False
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

So hat es zwar geklappt, es wurden aber komplett alle geöffnete Dateien geschlossen.
Code:

Application.Quit
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

So habe ich es auch versucht, die Datei wurde zwar geschlossen, danach kamm aber die Fehlermeldung "Object erforderlich"
Code:

gesMappe.Quit
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß

EarlFred · 14. Juni 2014

Hallo Gruß,

was heißt das?

aber ohne Erfolg
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das ist keine Fehlerbeschreibung, mit der man etwas anfangen kann.

Grüße
EarlFred

Faultier_1982 · 16. Juni 2014

sorry das stimmt, habe das Problem inzwischen lösen können.

vielen Dank Gruß

Office: Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben

Code von 32-Bit auf 64-Bit umschreiben - Similar Threads - Code Bit Bit

Per Hyperlink ausgeblendetes Blatt einblenden

Code wird nicht komplett ausgeführt

Code von 32-Bit auf 64-Bit umschreiben

Fehler im code bei Umstieg auf Excel 64 bit

Umstellung auf Windows 64 bit, Code-Anpassung

Office 365 64 Bit-Version, VBA-Code funktioniert nicht mehr

Code für 64 Bit System aktualisieren