Office: Collection: Schlüssel/Wert vorhanden?

Hey Amigos, wie geht's?

Ich möchte herausfinden, ob eine Collection ein bestimmtes Schlüssel-Wert-Paar enthält. Natürlich läßt sich das auch wüst über Fehlerbehandlung und deren Sprungmarken "lösen", aber das scheint mir irgendwie nicht die beste Lösung. Gibt es einen besseren Weg?

Vielen Dank für eure Antworten!
Gruß,
/dev

:)

 

Hi,

Du kommst M.E. nicht an die Keys einer Collection ran.

1. Nimm ein Dictionary-Objekt, da geht das.

http://msdn.microsoft.com/library/de...67a747c8db.asp

2. Erstelle eine Klasse mit 2 Variablen Key & Value und den entsprechenden Let/Get-Properties dazu.
In der Collection fügst Du nun Elemente dieser Klasse hinzu. Den Key der Collection setzt Du dabei gleich mit dem Key der Klasse.

cu, Bernd
--
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub x()
Dim col As Collection, keyval As clsKeyVal, i As Integer

Set col = New Collection

colAdd col, "Key1", "Hallo"
colAdd col, "Key2", 100
colAdd col, "Key3", Now
Debug.Print colAdd(col, "Key1", "Hoppla")

For Each keyval In col
Debug.Print keyval.Key, keyval.Value
Next

For i = col.Count To 1 Step -1
col.Remove i
Next
End Sub

Function colAdd(col As Collection, Key As String, v As Variant) As Boolean
Dim i As Integer
Dim keyval As clsKeyVal

colAdd = False
For i = 1 To col.Count
If col(i).Key = Key Then Exit Function
Next
Set keyval = New clsKeyVal
keyval.Key = Key
keyval.Value = v
col.Add keyval, Key
colAdd = True
End Function

' **********************************************************************
' Modul: clsKeyVal Typ: Klassenmodul
' **********************************************************************

Option Explicit

Private myKey As String
Private myVal As Variant

Property Get Key() As String
Key = myKey
End Property

Property Let Key(newKey As String)
myKey = newKey
End Property

Property Get Value() As Variant
Value = myVal
End Property

Property Let Value(newVal As Variant)
myVal = newVal
End Property

Private Sub Class_Initialize()
Debug.Print "clsKeyVal.Initialize"
End Sub

Private Sub Class_Terminate()
Debug.Print "clsKeyVal.Terminate"
End Sub