Office: Daten in über Commandobutton in ein anderes Tabellenblatt

Hallo,

ich habe noch ein Problem.

Mein Makro formatiert Daten und fügt die anschließend in ein anderes Tabellenblatt ein. Funkioniert auch einwandfrei.

Wenn ich nun allerdings dieses Makro über einen Commandobutton starten möchte kommt immer die Fehlermeldung: Lautzeitfehler 1004.

Ich habe das Gefühl, das man über den Button nicht in ein anderes Tabellenblatt wechseln kann. Ist das richtig?

Gibt es eine Möglichkeit, dass Problem zu umgehen?

Gruß
Michael

 

Hallo!

Der Button macht eigentlich nix anderes, als das Makro aufzurufen.
Allerdings ist der Button ein Objekt des Tabellenblatts. Daher kann evtl. eine andere Adressierung nötig sein als bei einem Makro, welches in einem allgemeinen Modul liegt.

Aber ohne deinen Code zu kennen, wird das hier wohl eher ein Revival von "Rate mal mit Rosenthal"...

 

Anbei sende ich mal die aktuelle Datei, zum besseren Verständnis...

 

irgendwie finde ich nichts, um nachträglichen eine datei anzuhängen. sorry.

hier der code:

Private Sub CommandButton2_Click()
Sheets("ISBN").Select
Columns("A:A").Select
Selection.TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar _
:="|", FieldInfo:=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True
Columns("B:B").Select
Selection.Replace What:="-", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Selection.NumberFormat = "0"
Range("B1").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Copy
Sheets("Bestellungen - Übersicht").Select
Range("A5").Select
ActiveSheet.Paste
Application.CutCopyMode = False
Columns("A:A").EntireColumn.AutoFit
Range("A1").Select

End Sub

 

Hallo!

Auf welchem Blatt liegt denn der Button?

PS: Eine Datei kannst du so anhängen:
Button "Antwort erstellen"
Button "Durchsuchen"
Datei auswählen
Button "Attachment hinzufügen"
Button "Absenden"

 

Der Button liegt im Tabellenblatt "Bestellungen - Übersicht".

Er soll in das Blatt "ISBN" gehen, dort Daten aus Spalte A trennen und die abgetrennten Daten aus Spalte B nehmen und in das Blatt "Bestellungen - Übersicht" wieder einfügen.

Leider komme ich momentan nicht an die Datei ran (liegt auf arbeit, ich bin momentan zu hause). Ich hoffe der Code und meine Beschreibung reichen aus.

 

Hallo!

Das hoffe ich auch... :-D
Teste mal dies:

Code:

Private Sub CommandButton1_Click()
With Sheets("ISBN")
.Columns(1).TextToColumns OtherChar:="|"
.Columns(2).Replace What:="-", Replacement:="", LookAt:=xlPart
.Columns(2).NumberFormat = "0"
.Range(.Range("B1"), .Range("B1").End(xlDown)).Copy Range("A5")
Columns(1).AutoFit
End With
End Sub

 

Guten Morgen,

ich habe gerade einmal Deinen Vorschlag von gestern probiert. Leider kommt noch immer die gleiche Fehlermeldung.

Aber: Ich kann Dir jetzt die Datei hängen.

Kannst Du das bitte noch einmal prüfen?

Vielen Dank

Michael

 

Hallo!

Da fehlt wohl nur eine Kleinigkeit:

Private Sub CommandButton2_Click()
With Sheets("ISBN")
.Columns(1).TextToColumns Other:=True, OtherChar:="|"
.Columns(2).Replace What:="-", Replacement:="", LookAt:=xlPart
.Columns(2).NumberFormat = "0"
.Range(.Range("B1"), .Range("B1").End(xlDown)).Copy Range("A5")
Columns(1).AutoFit
End With
End Sub

 

jetzt funktioniert das, wie ich mir das vorgestellt habe.

vielen dank und schönes wochenende

gruß
michael