Office: (Office 365) CSV Verbindung ergänzt neue Spalten nicht

Hallo zusammen

Ich habe eine csv-Datei über "Daten abrufen - Aus Datei - Aus Text/CSV" in mein Excelfile verknüpft. Nun wird diese csv-Datei regelmässig überschrieben, die Werte aktualisiert und Spalten ergänzt. Die überarbeiteten Werte werden nach "Alle aktualisieren" in Excel auch richtig korrigiert, die neuen Spalten werden aber nicht erkannt bzw. hinzugefügt. Woran liegt das?

Vielen Dank im Voraus

 

Hallo dudinger,

da bist Du auf eine sehr beliebte Schwachstelle von PQ gestoßen, denn die Spalten, die einbezogen werden, ist im M-Code sehr statisch und muß entsprechend nachbehandelt werden.
Aber ohne csv-Demodatei und Deinem bisherigen M-Code kann man da nur wenig helfen.

Gruß von Luschi
aus klein-Paris

 

Hallo Luschi

Danke für deine Antwort. Ich habe in der Zwischenzeit im Power Query-Code folgenden Eintrag gefunden: "Columns=37"
Wenn ich den Eintrag entferne, wird meine Liste komischerweise auf 23 Spalten reduziert.
Ich habe ihn vorerst auf "Columns=100" geändert. Damit sollte ich mal arbeiten können.

Gibt es eine elegantere Möglichkeit um die Anzahl variabel zu definieren?

Merci

 

Hallo dudinger,

hier mal mein PQ!-Beispiel dazu:

Code:

let
    //Columns=100 ist absichtlich so hoch (oder noch höher setzen)
    pfad = "E:\Daten\Excel\PowerQuery\...\CSV\LeuteAZN1.csv",
    Quelle = Csv.Document(File.Contents(pfad),
        [Delimiter=",", Columns=100, Encoding=65001, QuoteStyle=QuoteStyle.None]),
    //alle Spaltennamen der csv-Datei (Column1 .. Column100)   
    #"alle SpaltenNamen" = Table.ColumnNames(Quelle),
    /* in der 1. Zeile stehen die eigentlichen Spaltennamen
       in den Spalten, die ja eigentlich zuviel sind ist diese Angabe leer
       und diese Spaltennamen werden ermittelt
    */
    #"leere Spalten" = List.Accumulate(
            #"alle SpaltenNamen",
            {},
            (st, cur) => if Table.Column(Quelle,cur){0}=""
                         then st & {cur}
                         else st   
    ),
    //leere Spalten löschen
    #"Entfernte Spalten" = Table.RemoveColumns(Quelle, #"leere Spalten"),

    //und erst jetzt den Header heraufsetzen!!!
    #"Höher gestufte Header" = Table.PromoteHeaders(#"Entfernte Spalten", [PromoteAllScalars=true])
    
    /*diesen PQ-Schritt so weit wie möglich nach hinten verschieben
      #"Geänderter Typ" = Table.TransformColumnTypes(#"Höher gestufte Header",
        {{"Position", Int64.Type}, {"Const", type text}, {"Created", type date},
         {"Modified", type date},  {"Description", type text}, {"Name", type text},
         {"Known For", type text}, {"Birth Date", type date}
        })
    */

in

    #"Höher gestufte Header"

Gruß von Luschi
aus klein-Paris