Office: datenbankauswertung mit "unbekannten" Kriterien

Hallo,

ich habe folgendes Problem und kriege keine vernünftige Lösung hin.

Hintergrund: Durch mehrere Messstationen werden minütlich Daten geliefert und in eine Tabelle geschrieben, soweit sich Änderungen in den Parametern ergeben. Es kann also vorkommen, dass mehrere Minuten/ Stunden keine Datensätze zu meinem Suchkriterium erstellt werden.

Die Tabelle hat folgende Spalten:
Messtation / Tagesdatum / Uhrzeit / auszulesender Wert

Insgesamt habe ich 10 Messstationen, die alle in die selbe Tabelle (unregelmäßig) schreiben. Die Tabelle beinhaltet Messdaten von 12:00 Mittag bis 12:00 am nächsten Tag.
Ich möchte jetzt folgende Auswertung machen bzw. Daten auslesen:
1) Beginnwert Messstation 1 usw.
2) Differenz Messwerte 14:00 - 8:00 (bzw. den zeitlich folgenden Wert für die jeweilige Station) - Problem: Ich kenne die genaue Zeit nicht, für welche der nächste Messwert erfasst wurde.
3) Letzter Wert der jeweiligen Messstation in dem 24-Stunden-Bereich

Ich hoffe Ihr habt eine Lösung (ich kriege die Kriterien Messstation und unbekannte Uhrzeit einfach nicht unter einen Hut ... na ja, der Datumswechsel macht mir auch Sorgen)

Vielen Dank

dusk79 :-D

 

Hallo!

Werden denn die alten Werte überschrieben, oder werden die neuen Werte unten an deine Liste angehängt?

 

Hallo

Für jeden 24-Stunden-Zeitraum soll eine neue Tabelle erstellt werden (die ich in Excel übernehmen will). Die Daten werden in der Liste angehängt.
Im ungünstigsten Fall habe ich in den 24 Stunden also (24 Stunden x 60 Minuten x 10 Messgeräte = 14.400 Datensätze)
Im "besten" Fall habe ich nur die Startwerte für alle 10 Stationen.

Viele Grüße vom dusk

 

Hallo!

Und wie soll deine Auswertungstabelle vom Aufbau aussehen?
Vielleicht könnte es auf eine Pivot-Tabelle hinauslaufen...

 

Hallo,

ich habe mal irgendwann davon gehört, dass es eine Pivot-Tabelle gibt. Leider fehlt mir jeglicher Bezug (ich werde wohl morgen mal nachlesen ;).

Die Auswertung soll im Grunde nur die Werte liefern
Mess-Station 1 (Differenz Messwerte) =
usw.
Die kürzere zeitraumbezogene Auswertung soll nur bei Bedarf durchgeführt werden.

Vorläufig sollen die Daten dann einerseits als Diagramm und zudem in eine Lageskizze umgesetzt werden (das kriege ich über bedingte Formatierung hin).
Weitere Auswertungen sollen folgen, wenn wir genügend Daten zusammen haben bzw. abschätzen können, ob Auswertungen zweckmäßig sind.

Ich hoffe Du kannst mit meiner Erklärung etwas anfangen.

Viele Grüße dusk
Ich

 

Hallo!

Ich kann dir zumindest eine Auflistung der infrage kommenden Werte liefern.
In H2 und I2 werden gewünschte Station und Datum eingegeben; die Formeln können alle nach unten ausgefüllt werden.

	A	B	C	D	E	F	G	H	I	J	K
1	Station	Datum	Uhrzeit	Wert			Hilfe	Station	Datum	Uhrzeit	Werte
2	1	11.01.2010	11:59	101			0	1	11.01.2010	12:00	103
3	2	11.01.2010	12:00	102			0		11.01.2010	17:00	107
4	1	11.01.2010	12:00	103			1		11.01.2010	18:00	108
5	2	11.01.2010	13:00	104			1		12.01.2010	10:00	110
6	2	11.01.2010	13:30	105			1
7	2	11.01.2010	15:00	106			1
8	1	11.01.2010	17:00	107			2
9	1	11.01.2010	18:00	108			3
10	2	12.01.2010	08:00	109			3
11	1	12.01.2010	10:00	110			4
12	1	12.01.2010	12:01	111			4

Zelle	Formel
G2	=MAX(G$1:G1)+(A2=H$2)*(B2+C2>=I$2+0,5)*(B2+C2<=I$2+1,5)
J2	=WENN(ZEILE(A1)>MAX(G:G);"";INDEX(C:C;VERGLEICH(ZEILE(A1);G:G;)))
K2	=WENN(ZEILE(A1)>MAX(G:G);"";INDEX(D:D;VERGLEICH(ZEILE(A1);G:G;)))
I3	=WENN(ZEILE(A2)>MAX(G:G);"";INDEX(B:B;VERGLEICH(ZEILE(A2);G:G;)))

 

Guten Morgen,

vielen Dank schon mal für die ersten Hinweise…

Vielleicht noch ein bisschen Hintergrund:
Meine Aufgabe ist der Versuchsaufbau und eine möglichst kostensparende Auswertung ;)
In ein paar Monaten wird dann die Auswertung sicher von jemandem anderen übernommen (weshalb ich mich instinktiv für Excel entschieden habe – „das versteht jeder“, dachte ich *g*).

Mein Ansatz war bisher folgender: Ich bastle mir ein Makro, mit dem ich die Daten nach Station sortiere. Das funktioniert ohne Probleme. Dann lese ich mit sverweis den ersten Wert jeder Station aus. Soweit so gut.
Danach wollte ich den Endwert jeder Station ermitteln (da bin ich gescheitert).
Ergänzung: Die vorliegende Tabelle enthält keine Werte vor 12:00 (Tag 1) und keine Werte nach 12:00 (Tag 2). So dass ich diese glücklicherweise nicht ausfiltern muss.

Zusatzaufgabe:
Und dann bekam ich den Hinweis, dass man auch prüfen könne, ob in einem Intervall (1 Minute oder 2 Minuten) die Werte besonders schnell anwachsen.
Mein gedanklicher Ansatz: ich erstelle nach Sortierung eine neue Kontrollspalte und lasse die Differenz (Messwert der Zeile mit der vorangegangenen Zeile) ausgeben. Das funktioniert, da im Falle einer Änderung der Wert minütlich ausgegeben wird. Andernfalls ist der Zeitraum zwischen 2 Zeilen zwar größer – überschreitet aber nicht den Maximalwert.
In Deiner Tabelle: Spalte L … Feld L3 =K3-K2 usw.
Danach lasse ich mir einen Hinweis ausgeben, wenn der Wert in der Spalte L irgendwann den Grenzwert übersteigt. (Das ganze verpacke ich in eine =wenn-Funktion mit Bezug auf die Stationsnummern, damit er mir nicht den Sprung zwischen Station 1 und 2 usw. auswirft. Bei meiner Sortierung kommen die Werte der Stationen direkt hintereinander)
Es funktioniert. Aber die Methode wirkt unbeholfen und ich befürchte, dass mein/e Nachfolger/in ohne ausreichende Dokumentation etc. nicht versteht was ich da rechne. Eine einheitliche Formel ohne Sonderspalte wäre da schon klasse.
Und die Alternative: "Schau Dir einfach jeden Tag die Tabelle durch und übersieht bitte keinen Wert" kommt im PC-Zeitalter nicht in Betracht *g*

Die minimalste Auswertung soll also folgendes ausgeben:

Datum
Station 1: (Differenz Messwert Tagesbeginn und Tagesende)
Station 2: … usw.

Messwertkontrolle: (ggf. Textausgabe: „Die Station Y hat heute in einem Intervall von 1 Minute den Maximalwert von xxx überschritten)

Ich bräuchte also mind. noch eine Formel um den letzten Wert des Tages für eine Station zu ermitteln. Mit sverweis nimmt er immer den ersten Wert der Station nach meiner automatischen Sortierung.
Falls ihr eine clevere Variante für die Messwertkontrolle zur Hand habt, dann wäre ich auch dafür dankbar.


Viele Grüße vom dusk
(und Danke für die Hilfe)

 

Hallo!

	A	B	C	D	E	F	G	H	I	J
1	Station	Datum	Uhrzeit	Wert			Station	Erster	Letzter	Max-Wert
2	1	11.01.2010	13:00	101			1	101	103	222
3	1	11.01.2010	14:00	222			2	444	107	444
4	1	12.01.2010	10:00	103			3	108	109	109
5	2	11.01.2010	15:00	444
6	2	12.01.2010	08:00	333
7	2	12.01.2010	09:00	106
8	2	12.01.2010	10:00	107
9	3	11.01.2010	18:00	108
10	3	11.01.2010	19:00	109

Zelle	Formel
H2	=SVERWEIS(G2;A:D;4;)
I2	=VERWEIS(2;1/(A$2:A$999=G2);D$2:D$999)
J2	{=MAX((A$2:A$999=G2)*D$2:D$999)}
H3	=SVERWEIS(G3;A:D;4;)
I3	=VERWEIS(2;1/(A$2:A$999=G3);D$2:D$999)
J3	{=MAX((A$2:A$999=G3)*D$2:D$999)}
H4	=SVERWEIS(G4;A:D;4;)
I4	=VERWEIS(2;1/(A$2:A$999=G4);D$2:D$999)
J4	{=MAX((A$2:A$999=G4)*D$2:D$999)}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Wow,

wäre ich nie drauf gekommen.
Funktioniert und ich erspare mir ne Menge Arbeit.

Vielen Dank

dusk79

PS: Hoffentlich kommt jetzt nicht noch jemand und möchte eine andere Auswertung ;-)