Office: (Office 2003) Datensätze sperren

ChristianS. · 5. November 2009

Dein Benutzer gehört zu zwei (!) Gruppen: ElektrikerBWG und User

Damit wird die Gleichheitsbedingung nicht erfüllt. Darf er jetzt, oder darf er nicht löschen? Als Mitglied der Elektriker ja, als "normaler" User nicht.

Ich vermute mal, dass du jeden Benutzer nur eine Gruppe zuordnen willst, das ist aber eben nicht der Fall. Ändere das.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

hab ich auch gesehen*grins mitdenken hilft ja echt!

Hab jetzt den COde:
Code:

If GroupsOfCurrentUser() = "ElektrikerBWG,Users" Then
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

und es funktioniert*dance !
p.s.: konnte nähmlich bei dem User: elektriker die Gruppe: Users nicht entfernen kam ne Hinweismeldung das dies woll standard wär mhhh
Aber müsste jetzt ja auch so gehen!*rolleyes.gif*

Soweitsogut!
Geht das jetzt auch das ich sage das nur Störungen die nen Haken bei behoben drin haben und und ab den Zeitpunkt noch 5 Tage nicht gelöscht werden können?
Das mit Haken und datum wird sicherlich nicht gehen weil ja keiner weiss wann der Haken reingesetzt wurde , aber meistens trägt ja der letzte BehebungsJob dazu bei das die Störung behoben ist und der hat ja nen Datum! Kann ich ja das nehmen! Allerdings liegt das BehebungsjobDatum ja wiederum in einem UFO, dann muss ich bestimmt nur auf dieses Attribut verweisen, oder?

Atrus2711 · 5. November 2009

Ach Christian,
wenn der aktuelle User künftig vielleicht noch in einer dritten Gruppe steckt, wird die Bedingung wieder nicht erfüllt. Die Gleichheit ist Unsinn! Enthaltensein ist gefragt, wie Josef und ich jetzt bestimmt zum dritten Mal sagen. *rolleyes.gif*

Und zu den Bedingungen: du wirst die Datums- und Hakenwerte, die du auswerten willst, irgendwoher nehmen müssen, per Dlookup, Bezug auf ein Control im Ufo, Einbau in die Abfrage des Hauptforms usw.

Achja:

mitdenken hilft ja echt!
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn du das jetzt erst merkst, ....*sos

ChristianS. · 5. November 2009

Sorry das ich manchmal Sachen überlese(wahrscheinlich weil ich sie in dem moment nicht verstehe)*tongue.gif*

Tipp:
Ich würde

If GroupsOfCurrentUser() = "ElektrikerBWG" then

auf

If IsMember("ElektrikerBWG") then

umschreiben.
Anm.:
IsMember soll im Hintergrund prüfen, ob der aktuelle Benutzer zur angegebenen Benutzergruppe gehört.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mit Code:

GroupsOfCurrentUser()
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

wird doch die Function die im Modul liegt aufgerufen,oder?

Also wenn ich das jetzt in Code:

If IsMember("ElektrikerBWG") then
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

umändere muss ich doch sicherlich auch die Funktion ändern, oder?*eek.gif*

Hab gleich Feierabend, also bis morgen! Und Danke für Eure Geduld *wink.gif* !

Atrus2711 · 5. November 2009

Ja.
IsMember gibts aber noch nicht. Die muss erst noch geschrieben werden.

Hier ist sie:
Code:

Function IsMember(strUser As String, strGroup As String) As Boolean
Dim ws As DAO.Workspace
Dim grp As DAO.Group
Dim usr As DAO.User

IsMember = False 'Pessimistischer Default

Set ws = DBEngine.Workspaces(0)
For Each grp In ws.Groups 'Jede Gruppe durchflöhen
If grp.Name = strGroup Then 'Wenn Gruppe gefunden (sie könnte ja auch gar nicht existieren!)
For Each usr In grp.Users 'Jeden User der Grppe durchflöhen
If usr.Name = strUser Then 'Wenn User gefunden,
IsMember = True 'hurra
Exit For 'Suche beenden ---------------------------------------------------------------------------->Exit
End If
Next usr 'nächster User
Exit For 'Suche Beenden ------------------------------------------------------------------------------------>Exit
End If
Next grp 'nächste Gruppe

Set grp = Nothing
Set ws = Nothing
Set usr = Nothing
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ChristianS. · 5. November 2009

Ich weiss gar nicht was ich machen würde, wenn ich euch nicht hätte!
Aufjedenfall keine Datenbank*grins

Nee Spaß beiseite! Würde ja gern auch mal besser verstehen was die VBA Codes immer bedeuten bzw machen! Gibts da Lektüre dazu (sicherlich gibts die!) im Netz als PDF oder so! Kannst du / könnt Ihr mir welche empfehlen?*wisper.gif

ChristianS. · 5. November 2009

wenn ich den Code kompiliere bringt er die Fehler Meldung:

Fehler beim Kompilieren:
Argument ist nicht optional

und IsMember ist BLAU hinterlegt!

Code:

Private Sub Form_Delete(Cancel As Integer)
Stop
Debug.Print IsMember("ElektrikerBWG"), "ElektrikerBWG,Users"
Debug.Print Me!BehebungsjobDatum, DateAdd("d", -3, Date)

If IsMember("elektriker,ElektrikerBWG") Then
If CDate(Me!BehebungsjobDatum) < DateAdd("d", -3, Date) Then
MsgBox "Elektriker,Meldedatum ist mehr als 3 Tage alt (Verglichen mit heute)"
Else
MsgBox "Elektriker, Meldedatum ist jünger."
End If
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In der Function:
Code:

Function IsMember(strUser As String, strGroup As String) As Boolean
Dim ws As DAO.Workspace
Dim grp As DAO.Group
Dim usr As DAO.User

IsMember = False 'Pessimistischer Default

Set ws = DBEngine.Workspaces(0)
For Each grp In ws.Groups 'Jede Gruppe durchflöhen
If grp.Name = strGroup Then 'Wenn Gruppe gefunden (sie könnte ja auch gar nicht existieren!)
For Each usr In grp.Users 'Jeden User der Grppe durchflöhen
If usr.Name = strUser Then 'Wenn User gefunden,
IsMember = True 'hurra
Exit For 'Suche beenden ---------------------------------------------------------------------------->Exit
End If
Next usr 'nächster User
Exit For 'Suche Beenden ------------------------------------------------------------------------------------>Exit
End If
Next grp 'nächste Gruppe

Set grp = Nothing
Set ws = Nothing
Set usr = Nothing
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

wird ja auch geschaut nach dem Benutzer (und nicht nur nach der Gruppe in der der Benutzer ist)
Aber eine "EnthaltenSein" reicht aus,oder?
Muss ich in dem Code Form_Delete auch noch was ändern?*boah

Josef P. · 5. November 2009

Code:

Debug.Print IsMember("ElektrikerBWG"), "ElektrikerBWG,Users"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code:

Function IsMember(strUser As String, strGroup As String) As Boolean
...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Vergleiche einmal die Anzahl der Parameter. *wink.gif*
=>
Code:

Debug.Print IsMember(CurrentUser(), "ElektrikerBWG")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Tipp: Da man meinst auf CurrentUser abfrage, ist es vielleicht vorteilhaft, wenn man den Usernamen nicht immer angeben muss.
=>
Code:

Function IsMember(byval strGroup As String, optional byval strUser As String = vbnullstring) As Boolean
if len(strUser) = 0 then
strUser = currentuser()
end if
...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Dann funktioniert auch ein IsMember("ElektrikerBWG").

Atrus2711 · 5. November 2009

Mit solchen optionalen Parametern arbeite ich ungern, da er eben optional ist. Ein Funktionsaufruf ist mit und ohne möglich, aber sie tut dann unterschiedliches, was ich u.U. nicht bemerke.

Meist der aktuelle User heißt ja: manchmal auch nicht.

Die Pflichtangabe des Users war schon Absicht, damit man den User angeben muss (ja, auch wenn es meistens der CurretnUser ist). Als Pflichtargument wird es dann angemahnt, wenn es fehlt. Als optionales Argument defaultet es zum CurrentUser, obwohl das vielleicht gar nicht erwünscht ist.

Ist aber Geschmackssache. Defaults habe ich halt nicht so gerne. Ich gebe in der Pizzeria auch immer wieder neu an, was ich haben will, und lasse mich auf Luigis "wie immer" ein... *wink.gif*

@Chrsitian:
User und Gruppen sind m:n. Jeder kann überall drin sein, und jede kann aus allen bestehen.

ChristianS. · 5. November 2009

Ahhhhhh.....*upps

Und nun?

Meist der aktuelle User heißt ja: manchmal auch nicht.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Seh ich auch so!

Aber was mach ich jetzt?*frown.gif*

Code:

Debug.Print IsMember(CurrentUser(), "ElektrikerBWG")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hab ich jetzt!
und CurrentUser och bei If IsMember als ersten Para eingetragen, aber kommt jetzt kommt diesmal hier die Fehlermeldung!

Code:

Private Sub Form_Delete(Cancel As Integer)
Stop
Debug.Print IsMember("CurrentUser(),ElektrikerBWG"), "ElektrikerBWG,Users"
Debug.Print Me!BehebungsjobDatum, DateAdd("d", -3, Date)

If IsMember("CurrentUser(),ElektrikerBWG") Then
If CDate(Me!BehebungsjobDatum) < DateAdd("d", -3, Date) Then
MsgBox "Elektriker,Meldedatum ist mehr als 3 Tage alt (Verglichen mit heute)"
Else
MsgBox "Elektriker, Meldedatum ist jünger."
End If
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und der Einzelschritt_modus funktioniert dann auch nicht!

Atrus2711 · 5. November 2009

Die zwei Argumente sind jeweils Texte. Du hast die beiden Angaben (User und Gruppe) in einem Text übergeben. Zudem funktionieren Funktionen wie CurrentUsre nicht, wenn sie in Anführungsstrichen stehen.

Code:

Private Sub Form_Delete(Cancel As Integer)
Stop
Debug.Print IsMember(CurrentUser(), "ElektrikerBWG")
Debug.Print Me!BehebungsjobDatum, DateAdd("d", -3, Date)

If IsMember(CurrentUser(), "ElektrikerBWG") Then
If CDate(Me!BehebungsjobDatum) < DateAdd("d", -3, Date) Then
MsgBox "Elektriker,Meldedatum ist mehr als 3 Tage alt (Verglichen mit heute)"
Else
MsgBox "Elektriker, Meldedatum ist jünger."
End If
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ChristianS. · 6. November 2009

Klappt!*grins

Jetzt bloß noch Löschen verbieten! Versuch ich aber selber mal mit den Infos die ich von euch vorher schon bekommen hab!
Es sei denn du meinst das das eh schief geht dann kannste ja was schreiben*wink.gif*
wenn nicht dann schreib ich spätestens wenns soweit ist*tongue.gif*

Atrus2711 · 6. November 2009

Löschen verbieten heißt Cancel = True setzen. Wann immer das passieren soll.

ChristianS. · 6. November 2009

Endlich fertig!!! Ich Danke Euch allen für Eure großartige Unterstützung!!!*knuddel

@ATRUS: DANKE!!!!!!!!!!!!!

So hier das Endergebnis:

In der "Bei Löschen"-Prozedur
Code:

Private Sub Form_Delete(Cancel As Integer)
Debug.Print IsMember(CurrentUser(), "ElektrikerBWG"), "Users,ElektrikerBWG"
Debug.Print Me!BehebungsjobDatum, DateAdd("d", -3, Date)

If IsMember(CurrentUser(), "ElektrikerBWG") Then
If CDate(Me!BehebungsjobDatum) < DateAdd("d", -3, Date) Then
MsgBox "Elektriker,Meldedatum ist mehr als 3 Tage alt (Verglichen mit heute)"
Cancel = True
Else
MsgBox "Elektriker, Meldedatum ist jünger."
End If
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

als Module:
Code:

Function GroupsOfCurrentUser() As String
Dim wrkDefault As Workspace
Dim usrLoop As User
Dim grpLoop As Group
Dim grpMember As Group
Dim AktGruppen As String
Set wrkDefault = DBEngine.Workspaces(0)
With wrkDefault
For Each usrLoop In .Users
If usrLoop.Name = CurrentUser Then
For Each grpLoop In usrLoop.Groups
AktGruppen = AktGruppen & "," & grpLoop.Name
Next grpLoop
End If
Next usrLoop
End With
GroupsOfCurrentUser = Mid(AktGruppen, 2)
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

und

Code:

Function IsMember(strUser As String, strGroup As String) As Boolean
Dim ws As DAO.Workspace
Dim grp As DAO.Group
Dim usr As DAO.User

IsMember = False 'Pessimistischer Default

Set ws = DBEngine.Workspaces(0)
For Each grp In ws.Groups 'Jede Gruppe durchflöhen
If grp.Name = strGroup Then 'Wenn Gruppe gefunden (sie könnte ja auch gar nicht existieren!)
For Each usr In grp.Users 'Jeden User der Grppe durchflöhen
If usr.Name = strUser Then 'Wenn User gefunden,
IsMember = True 'hurra
Exit For 'Suche beenden ---------------------------------------------------------------------------->Exit
End If
Next usr 'nächster User
Exit For 'Suche Beenden ------------------------------------------------------------------------------------>Exit
End If
Next grp 'nächste Gruppe

Set grp = Nothing
Set ws = Nothing
Set usr = Nothing
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

*grins

Office: (Office 2003) Datensätze sperren

Datensätze sperren

Datensätze sperren

Datensätze sperren

Datensätze sperren

Datensätze sperren

Datensätze sperren - Similar Threads - Datensätze sperren

Filtern von Datensätzen

Access Neuer Datensatz im Formular

Datensatz aus Ufo2 auch in Ufo1 anzeigen

Serienbrief aus mehreren Datensätze

Datensatz sperren

kann man einzelne Datensätze sperren?

Löschen von Datensätzen über Eingabeformular sperren (A2003)