Office: (Office 2010) Dateieigenschaften lesen

VBA_Programmierer · 28. Oktober 2013

Hallo zusammen,

ich habe ein kleines Problem. Ich will mit einem VBA Makro Dateieigenschaften von verschiedenen Dateien auslesen.
Dazu habe ich eine Rekursiv Funktion geschrieben, die die einzelnen Ordner aufruft und durchläuft.

Aus der Rekursiv Funktion rufe ich dann diese Funktion auf:
Code:

Public Function CreateList(Working_Path As String)

Const STRFOLDER As String = "D:/Testordner" ' Funktioniert
STRFOLDER = Working_Path ' Funktioniert nicht

Dim objShell As Object
Dim objFolder As Object
Dim x As Byte
Dim spalte As Integer
Dim zeile As Long
Dim varName, arrHeaders(100)

If Dir(STRFOLDER, 16) = "" Then
MsgBox "Der Ordner " & STRFOLDER & " wurde nicht gefunden!" & Space(10), 64, "weise hin..."
Exit Function
End If

'Application.ScreenUpdating = False
Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(STRFOLDER)

spalte = 1

For x = 0 To 100
arrHeaders(x) = objFolder.GetDetailsOf(varName, x)
Cells(1, spalte + x) = arrHeaders(x)
Next

Rows(1).Font.Bold = True
zeile = 2

For Each varName In objFolder.Items
For x = 0 To 100
Cells(zeile, spalte + x) = objFolder.GetDetailsOf(varName, x)
Next
zeile = zeile + 1
Next

Columns.AutoFit
'Application.ScreenUpdating = True
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Variante 1: mit der String Constante würde funktionieren
Variante 2: mit dem wechselnden Pfad Ordner -> Unterordner funktioniert nicht.

Kann mir einer sagen warum das nicht geht und wie ich das umschreiben muss damit es funktioniert?

Vielen Dank im Voraus
Mit freundlichen Grüßen
Timo

:)

HS(V) · 30. Oktober 2013

Edit: Falsch gelesen.

bst · 30. Oktober 2013

Morgen,

versuche mal:

Code:

Set objFolder = objShell.Namespace("" & STRFOLDER & "")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

oder nimm eine Variable vom Typ Variant der Du den String zuweist.

Code:

varFolder = CVar(STRFOLDER)
Set objFolder = objShell.Namespace(varFolder)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Nachtrag:

Code:

Set objFolder = objShell.Namespace((STRFOLDER))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

sollte auch funktionieren.

cu, Bernd

haklesoft · 31. Oktober 2013

Hallo Timo,

so könnte es in purem Excel-VBA gehen: Code:

Sub ListDetailsOf(Working_Path As String)
'Hinweis: Verweis auf Shell32.dll muss gesetzt sein
Dim objShell As Shell
Dim objFolder As Folder
Dim objFolderItem As FolderItem
Dim sFolder As String
Dim i As Integer
Dim iSpalte As Integer

Const ciMAX As Integer = 300 'für Win 7

Const csFOLDER As String = "D:\Testordner"

sFolder = Working_Path
If Len(sFolder) < 1 Or Dir(sFolder, 16) = "" Then
sFolder = csFOLDER
If Dir(sFolder, 16) = "" Then
MsgBox "Der Ordner " & sFolder & " wurde nicht gefunden!" & Space(10), 64, "weise hin..."
Exit Sub
End If
End If

Application.ScreenUpdating = False
Set objShell = New Shell
Set objFolder = objShell.NameSpace(sFolder)

If (Not objFolder Is Nothing) Then
iSpalte = iSpalte + 1
'Header listen
For i = 0 To ciMAX
Cells(i + 1, iSpalte) = objFolder.GetDetailsOf("", i)
Next
'Details auflisten
For Each objFolderItem In objFolder.Items
iSpalte = iSpalte + 1
For i = 0 To ciMAX
Cells(i + 1, iSpalte) = objFolder.GetDetailsOf(objFolderItem, i)
Next i
Next
Set objFolderItem = Nothing
End If
Set objFolder = Nothing
Set objShell = Nothing

Columns.AutoFit
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: (Office 2010) Dateieigenschaften lesen

Dateieigenschaften lesen

Dateieigenschaften lesen

Dateieigenschaften lesen

Dateieigenschaften lesen - Similar Threads - Dateieigenschaften

ListFilenames_FSO_Star

Verwenden von Zellwerten als benutzerdefinierte Excel-Dateieigenschaft zur Unterstützung der ...

Dateieigenschaften auslesen: Datumswerte

MP3 Dateieigenschaften (TAGs) auslesen