Office: (Office 2016) Datensatz mit Unterformular duplizieren

jabra1307 · 10. Mai 2016

Hallo!

Ich habe eine Tabelle "Stamm" und eine Tabelle "Inhalt". Die beiden Tabellen sind über "StammID" verknüpft.

In einem Hauptformular mit "Stamm" und einem Unterformular mit "Inhalt" gebe ich Daten ein.

Nun möchte ich gerne einen Button haben, der es mir ermöglicht die Datensätze aus dem HF zusammen mit den Daten aus dem UF zu kopieren.

Dazu habe ich einen Code gefunden und versucht ihn auf meine Bedürfnisse umzubasteln.

Nur leider funktioniert das nicht ganz: die Daten aus dem UF werden zwar kopiert, aber beim einfügen wird bei "StammID" nicht die neu erzeugte ID eingefügt, sondern die des Ursprungsdatensatzes.

Da kommt quasi dabei raus:

Datensatz 1: Stamm: 123; Inhalt: abc

dann kopiere ich über meinen Button und erhalte:

Datensatz 1: Stamm: 123; Inhalt: abc, abc
Datensatz 2: Stamm: 123; Inhalt:

Würde mich sehr über Hilfe freuen.

Code:

Private Sub Befehl731_Click()

SQL = ""
'*** Prozedur, aktuellen Datensatz duzplizieren ***
'Sichern der alten IDs
If Not IsNull(Me.ID) Then
sichID = Me.ID
End If

If MsgBox("Soll der Datensatz " & sichID & " kopiert werden?", vbQuestion + vbYesNo, "Kopieren bestätigen") = vbNo Then
Exit Sub
End If

'Markieren
DoCmd.DoMenuItem acFormBar, acEditMenu, acSelectRecord, , acMenuVer70
'Kopieren
DoCmd.DoMenuItem acFormBar, acEditMenu, acCopy, , acMenuVer70
DoEvents
'Am Ende anfügen
DoCmd.DoMenuItem acFormBar, acEditMenu, 5, 0, acMenuVer70

MsgBox "Datensatz wurde kopiert!", vbInformation, "Meldung!"
'kopierten Datensatz endgültig sichern
DoCmd.RunCommand acCmdSaveRecord
'Zum letzten Datensatz wechseln (=neu kopierter)
DoCmd.RunCommand acCmdRecordsGoToLast

'Kopieren der Inhalte des zuvor kopierten Datensatzes
Set dbs = CurrentDb
SQL = "INSERT INTO Inhalt ( InhaltID, Position, Leistung, Income1, Income2, Fee, Summe, StammID, FeeInfo, Bez_Income1, Bez_Income2 ) " & _
"SELECT " & Me.ID & " as InhaltID, Position, Leistung, Income1, Income2, Fee, Summe, StammID, FeeInfo, Bez_Income1, Bez_Income2 FROM Inhalt WHERE " & _
"(((Inhalt.StammID)=" & sichID & "))"
'MsgBox sql
dbs.Execute (SQL)

'Formular aktualisieren
Me.Requery
DoCmd.RunCommand acCmdRecordsGoToLast
If Not Err Then
MsgBox "Die Inhalte für " & Me.ID & " wurden kopiert!", vbInformation, "Kopieren erfolgreich"
End If

FehlerExit:
Exit Sub
FehleInhaltIDr:
If Err Then
MsgBox "Fehler: " & Err.Number & " / " & Err.Description & vbCrLf & "letzter SQL: " & SQL, vbExclamation, "Fehler!"
Resume FehlerExit
End If

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

gpswanderer · 12. Mai 2016

Hallo,
wie der Name schon sagt, sind Stammdaten die Stammdaten und somit feststehend. Wozu sollen diese kopiert werden und das auch noch mit den n-Datensätzen ?

Vielleicht gibt es ja ganz andere Lösungen.

jabra1307 · 12. Mai 2016

Zum Erstellen von Rechnungen.

In der Tabelle "Stamm" sind Felder wie "Kunde", "Leistung", "Datum", etc enthalten.

In der Tabelle "Inhalt" sind die eigentlichen abzurechnenden Leistungen drin.

Ich habe jeden Monat "wiederkehrende Rechnungen" bei welchen sich nur sehr wenig am eigentlichen Inhalt ändert und es würde mir die Arbeit extrem erelichtern, wenn ich den gesamten Datensatz aus dem Vormonat einfach kopieren könnte um kleiner Änderungen für den aktuellen Monat zu machen.

gpswanderer · 12. Mai 2016

Hallo,
kopiere mit 2 Anfügeabfragen und nicht mit den Menübefehlen ( DoCmd.DoMenuItem), die sind unbrauchbar, weil man Menüs ändern kann und die Befehle dann nicht mehr gefunden werden.
Was ich aber nicht verstehe ist das:

aber beim einfügen wird bei "StammID" nicht die neu erzeugte ID eingefügt, sondern die des Ursprungsdatensatzes.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Eine ID ist der Primärschlüssel und ein Primärschlüssel ist eindeutig, wenn die Tabelle korrekt ist, dürfte sich die gleiche ID (123) gar nicht anfügen lassen. Kannst Du das mal erklären.

Normalerweise hat man als ID einen Autowert, wenn man jetzt per Anfügeabfrage kopiert, lässt man diesen Autowert weg, es wird dann automatisch hochgezählt.

Mit der 1.Anfügeabfrage kopierst Du den Stammdatensatz.
Mit der 2. Anfügeabfrage koppierst Du die Details, dabei muss der Fremdschlüssel (die ID des neu kopierten Stammdatensatzes) ebenfalls gefüllt werden.

jabra1307 · 12. Mai 2016

Die "StammID" ist der Fremdschlüssel.
Primärschlüssel Tabelle Stamm: "ID"
Primärschlüssel Tabelle Inhalt: "InhaltID"

Mein Problem ist genau das. Nämlich dass in meinem Code der Fremdschlüssel nicht in das Feld "StammID" kopiert wird, sonder eben der des "alten" Datensatzes.

http://www.bilder-upload.eu/show.php...1463067266.png

drambeldier · 7. Januar 2021

Hi,

von jabra1307

Mein Problem ist genau das. Nämlich dass in meinem Code der Fremdschlüssel nicht in das Feld "StammID" kopiert wird, sonder eben der des "alten" Datensatzes.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

das sollte uns nicht wundern:
Code:

"(((Inhalt.StammID)=" & sichID & "))"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Schau mal, wo sichID herkommt.

Gruß
Ralf

drambeldier · 12. Mai 2016

Hi,

komm jetzt nicht ins Grübeln, ich bin nicht sicher, ob ich Deine Absicht überhaupt verstanden habe.

Wohin soll denn StammID zeigen? Am Parent hat sich nichts geändert, somit muss doch in der Kopie das Gleiche stehen wie in der Quelle - odrr?

Gruß
Ralf

MaggieMay · 7. Januar 2021

Hallo,

die Lösung findest du mAn in diesem Beitrag:

von gpswanderer

kopiere mit 2 Anfügeabfragen
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Nach dem Einfügen des Stammdatensatzes kannst du die dabei vergebene Autowert-ID folgendermaßen abfragen Code:

sichID_neu = CurrentDB.OpenRecordset("Select @@Identity")(0)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

und anstelle der "sichID" beim nachfolgenden Insert einsetzen.

siehe auch: http://www.access-im-unternehmen.de/589.0.html

ebs17 · 12. Mai 2016

Ein Beispiel zum Kopieren eines Datensatzes mit zugehörigen abhängigen Datensätzen (zweimal 1:n-Beziehung) kannst Du hier finden:
Kopie eines Datensatzes

jabra1307 · 5. Juli 2016

Vor lauter Frust, dass ich es partout nicht hinbekommen habe, habe ich die ganze Sache erst mal in die Ecke geschmissen. Nach ein paar Tagen hab ich mich aber noch mal drangesetzt und am Ende vor lauter Freude über den Erfolg vergessen Feedback zu geben, was ich hiermit gerne nachholen möchte:

Folgender Code hat mir Glückseligkeit beschert:

Code:

Dim db As DAO.Database
Dim rstRechnungen As DAO.Recordset
Dim rstPositionenAlt As DAO.Recordset
Dim rstPositionenNeu As DAO.Recordset
Dim lngRechnungID As Long
Set db = CurrentDb
Set rstRechnungen = db.OpenRecordset("Stamm", dbOpenDynaset)
With rstRechnungen
.AddNew
!Gesellschaft = Me!Gesellschaft
!Kunde = Me!Kunde
!Rechnungsstellung = Date
!ZielTage = Me!ZielTage
!Zahlungsziel = Date + Me!ZielTage
!Leistungsmonat = Me!Leistungsmonat
!Abrechnungsmonat = Me!Abrechnungsmonat
!Code = Me!Code
!Art = Me!Art
!Leistung = Me!Leistung
!Objektdaten = Me!Objektdaten
!GaNr = Me!GaNr
!ReferenzNr = Me!ReferenzNr
!Auftragsnummer = Me!Auftragsnummer
!Custom1 = Me!Custom1
!Text1 = Me!Text1
!Custom2 = Me!Custom2
!Text2 = Me!Text2
lngID = !ID
.Update
.Close
End With
Set rstPositionenAlt = db.OpenRecordset("SELECT * FROM Inhalt WHERE StammID = " & Me!ID, dbOpenDynaset)
Set rstPositionenNeu = db.OpenRecordset("SELECT * FROM Inhalt WHERE 1=2", dbOpenDynaset)
With rstPositionenAlt
Do While Not .EOF
rstPositionenNeu.AddNew
rstPositionenNeu!StammID = lngID
rstPositionenNeu!Position = !Position
rstPositionenNeu!Leistung = !Leistung
rstPositionenNeu!Income1 = !Income1
rstPositionenNeu!Income2 = !Income2
rstPositionenNeu!Fee = !Fee
rstPositionenNeu!FeeInfo = !FeeInfo
rstPositionenNeu!Bez_Income1 = !Bez_Income1
rstPositionenNeu!Bez_Income2 = !Bez_Income2
rstPositionenNeu.Update
.MoveNext
Loop
.Close
End With
Me.Requery
Me.Recordset.FindFirst "ID = " & lngID
Set rstPositionenNeu = Nothing
Set rstPositionenAlt = Nothing
Set rstRechnungen = Nothing
Set db = Nothing
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

MaggieMay · 5. Juli 2016

Hi,

und so sähe das mit einer SQL-Lösung aus: Code:

Dim db As DAO.Database
Dim strSQL As String
Dim lngID As Long
Set db = CurrentDb
strSQL = "Insert Into stamm (Gesellschaft, Kunde, Rechnungsstellung,ZielTage,Zahlungsziel,Leistungsmonat,Abrechnungsmonat,Code,Art,Leistung,Objektdaten,GaNr,ReferenzNr,Auftragsnummer,Custom1,Text1,Custom2,Text2) " & _
"Values(" & Me!Gesellschaft & ", " & _
Me!Kunde & ", Date(), " & _
Me!ZielTage & ", " & _
Format(Date + Me!ZielTage, "\#yyyy\/mm\/dd\#") & ", " & _
Me!Leistungsmonat & ", " & _
Me!Abrechnungsmonat & ", " & _
Me!Code & ", " & _
Me!Art & ", " & _
Me!Leistung & ", '" & _
Me!Objektdaten & "', " & _
Me!GaNr & ", " & _
Me!ReferenzNr & ", " & _
Me!Auftragsnummer & ", '" & _
Me!Custom1 & "', '" & _
Me!Text1 & "', '" & _
Me!Custom2 & "', '" & _
Me!Text2 & "')"
db.Execute strSQL, dbFailOnError
lngID = db.OpenRecordset("Select @@Identity From stamm")(0)

strSQL = "Insert Into Inhalt (StammID,Position,Leistung,Income1,Income2,Fee,FeeInfo,Bez_Income1 = !Bez_Income1,Bez_Income2) " & _
"Select " & lngID & ", Position,Leistung,Income1,Income2,Fee,FeeInfo,Bez_Income1,Bez_Income2 " & _
"From Inhalt Where StammID = " & Me!ID
db.Execute strSQL, dbFailOnError
Set db = Nothing

Me.Requery
Me.Recordset.FindFirst "ID = " & lngID
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Auch eine Kombination aus beiden Verfahren, Recordset und SQL-Abfrage wäre möglich.

PS:
In der ersten Abfrage mit der Value-Liste müssen die Datentypen beachtet werden, Texte in Hochkommata, Datum formatiert, etc.
Ich habe das mal nach Gutdünken eingesetzt, damit du siehst wie es geht, da ich die Datentypen deiner Datenfelder nicht kenne.

Office: (Office 2016) Datensatz mit Unterformular duplizieren

Datensatz mit Unterformular duplizieren

Datensatz mit Unterformular duplizieren

Datensatz mit Unterformular duplizieren

Datensatz mit Unterformular duplizieren

Datensatz mit Unterformular duplizieren - Similar Threads - Datensatz Unterformular duplizieren

MS Access Formular: Datensatz duplizieren mit Unterformularen

Datensätze im unterformular nach suche Filtern

Listenfeld in Unterformular soll auf Datensatz des Hauptformulars reagieren

Im Unterformular bestehenden Datensatz auswählen

neuer datensatz in unterformular per button click mit festem wert einfügen

Datensatz im Unterformular suchen

Datensätze duplizieren aus Haupt- und Unterformular