Office: Datum in Excel Tabellen

Hallo ....

Ich hoffe das mir jemand helfen kann

Ich habe folgendes Problem ich bin dabei ein Kassenbuch in Excel zu erstellen und möchte gerne wenn ich in der Spalte H die ENTER taste gedrückt habe in der nächsten Zeile in Spalte A das aktuelle Datum haben und in Spalte B eine fortlaufende Beleg Nummer haben so das ich gleich in spalte C mit meinem Text anfangen kann......

Kann mir da jemand helfen ???????????
Danke danke danke

 

Hallo Joe,

es wird Dir klar sein, dass die folgende Anforderung nur mit einem VBA-Makro durchgeführt werden kann

Und nun die VBA-Makros zum Behandeln von 3 Arbeitsmappen-Ereignissen:

Code:

Private Sub Workbook_Activate()
  With Application
    .MoveAfterReturn = True
    .MoveAfterReturnDirection = xlToRight
  End With
End Sub

Private Sub Workbook_Deactivate()
  With Application
    .MoveAfterReturn = True
    .MoveAfterReturnDirection = xlDown
  End With
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
  If Target.Column = 9 Then
    Cells(Target.Row + 1, 3).Select
    With ActiveCell.Offset(0, -2)
      If .Value = "" Then
        .NumberFormat = "DD.MM.YYYY"
        .Value = Int(Now())
  '      .Formula = "=TODAY()"
      End If
    End With
    With ActiveCell.Offset(0, -1)
      If .Value = "" Then
  '      .FormulaR1C1 = "=R[-1]C+1"
        .Value = .Offset(-1, 0).Value + 1
      End If
    End With
  End If
End Sub

1) Die 1. Ereignisbehandlung 'Workbook_Activate' bewirkt, dass immer dann, nachdem diese Arbeitsmappe aktiviert (oder geöffnet) worden ist, der Zellzeiger eine horizontale Bewegung ausführt, wenn man die EINGABE-Taste drückt.

2) Die 2. Ereignisbehandlung 'Workbook_Deactivate' bewirkt, dass immer dann, nachdem diese Arbeitsmappe deaktiviert (oder geschlossen) worden ist, der Zellzeiger eine vertikale Bewegung ausführt, wenn man die EINGABE-Taste drückt.

3) Die 3. Ereignisbehandlung 'Workbook_SheetSelectionChange(...)' bewirkt Folgendes:
Ist der Zellzeiger in einer Zelle der Spalte H angelangt und wird die EINGABE-Taste gedrückt, springt der Zellzeiger in die nächste Zeile und zwar in Spalte C. Dabei wird aber gleichzeitig in der Spalte A das heutige Datum eingetragen und in Spalte B eine fortlaufende Nummer (um 1 höher als in der Vorzeile) eingetragen. Dabei kann man, wenn man will, diese erzeugte Nummer abändern.

4) Installation der Makros:
Falls Du nicht weißt, wie man das macht - hier ist die Schritt-für-Schritt-Anleitung:
a) Den vorigen weißen Bereich mit den Makros mit der Maus markieren, die Tastenkombination Strg+C drücken, um sie in die Zwischenablage zu kopieren.
b) Dann wechselst Du zurück in Dein (Kassen)Arbeitsblatt, drückst dort die Tastenkombination Alt+F11. Dadurch wird der VBA-Editor geöffnet.
c) Dort drückst Du die Tastenkombination Strg+R, um das Projekt-Explorer-Fenster anzuzeigen (falls es noch nicht sichtbar sein sollte).
Dort suchst Du Dir den Eintrag 'Microsoft Excel Objekte' und unmittelbar darunter muss es den Eintrag 'DieseArbeitsmappe' geben. Auf diesen Eintrag machst Du einen Doppelklick, sodass sich das Codemodul-Fenster für die Arbeistmappe (Workbook-Objekt) öffnet.
d) In diesem drückst Du die Tastenkombination Strg+V, um die kopierten Makros einzufügen, die damit als Programmcode wieder sichtbar werden.
e) Du wechselt daraufhin wieder zurück in Dein Arbeitsblatt und speicherst die Arbeitsmappe, damit die Änderungen nicht mehr verloren gehen können.

Das wär's. Wie Du Dich überzeugen kannst, zeigen alle Arbeitsblätter Deiner Arbeitsmappe dieses oben geschilderte neue Verhalten. Andere (geöffnete) Arbeitsmappen sind davon nicht betroffen.