Office: Daten autom. in freie Zeile einfügen

Hallo zusammen.

Ich habe folgendes Problem:
1. In einem Exceltabellenblatt A (als Vorlage) möchte ich bestimmte manuel eingetragene Daten auf Knopfdruck in eine anderes Tabellenblatt B kopieren.
anschließen wir A mit Datum/Name abgespeichert.
Wenn ich neue Eintragungen machen möchte rufe ich wieder die Vorlage A auf.
2. In Tabelle B stehen bereits andere Datensätze aus Tabelle A
3. Die Datensätze in Tabelle B solle in einer Zeile sein
4. Der jeweilige neue Datensatz soll in die nächst freie Zeile in Tabelle B (durch Befehl/Knopfdruck) kopiert werden :-)

Hat jemand eine Ahnung, wie das geht?

Gruß Andi

 

Hallo Andi,

nachfolgend das Makro, das dies bewerkstelligen sollte. Es ist nur als Muster gedacht, das an Deine Verhältnisse anzupassen ist.

Code:

Public Sub Einträge_kopieren()
  Dim RgBenutzt As Range
  Dim WsQuelle As Worksheet, WsZiel As Worksheet
  Dim ZeileZiel As Long
  
  'Arbeitsblatt, in dem die Vorlage enthalten ist:
  Set WsQuelle = Worksheets("Tabelle1")
  'Arbeitsblatt, in dem die Datensätze zeilenweise gesammelt werden:
  Set WsZiel = Worksheets("Tabelle2")
  
  Set RgBenutzt = WsZiel.UsedRange
  ZeileZiel = RgBenutzt.Rows.Count + 1
  
  With WsZiel.Rows(ZeileZiel)
    'Wert aus Zelle A3 der Vorlage wird nach Spalte A (=Cells(1)) kopiert
    .Cells(1) = WsQuelle.[A3]
    'Wert aus Zelle B4 der Vorlage wird nach Spalte B (=2) kopiert
    .Cells(2) = WsQuelle.[B4]
    'Wert aus Zelle C6 der Vorlage wird nach Spalte C (=Cells(3)) kopiert
    .Cells(3) = WsQuelle.[C6]
    'Wert aus Zelle E4 der Vorlage wird nach Spalde D (=4) kopiert
    .Cells(4) = WsQuelle.[E4]
    'Wert aus Zelle D5 der Vorlage wird nach Spalde E (=5) kopiert
    .Cells(5) = WsQuelle.[D5]
    '....
    'usw.
    '....
  End With
End Sub

Das Makro geht davon aus, dass im Arbeitsblatt 'Tabelle1' eine Art Formular enthalten ist, das einige verstreut liegende Zellen enthält, die in das Arbeitsblatt 'Tabelle2' übertragen werden sollen. In 'Tabelle2' sollen diese Formulardaten zeilenweise eingetragen werden, jeweils in der nächsten freien Zeile. Dabei wird vorausgesetzt, dass in Zeile 1 von 'Tabelle2' bereits eine Überschrift enthalten ist (wichtig, sonst funktioniert das Makro nicht korrekt!)

Beispielhaft werden einige Zellen aus 'Tabelle1' aufgegriffen und nach 'Tabelle2' kopiert und zwar nach folgendem Schema (das ist natürlich von Dir an Deine Vorstellungen anzupassen):

Tabelle1	Tabelle2
Zelle	Spalte
A3	A
B4	B
C6	C
E4	D
D5	E

Installation des Makros:
Das Makro ist zu kopieren und in ein allgem. Codemodul einzufügen.
Das allgem. Codemodul ist über den VBA-Editor (Tastenkombination Alt+F11) erreichbar und dort über die Menüauswahl "Einfügen > Modul".

Aufrufen des Makros:
Durch Drücken der Tastenkombination Alt+F8 und anschließendem Drücken der EINGABE-Taste
oder
durch Einfügen eines Buttons, der mit dem Makro verknüpft wird, ins Arbeitsblatt 'Tabelle1'.