Office: (Office 2007) Datei aus einem Ordner öffnen

Guten Tag in die Runde,

mit einem Click-Button von einer userform öffnen ich einen Ordner, in dem sich Dateien befinden.
Das klappt mit der folgenden Prozedur einwandfrei:

Sub öffnen()
Dim Monat As String
Dim Jahr As Integer

Monat = Month(Now)
Monat = Format(Now, "MM")
Jahr = Year(Now)

Shell "Explorer.exe S:\Fibu\CTS\Buchhaltungsstatistik\" & Monat & "." & Jahr & "\", vbNormalFocus

End Sub

Wenn ich jetzt eine Datei aus dem Ordner auswähle und mit einem Doppel-Click öffnen will, verschwindet der geöffnete Ordner und die Datei wird nicht geöffnet.
Wie muss ich die Prozedur ändern oder erweitern, damit ich die ausgewählte Datei öffnen und mit dieser weiter arbeiten kann?

Vielen Dank für Tipps und Hilfe vorab.

Gruß
Angela

 

Hi Angela,

versuche es mal nach diesem Prinzip:

Code:

Sub DateienAuswaehlenEine()
   Dim strDatei As String
   Dim fdDialog As FileDialog
   Set fdDialog = Application.FileDialog(msoFileDialogFilePicker)
   With fdDialog
      .Filters.Add "Excel-Dateien", "*.xlsx; *.xlsm; *.xls", 1  '<== evtl. Dateiendungen anpassen
      .InitialFileName = "I:\Z_Test\" '<== Pfad anpassen
      .Title = "Bitte Datei auswählen"
      .AllowMultiSelect = False         ' kein Multiselect
      .ButtonName = "Auswahl"
      If .Show = -1 Then
         strDatei = .SelectedItems(1)
      End If
   End With
   If strDatei <> "" Then Workbooks.Open strDatei
   Set fdDialog = Nothing
End Sub

Bis sopäter,
Karin

 

Hi Karin,

vielen Dank, das hat auf Anhieb geklappt.

LG
Angela