Office: Daten von Blatt1 nach Blatt2 übertragen, wenn Feld2 = leer

Hallo!

Meine Excel Kenntnisse sind leider arg limitiert. Dennoch versuche ich, folgendes Szenario mit Excel 2003 zu realisieren.

Es gibt eine Datei mit 8 Tabellenblätter.

• Zuammenfassung
  Kommandoebene
  Organisation
  Spieler
  Schiedsrichter
  Media
  Volunteer
  Security

Jedes Blatt ist gleich aufgebaut.

• A: ID
  B: Nachname
  C: Vorname
  D: Nation
  E: Position
  F: Geburtsdatum
  G: Geschlecht
  H: Farbe
  I: Telefon (mobil)

Die ID ist 4-stellig.

• Kommandoebene: 0001 - 0999
  Organisation: 1001 - 1999
  Spieler: 2001 - 2999
  Schiedsrichter: 3001 - 3999
  Media: 4001 - 4999
  Volunteer: 5001 - 5999
  Security: 6001 - 6999

Ich möchte nun diesen Ablauf erzeugen:

Schaue auf Tabellenblatt "Kommandoebene".
Gehe Zeile für Zeile durch.
Wenn Feld A und Feld B nicht leer sind, kopiere die Zeile 1zu1 in Tabellenblatt "Zuammenfassung"

Schaue auf Tabellenblatt "Organisation".
Gehe Zeile für Zeile durch.
Wenn Feld A und Feld B nicht leer sind, kopiere die Zeile 1zu1 in Tabellenblatt "Zuammenfassung"
....

Vielleicht noch eine Anmerkung zum Kenntnisstand. Mit PHP und MySQL bekäme ich es hin. Aber das nutzt mir gar nix.
Leider fehlen mir sämtliche Kenntnisse bei Excel. Damit habe ich nie ernsthaft gearbeitet.

Vermutlich muss ich ein Makro nutzen. Aber was schreibe ich da rein?

Kann mir bitte jemand helfen?!

Vielen Dank und Gruß
Kernel Trautman

 

Re: Daten von Blatt1 nach Blatt2 übertragen, wenn Feld2 = le

Jau, das ist eigentlich gar kein Riesen-Problem, wenn Du schon etwas Kenntnisse in php hast. Dann ist Dir ein bißchen VBA-Source ja auch nicht gleich ein Greuel. ;-)

Laß dir zuerst mal die "Steuerelemente-Toolbox" über das Menü "Ansicht - Symbolleisten" anzeigen. Dort findest Du dann auch die "Befehlsschaltfläche". Einmal anklicken und irgendwo auf dem Blatt "Zusammenfassung" platzieren. Jetzt rechte Maustaste auf dem neuen Button und "Eigenschaften" angewählt. Folgende Einstellungen:

Code:

(Name): B_Zusammenfassung
Caption: Zusammenfassung

Das Eigenschaften-Fenster kannst Du jetzt wieder schließen. Nochmal rechte Maustaste auf dem Button und "Code anzeigen" wählen. Du landest im VBA-Editor mit dem Sourcecode des Tabellenblatts und im "Click"-Ereignis des Buttons.

Lösche mal den gesamten angezeigten Sourcecode und ersetze ihn durch:

Code:

Option Explicit

Const sh0 = "Zusammenfassung"
Const sh1 = "Kommandoebene"
Const sh2 = "Organisation"
Const sh3 = "Spieler"
Const sh4 = "Schiedsrichter"
Const sh5 = "Media"
Const sh6 = "Volunteer"
Const sh7 = "Security"

Private Sub B_Zusammenfassung_Click()

    Dim ws2 As Worksheet
    Dim y2 As Long
    Dim n As Integer
    Dim s As String
    Dim ws1 As Worksheet
    Dim y1 As Long
    Dim tst1 As String

    Set ws2 = ThisWorkbook.Worksheets(sh0)
    y2 = 1
    ws2.Range("a2:i65536").ClearContents

    For n = 1 To 7

        Select Case n
            Case 1: s = sh1
            Case 2: s = sh2
            Case 3: s = sh3
            Case 4: s = sh4
            Case 5: s = sh5
            Case 6: s = sh6
            Case 7: s = sh7
        End Select
        Set ws1 = ThisWorkbook.Worksheets(s)
        y1 = 2

        'ws1.Activate: ActiveSheet.Cells(y1, 1).Activate
        tst1 = Trim$(ws1.Cells(y1, 1).Value)
        While (tst1 <> "")
            tst1 = Trim$(ws1.Cells(y1, 2).Value)
            If (tst1 <> "") Then
                y2 = y2 + 1
                ws1.Rows(y1).Copy
                ws2.Rows(y2).PasteSpecial Paste:=xlPasteValues
            End If
            y1 = y1 + 1
            'ws1.Activate: ActiveSheet.Cells(y1, 1).Activate
            tst1 = Trim$(ws1.Cells(y1, 1).Value)
        Wend
        ws1.Activate: ws1.Cells(2, 2).Activate

    Next n

    ws2.Activate: ws2.Cells(2, 2).Activate

    Application.CutCopyMode = False

End Sub

Jetzt kannst Du den VBA-Editor schließen und mußt nur noch den Entwurfs-Modus in Excel beenden. Auf der Steuerelemente-Toolbox befindet sich als erstes Symbol so eins mit Geodreieck, Lineal und Stift, daß z.Z. "eingedrückt" sein sollte. Deswegen sind auch die Eck-Marker zum Größe verändern um den Button herum sichtbar. Einmal das Icon angeklickt und schon kannst Du den Button ganz normal drücken.

Gruß, Michael