Office: (Office 365) Datu abgleiche und in Kalender eintragen

Hallo, ich habe folgendes Problem. Ich möchte einen automatischen Kalender basteln, in dem auf der ersten Seite lediglich Datum, Person und krank/urlaub eingetragen werden sollen.
Aus dieser Liste möchte ich dann in einem Kalender mit anzeigen lassen, ob die Person an dem Tag Anwesend (A), Krank (K) oder Urlaub (U) hatte.
Leider komm ich mit Index+Vergleich nicht weiter.
Habt ihr vll eine Idee? Vielen Dank schonmal
Gruß Q

 

Du möchtest Prüfen ob Deine Eingabe z.B "Krank" richtig ist?

 

Nein, ich möchte, dass die Kalender-Liste sich automatisch füllt, also bei Person 1 als Bsp. würde dann ein K beim 1.1.23 beim 2.1.23 usw bis zum 5.1.23 stehen

 

Gut dann habe ich diese Aussage
"Aus dieser Liste möchte ich dann in einem Kalender mit anzeigen lassen, ob die Person an dem Tag Anwesend (A), Krank (K) oder Urlaub (U) hatte."
wohl falsch interpretiert und bin raus.

Gruß Hajo

 

Trotzdem danke für deine schnelle Antwort :)

 

Hallo Quiena,

folgende Formel in C5:

=WENNFEHLER(INDEX(Eingabe[[Status]:[Status]];AGGREGAT(15;6;(ZEILE(Eingabe)-ZEILE(Eingabe[#Kopfzeilen]))/(Eingabe[[Datum von]:[Datum von]]<=$B5)/(Eingabe[[Datum bis]:[Datum bis]]>=$B5)/(Kalender[[#Kopfzeilen];[Person 1]]=Eingabe[[Person]:[Person]]);1));"")

Dies kopiert sich automatisch nach unten Nach rechts musst Du diese kopieren.

 

Super es hat funktioniert :D
Vielen dank

 

Hallo, ich bräuchte tatsächlich noch einmal Hilfe bei dieser Liste
Und zwar möchte ich jetzt die Datumsangaben in der Eingabe überprüfen ob ein Datum schonmal verwendet wurde. wenn also für Person 1 eingetragen wurde 3.1. bis 7.1. Urlaub und dann 4.1. bis 5.1. für die selbe Person Krank soll in einer Spalte nebendran ein Hinweis kommen (zB Achtung Datum überschneidet sich) und das i Tüpfelchen wäre wenn dann noch die Zellenadresse genannt wird bzw die Zeile sodass der Benutzer das Datum nachträglich korrigieren kann. Hat da jemand eine Idee?

 

Hallo Quiena,

momentan wertet die Formel die Angaben aus, die in der Eingabeliste zuerst eingeschrieben wurden. Danach eingeschriebene Angaben zur Person an gleichen Tagen werden ignoriert.
Wenn Du aber in der Formel das 1. Argument von AGGREGAT() die 15 durch eine 14 ersetzt, werden nur die zuletzt im Eingabetabellenblatt erfasst Daten im Kalender für die entsprechenden Tage angezeigt. Wenn Du das so ausführst kann man sich das zusätzlich von Dir beschriebene sparen. Oder?

 

Mir wäre es lieber wenn ich es in einer extra spalte hab da ich die datumsangaben für weitere Berechnungen benötige und die daher stimmen müssen. Doppelbelegungen darf es keine geben.

 

Hallo Quiena,

dann würde ich es gleich in der Eingabeerfassung vornehmen. Dies z.B. wie folgt:

Arbeitsblatt mit dem Namen 'Eingabe'
	B	C	D	E	F	G
2					Überschneidung
3	Datum von	Datum bis	Person	Status	von	bis
4	01.01.2023	05.01.2023	Person 1	K	03.01.23	05.01.23
5	03.01.2023	15.01.2023	Person 2	U
6	08.01.2023	15.01.2023	Person 1	U
7	12.01.2023	18.01.2023	Person 3	U	12.01.23	18.01.23
8	20.01.2023	25.01.2023	Person 2	K
9	03.01.2023	06.01.2023	Person 1	U	03.01.23	05.01.23
10	05.01.2023	26.01.2023	Person 3	K	12.01.23	18.01.23
11

Zelle	Formel
F4	=WENNFEHLER(MAX(AGGREGAT(14;6;[Datum von]/([Datum bis]>=[@[Datum von]])/([Datum von]<=[@[Datum bis]])/([Person]=[@Person])/([Status]<>[@Status]);1);[@[Datum von]]);"")
G4	=WENNFEHLER(MIN(AGGREGAT(15;6;[Datum bis]/([Datum bis]>=[@[Datum von]])/([Datum von]<=[@[Datum bis]])/([Person]=[@Person])/([@von]<>"");1);[@[Datum bis]]);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

 

Super nochmal vielen dank

 

Bitteschön.