Office: (Office 2019) Datei vor dem verschieben prüfen, ob vorhanden

Hallo allerseits,

ich, als VBA Anfänger, bastel nun schon länger an einer Lösung herum, leider ohne Erfolg.

Ich habe eine Liste mit Dateinamen. Das Programm soll diese Dateien aus dem Ordner in einen Überordner verschieben. Das bekomme ich mit meinem Code auch hin.
Gerne würde ich vor dem Verschieben überprüfen, ob die Datei schon vorhanden ist. Und da liegt der Knackpunkt. Ich habe da schon vieles versucht, aber nichts hat funktioniert. Könnt Ihr mir einen Lösungsansatz geben?

Das ist mein Code der lediglich die Dateien verschiebt:

Code:

For n = 1 To WkSh_Z.Cells(Rows.Count, 1).End(xlUp).Row

    If Sheets("verschieben").Cells(n, 1).Value > 0 Then
        
        FSO.MoveFile quelle & "\" & Sheets("verschieben").Cells(n, 1).Value, ziel & "\" & Sheets("verschieben").Cells(n, 1).Value
        
    End If
    
Next

Vielen Dank vorab für Eure Unterstützung.

Mfg
Andy

 

Hallo,

Code:

Option Explicit
Public Sub testSub()

   Dim WkSh_Z As Worksheet
   Dim FSO As New FileSystemObject
 
   Dim Quelle As String, Ziel As String
   Dim QuellDatei As String, ZielDatei As String, DateiNameN As String
   Dim n As Long
 
   Set WkSh_Z = Worksheets("Arbeitsblatt XY")   '<--- Anpassen!
   Quelle = "C:\Quellpfad"                      '<--- Anpassen!
   Ziel = "D:\Zielpfad"                         '<--- Anpassen!
 
   For n = 1 To WkSh_Z.Cells(Rows.Count, 1).End(xlUp).Row
 
       DateiNameN = Sheets("verschieben").Cells(n, 1).Value
       QuellDatei = Quelle & "\" & DateiNameN
       ZielDatei = Ziel & "\" & DateiNameN
    
       If DateiNameN > 0 Then                  '<--- Was soll das bedeuten?
           If FSO.FileExists(ZielDatei) Then
             MsgBox "Die Zieldatei " & ZielDatei & " existiert bereits."
             '....
             '....
           Else
             FSO.MoveFile QuellDatei, ZielDatei
           End If
       End If
    
   Next n

   Set FSO = Nothing
End Sub

Mir ist nicht klar, was in der IF-Zeile der Test bedeutet, dass der Dateiname größer 0 sein soll.

 

Hi,

du kannst mittels Dir prüfen, ob eine Mappe bereits vorhanden ist - nach diesem Prinzip:

Code:

    If Dir(Pfad & Dateiname & Dateiendung) = "" Then
        '... hier deinen Code zum Verschieben
    End If

---

 

Danke @Exl121150,

ich muss sagen, so ähnlich hatte ich es auch schon probiert, aber nicht hinbekommen. Jetzt funktioniert es wunderbar. Dass er erst prüft, ob der Zellwert größer 0 ist, war noch ein Überbleibsel, was sich ja mit der Prüfung:
For n = 1 To WkSh_Z.Cells(Rows.Count, 1).End(xlUp).Row erledigt hatte. Habe es jetzt herausgenommen.

Vielen Dank dir.

Auch dir eine Dankeschön @Karin für deine Gedanken.

Mfg Andy