Office: (Office 2000) Daten im Formular filtern und als xls speicherrn

steenhy · 21. April 2008

Hi,
finde leider kein passendes Beispiel?!

Ich filtere Daten in demFormular 'Teilnehmer - Tabelle' mit den Feld-Filter Funktionen.
Wie kann ich jetzt das Ergebniss als xls Datei speichern?
Bzw. wie übergebe ich den
=[Teilnehmer-Tabelle].Formular.Filter
an eine Abfrage die ich dann mit
DoCmd.OutputTo acOutputQuery, squery, acFormatXLS, [Dateipfad]
als xls speichern kann?

Gruß,

:)

Josef P. · 22. April 2008

Relativ angenehm finde ich Excel-Automation mit der Methode CopyFromRecordset, da man damit direkt das Recordset des Formulars einsetzen kann.

Prinzip:
Code:

Dim xlApp As Object '.. = Excel.Application
Dim xlWorkBook As Object '.. = Excel.Workbook
Dim xlWorkSheet As Object '.. = Excel.WorkSheet

Set xlApp = CreateObject("Excel.Application")
Set xlWorkBook = xlApp.Workbooks.Add
xlApp.Visible = True
Set xlWorkSheet = xlWorkBook.Worksheets(1)

'Überschriften einfügen
...

'Daten übertragen
xlWorkSheet.Range("A2").CopyFromRecordset Me.RecordsetClone
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

steenhy · 22. April 2008

Danke für schnelle Hilfe

leider kämpfe ich noch mit den Grundlagen.
Wenn ich Deinen Code in das Click Ereignis eines Button im Formular kopiere erhalte ich die Meldung wie "Unzulässiger Verweis auf RecordsetClone".
Muss ich den Bezug zum Formular noch näher definieren?

Gruß,

Josef P. · 22. April 2008

Me.RecordsetClone bezieht sich auf den RecordsetClone von Me. Me ist das Formular, in dem der Code steht.

Falls du z.B. die Daten aus einem Unterformular verwenden willst:
Code:

Me!Unterformularsteuerelement.Form.RecordsetClone
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Oder falls du ein Formular "von außen" ansprechen willst:
Code:

Forms("FormName").RecordsetClone
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das Formular muss natürlich geöffnet sein.

steenhy · 23. April 2008

ich bin zu blöd...
Das Haupformular ist "Teilnehmer Auswahl" das Ufo "Teilnehmer Tabelle".
ich habe beide Möglichkeiten probiert:
Code:

Private Sub Befehl10_Click()
On Error GoTo Err_Befehl10_Click

Dim xlApp As Object '.. = Excel.Application
Dim xlWorkBook As Object '.. = Excel.Workbook
Dim xlWorkSheet As Object '.. = Excel.WorkSheet
'
Forms.[Teilnehmer auswahl].[Teilnehmer-Tabelle].RecordsetClone
'Me![Teilnehmer Auswahl]![Teilnehmer-Tabelle].Form.RecordsetClone
'
Set xlApp = CreateObject("Excel.Application")
Set xlWorkBook = xlApp.Workbooks.Add
xlApp.Visible = True
Set xlWorkSheet = xlWorkBook.Worksheets(1)

'Überschriften einfügen

'Daten übertragen
xlWorkSheet.Range("A2").CopyFromRecordset RecordsetClone

Exit_Befehl10_Click:
Exit Sub

Err_Befehl10_Click:
MsgBox Err.Description
Resume Exit_Befehl10_Click

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

und erhalte immer nur Fehlermeldung wie "Objekt unterstützt Methode nicht " (. oder ! Fehler) !?
Gruß

Josef P. · 23. April 2008

ich gehe jetzt einmal davon aus, dass du die Daten des Unterformulars exportieren willst und die Schaltfläche "Befehl10" im Hauptformular ist.

Code:

xlWorkSheet.Range("A2").CopyFromRecordset Me![Teilnehmer-Tabelle].Form.RecordsetClone
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

steenhy · 23. April 2008

Danke für die Geduld...
ich wusste nicht wo ich was einfügen sollte?!

Gibt es noch eine Möglichkeit die Spaltenüberschriften zu übertragen?

Gruß,

Josef P. · 23. April 2008

Ja, du kannst z.B. die Spaltenbezeichnung aus den Namen der Recordset-Felder auslesen.

Am einfachsten ist es, wenn du dir eine Hilfsfunktion schreibst, damit du nicht jedesmal den Code neu schreiben musst.
z.B.:
Code:

'Form-RecordsetClone exportieren
Public Function FormRecordset2Excel(ByRef frmRef As Access.Form, _
Optional ByVal StartRowNr As Long = 1, _
Optional ByVal StartColNr As Long = 1, _
Optional ByVal bWithRecordsetHeaders As Boolean = True)

Recordset2Excel frmRef.RecordsetClone, StartRowNr, StartColNr, bWithRecordsetHeaders

end function

'Recordset exportieren
Public Function Recordset2Excel (ByRef rstData As Object, _
Optional ByVal StartRowNr As Long = 1, _
Optional ByVal StartColNr As Long = 1, _
Optional ByVal bWithRecordsetHeaders As Boolean = True)

'rstData = ADODB oder DAO-Recordset-Referenz

Dim lngRstDataCols As Long
Dim strRstDataColsName() As String
Dim i As Long

Dim xlApp As Object '.. = Excel.Application
Dim xlBook As Object '.. = Excel.Workbook
Dim xlSheetAs Object '.. = Excel.WorkSheet

Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.Workbooks.Add
xlApp.Visible = True
Set xlSheet= xlBook.Worksheets(1)

'Überschriften
If bWithRecordsetHeaders Then
With rstData
lngRstDataCols = .Fields.Count
ReDim strRstDataColsName(lngRstDataCols - 1)
For i = 0 To (lngRstDataCols - 1)
strRstDataColsName(i) = .Fields(i).Name
Next i
xlSheet.Range(xlSheet.Cells(StartRowNr, StartColNr), _
xlSheet.Cells(StartRowNr, StartColNr + lngRstDataCols - 1)).value = strRstDataColsName
StartRowNr = StartRowNr + 1
End With
End If

'Daten
xlSheet.Cells(StartRowNr, StartColNr).CopyFromRecordset rstData

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich kopierte den Code aus einer Klasse von mir und änderte ihn, damit er in einem normalen Modul lauffähig ist. Daher kann es durchaus sein, dass noch Fehler vorkommen, denn geprüft habe ich ihn nicht. *wink.gif*

steenhy · 23. April 2008

Ich muss schon wieder nerven...

Mir gelingt es nicht die Fkt FormRecordset2Excel aufzurufen?
Dabei muss doch der Formularname übergeben werden?

Ich habe es u.a. mit

FormRecordset2Excel([Teilnehmer-Tabelle])

versucht.
Muss ich nicht einer Variablen den Wert der Fkt. zuweisen?

Gruß

Josef P. · 23. April 2008

probier einmal:
Code:

Private Sub Befehl10_Click()
FormRecordset2Excel Me!Unterformularsteuerelement.Form
' oder
'Recordset2Excel Me!Unterformularsteuerelement.Form.RecordsetClone
End sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Nicht der Namen sondern die Objekt-Referenz muss übergeben werden.

steenhy · 23. April 2008

Vielen Dank für die geduldige Hilfe.

Ich muss mich dringend mit den Grundlagen von Klassen, Objecten und Clonen etc. auseinandersetzen...

Gruß,

Office: (Office 2000) Daten im Formular filtern und als xls speicherrn

Daten im Formular filtern und als xls speicherrn

Daten im Formular filtern und als xls speicherrn

Daten im Formular filtern und als xls speicherrn

Daten im Formular filtern und als xls speicherrn

Daten im Formular filtern und als xls speicherrn - Similar Threads - Daten Formular filtern

Formular nur Daten speichern

Wöchentliche Daten in stündliche aufteilen

Datensatz abfragen und Daten ergänzen

Excel VBA aus einem Formular Daten in eine geschlossen Arbeitsmappe zu übertragen

1 Formular aber daten auf 2 Tabellenblätter speichern

Daten in bestimmtes Feld in Access Formular

Daten aus Zellen in Formular-Vorlage einfügen