Office: (Office Version unbekannt) Datensätze aussortieren bei mehrfacher (WENN/DANN) Beziehung

OFFICE365

Hallo Zusammen,

Ich bin leider nicht sonderlich begabt was das Thema Excel angeht. Jetzt stehe ich vor folgendem Problem:

Ich habe eine Liste mit 40.000 Zeilen.

In Spalte A steht ein Produkt (mindestens 2x, kann aber auch 10x vorhanden sein). In Spalte B stehen verschiedene Codes.
Es gibt einen Code (im Bsp. 111) der als Dummy verwendet wird. Des Weiteren gibt es "richtige" Codes.

Ich muss nun alle Produkte filtern, in denen es nur einen richtigen Code gibt auf X dummies gibt. Alle Produkte die mehr als einen richtigen Code haben sollen ausgeblendet werden. Den Anhang Mappe1.xlsx betrachten

Grafisches Bsp. im Anhang sollte es besser veranschaulichen.

Über Hilfe würde ich mich sehr freuen!

Danke!

LG
Shady

 

Hallo Shady,
der nach folgende Code sollte die richtigen Produkte in ein neues Blatt kopieren.
Voraussetzung: Daten auf aktivem Blatt, Produkt in Spalte A, Code in Spalte B ab Zeile 2, sonst Code anpassen.
Gruß der AlteDresdner

Code:

Sub Sortieren()
Const Dummy = "111"
Dim Sh As Object, Newsh As Object
Dim zeile As Long, zielzeile As Long
Dim Startz As Long, Pr As String, AnzOK As Long
  Set Sh = ActiveSheet
  Set Newsh = ThisWorkbook.Sheets.Add(after:=Sh)
  Newsh.Name = Sh.Name & "_Sortiert"
  With Sh
    .Rows(1).Copy Destination:=Newsh.Range("A1")
    zielzeile = 2
    zeile = 2
    Pr = .Cells(zeile, 1)
    Startz = zeile
    AnzOK = 0
    AnzOK = IIf(.Cells(zeile, 2) = Dummy, 0, 1)
    Do
      zeile = zeile + 1
      If .Cells(zeile, 1) <> Pr Or zeile > .Cells(.Rows.Count, 1).End(xlUp).Row Then 'neues Produkt
        If AnzOK = 1 Then 'übernehmen
          .Rows(Startz & ":" & zeile - 1).Copy Destination:=Newsh.Cells(zielzeile, 1)
          zielzeile = Newsh.Cells(Rows.Count, 1).End(xlUp).Row + 1
        End If
        Pr = .Cells(zeile, 1)
        AnzOK = IIf(.Cells(zeile, 2) = Dummy, 0, 1)
        Startz = zeile
      Else
        AnzOK = IIf(.Cells(zeile, 2) = Dummy, AnzOK, AnzOK + 1)
      End If
      If zeile > .Cells(.Rows.Count, 1).End(xlUp).Row Then Exit Do
    Loop
  End With
End Sub

 

Hallo,

in die Zelle C2 folgende Formel eingeben:
=WENN($B2=111;""; WENN(ZÄHLENWENNS($A:$A;$A2;$B:$B;"<>111")=1; "ok";""))
und die Formel hinunterkopieren so weit wie nötig.

In den Zeilen, wo "ok" erscheint, sind die zutreffenden Produkte enthalten.