Office: Dateipfadangabe aus einer Zelle beziehen

Hallo Leute,
ich habe 0 Erfahrung mit VBA.
Folgenden Code hab ich im Netz gefunden:

Sub BilderEinfuegen()
For Each shp In ActiveSheet.Shapes
If shp.Type = msoPicture Then shp.Delete
Next
Dim Pfad As String, Wiederholungen As Long
Pfad = "G:\WPS2013\Bilder\Stapler\"
For Wiederholungen = 1 To Range("A65345").End(xlUp).Row
If Dir(Pfad & Cells(Wiederholungen, 1) & ".jpg") <> "" Then
With ActiveSheet.Pictures.Insert(Pfad & Cells(Wiederholungen, 1) & ".jpg")
.Top = 200
.Left = 90
.Width = 200
.Height = 200
.Placement = xlMoveAndSize
End With
End If
Next
End Sub

Es werden Bilder automatisch in die Tabelle geladen.
Das Funktioniert auch gut.

1. Ich möchte nun den Pfad, wo die Bilder hinterlegt sind, aus einer Zelle (z.B. "M1") in das VBA-Skript übernehmen.

2. die Übernahme des Dateinames funktioniert nur aus Zelle A1. Was muss geändert werden um die Zelle G8 anzusprechen?

3. Das selbe Macro möchte ich dann noch in anderen Tabellen der Datei anwenden, wo halt ein anderer Dateipfad benötigt wird.

Schon mal vielen Dank im Vorraus


Gruß
tuempeltaucher

 

Hi,

Frage 2 ist unklar - ich interpretiere sie so: der Bildname soll nicht aus Spalte A entnommen werden sondenr aus Spalte G und nicht beginnend nicht ab Zeile 1 sondern Zeile 8

Zu Frage 3: wieviele Tabellenblätter enthält die Mappe und wie ist festgelegt, in welche davon die Bilder eingefügt werden sollen und in welche nicht?

Hier ein ungetesteter Code, der von meiner o.a. Interpretation der Fage 2 ausgeht und in alle Tabellenblätter der Arbeitsmappe Bilder einfügt:

Code:

Sub BilderEinfuegen()
    Dim Pfad As String, Wiederholungen As Long
    Dim shp As Shape, wksTab As Worksheet
    For Each wksTab In Worksheets
        If wksTab.Shapes.Count > 0 Then
            With wksTab
                For Each shp In .Shapes
                    If shp.Type = msoPicture Then shp.Delete
                Next shp
                Pfad = .Range("M1")
                For Wiederholungen = 8 To .Range("G65345").End(xlUp).Row
                    If Dir(Pfad & .Cells(Wiederholungen, 7) & ".jpg") <> "" Then
                        With .Pictures.Insert(Pfad & .Cells(Wiederholungen, 7) & ".jpg")
                            .Top = 200
                            .Left = 90
                            .Width = 200
                            .Height = 200
                            .Placement = xlMoveAndSize
                        End With
                    End If
                Next Wiederholungen
            End With
        End If
    Next wksTab
End Sub

Bis später,
Karin

 

Danke Karin,
funktioniert super im Tabellenblatt 1.

Ich habe zur Zeit 7 Tabellen in der Arbeitsmappe. In jeder Tabelle rufe ich Daten und ein Bild zu einem Gerät auf.
Da die Daten nicht alle gleich sind und der Speicherort der Bilder unterschiedlich sind, habe ich 7 Tabellen wo die gleiche Funktion
für das Aufrufen der Bilder gebraucht wird.

Was muss ich tun, damit das Macro auch in Tabelle 2-7 funktioniert?


Gruß
Frank

 

Hi Frank,

ich nehme an, mit 2-7 meinst du die Reihenfolge der Tabellen in der Arbeitsmappe? Was ist, wenn du diese Reihenfolge einmal änderst und die 7. Tabelle danach die 1. Tabelle ist? Gibt es vielleicht ein anderes Kriterium, wodurch sich diese Tabellen auszeichnen, in die die Bilder eignefügt werden sollen - z.B. ihr Name oder Teil ihres Namen oder der Inhalt einer bestimmten Zelle der bei allen diesen Tabellen gleich ist oder irgend etwas anderes?

Bis später,
Karin

 

Hallo Karin,

Es funktioniert alles wie ich es haben möchte.
Der Fehler lag in meiner Anwendung der Tabellen.
Das VBA-Script fügt mir in jeder Tabelle immer das passende Bild ein.

Nochmals vielen Dank

Gruß
Frank

 

Hallo Karin,

vielleicht kannst Du mir nochmal unter die Arme greifen.

Ich gebe in die Zelle G8 eine Nummer ein. Mit drücken der Return-Taste importiere ich die entsprechenden Daten.
Wie bekommt man es hin, das auch gleichzeitig das VBA-Script durchlaufen wird.

Zur Zeit hab ich ein Button auf dem ich drücke damit das Foto aktualisiert wird.


Gruß
Frank

 

Hi Frank,

wie importierst du die Daten - per VBA nehme ich an und du benutzt das Worksheet_Change-Ereignis? Schreibe ans Ende deines Codes diese Zeile:

Code:

BilderEinfuegen

Damit wird dann das Makro gestartet.

Bis später,
Karin

 

Hallo Karin,

die Daten werden per "sverweis" eingefügt. Die Zelle G8 ist eine rein numerische Zelle.

Gruß
Frank

 

Hi Frank,

wenn ich das alles jetzt richtig interpretiere, gibst du in G8 von Hand etwas ein, wodurch dein SVERWEIS() die relevanten Daten (per Formel) übernimmt? Dann ist das ganz einfach - füge folgenden Code ins Codemodul des Tabellenblattes ein:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address(False, False) = "G8" Then BilderEinfuegen
End Sub

Also: ist die Eingabezelle G8 dann rufe das Makro BilderEinfügen auf.

Bis später,
Karin

 

Hallo Karin,

Nachdem ich rausgefunden hab wie ich ins Codemodul gelange, klappt alles super.

Vielen Dank

Gruß
Frank

 

Also, wenn ich das richtig mitbekommen habe:

in den Codemodulen der Tabellenblätter werden die Befehle automatisch ausgeführt.

und in den Modulen (z.B. aufgezeinete Markros) wir ein Startbefehl (z.b. stgr/A) benötigt.