Office: Datum in Zeile finden und Spalten-Index zurückgeben

Gleitschirmflieger · 28. Juli 2014

Hallo liebe potenziellen Helfer,

steh grad auf'm Schlauch:
Code:

zRStPos = .Range("S10", .Cells(10, spalteDash)).Find(CDate(zRStart))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bringt:

Laufzeitfehler'91':
Objektvariable oder With-Blockvariable nicht festgelegt

Code:

zREnPos = .Range("S10", spalteDash & "10").Find(CDate(zREnde))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bringt:

Laufzeitfehler'1004':
Anwendungs- oder objektdefinierter Fehler

*rolleyes.gif* ?????

Hier der ganze Code:
Code:

Private Sub zeitraumEintrag()
Dim zRStart As Date 'Variable für Start-Datum
Dim zREnde As Date ' Variable für End-Datum
Dim zRStPos As Integer ' Variable für Spalten-Index der Zelle des Start-Datums
Dim zREnPos As Integer ' Variable für Spalten-Index der Zelle des End-Datums
Dim spalteDash As Integer 'Variable für Spalten-Index
zRStart = "14.01.2014" 'Zu Testzwecken Wertzuweisung Start-Datum
zREnde = "16.01.2014" 'Zu Testzwecken Wertzuweisung Start-Datum
With ActiveWorkbook.Worksheets("Dashboard") 'Bezug
spalteDash = .Cells(10, Columns.Count).End(xlToLeft).Column 'letzte Spalte in Zeile 10 wird ermittelt
zRStPos = .Range("S10", .Cells(10, spalteDash)).Find(CDate(zRStart)) 'Spalten-Index der Zelle mit dem Start-Datum ermitteln (funktioniert nicht)
zREnPos = .Range("S10", "S" & spalteDash).Find(CDate(zREnPos)) 'Spalten-Index der Zelle mit dem End-Datum ermitteln (funktioniert nicht)
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, Frank

:)

aloys78 · 30. Juli 2014

Hallo Frank,

ein Vorschlag für den Ersatz der ersten Anweisung
Code:

Dim c As Range 'Ergebnis Find
Set c = .Range(.Cells(10, 19), .Cells(10, spalteDash)).Find(CDate(zRStart), LookIn:=xlValues, lookAt:=xlWhole)
If Not c Is Nothing Then
'gefunden
zRStPos = c.Column

Else
'nicht gefunden

End If
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß
Aloys

Beverly · 30. Juli 2014

Hi Frank,

du kannst anstelle von Find auch die WorksheetFunction Match verwenden (entspricht der Formel VERGLEICH):

Code:

If Not IsError(Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)) Then
zRStPos = Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0) + 18 'Spalten-Index der Zelle mit dem Start-Datum ermitteln (funktioniert nicht)
End If
If Not IsError(Application.Match(CDbl(zREnde), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)) Then
zREnPos = Application.Match(CDbl(zREnde), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0) + 18 'Spalten-Index der Zelle mit dem End-Datum ermitteln (funktioniert nicht)
End If
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gleitschirmflieger · 30. Juli 2014

Danke Aloys und Karin!

Nach langem rumtüfteln hab ich das .Find() aufgegeben (Denke es lag am Format des Datums) und mich für Karin's Application.Match Version entschieden.
Funktioniert einwandfrei!

Nochmals vielen herzlichen Dank!

Schöne Grüße,
Frank

Gleitschirmflieger · 30. Juli 2014

Hallo Karin, (... oder wer sich berufen fühlt)

gestern beim schnellen Test-File hats prima funktioniert, ... heute im echten Projekt leider nicht. Ich vermute das Problem hat seine Ursache in irgendeiner Formatierung ... oder einem leichtsinnsfehler den ich übersehe.

Hier mein Code mit Kommentaren:

Code:

Private Sub zeitraumEintrag()
'Variable für den ersten Tag
Dim zRStart As Date
'Variable für den letzten Tag
Dim zREnde As Date
'Variable für den Spalten-Index des ersten Tags
Dim zRStPos As Integer
'Variable für den Spalten-Index des letzten Tags
Dim zREnPos As Integer
'Variable für den Spalten-Index des letzten Tags im Kalender
Dim spalteDash As Integer
'Spalten-Index des letzten Tags im Kalender ermitteln und der Variable übergeben
spalteDash = Sheets("Dashboard").Cells(10, Columns.Count).End(xlToLeft).Column
'Bezug
With Sheets("Daten")
'Ersten Tag (User-Input) an Variable übergeben (Test mit 03.01.2014)
zRStart = .Cells(zeileData, 7)
'Letzten Tag (User-Input) An Variable übergeben (Test mit 13.01.2014)
zREnde = .Cells(zeileData, 9)
'Bezug Ende
End With
'Bezug auf den Bereich mit den Datums-Werten vom 01.01.2014 bis 31.01.2015(Format = Zahl für den Test (siehe Variablen) Normalerweise Benutzerdefiniert "TT" = Bsp.: "02.01.2014" wird mit "02" angezeigt)
With Sheets("Dashboard").Range(Cells(10, 19), Cells(10, spalteDash))
'Prüfung ob der Vergleich einen Fehler ergibt.
If Not IsError(Application.Match(CDbl(zRStart), .Range(Cells(10, 19), (Cells(10, spalteDash))), 0)) Then
'Werte der Variablen:
'zRStart = 03.01.2014, CDbl(zRStart) = 41642, spalteDash = 414, Cells (10,19) = 41640, Cells (10,spalteDash) = 42035
'Bis hierhin Funktioniert es prima, ... Aaaaber:
'Spalten-Index des gesuchten Datum-Wertes übergeben.
zRStPos = Application.Match(CDbl(zRStart), .Range(Cells(10, 19), (Cells(10, spalteDash))), 0)
'Problem: zRSTPos = 0 ... sollte aber 21 sein, gemäß des Index der Spalte in der das Datum 03.01.2014 steht.
End If
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Vielen Dank vorab für jede Hilfestellung!

Gruß,
Frank

Luschi · 31. Juli 2014

Hallo Frank,

hier mal die Gegenüberstellung von:
'Karins Vorschlag
zRStPos = Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)
'Deine Umsetzung
zRStPos = Application.Match(CDbl(zRStart), .Range(Cells(10, 19), (Cells(10, spalteDash))), 0)

Fällt Dir dabei was auf? Ich meine nicht die Anzahl der Klammern bei Deinem Code.

Gruß von Luschi
aus klein-Paris

Gleitschirmflieger · 31. Juli 2014

Vielen Dank Luschi,

neben zwei weiteren Fehlern wars das.

Hier die Fehler im Detail:

If Not IsError(Application.Match(CDbl(zRStart), .Range(*mad.gif* Cells (10, 19), (*mad.gif* Cells(10, spalteDash))*mad.gif* ), 0)) Then

1.*mad.gif* = Punkt fehlt
2.*mad.gif* = Klammer zuviel und Punkt fehlt
3.*mad.gif* = Klammer zu viel

So ists richtig:

If Not IsError(Application.Match(CDbl(zRStart), .Range(.Cells (10, 19), .Cells(10, spalteDash)), 0)) Then

Weiterer Fehler:

With Sheets("Dashboard")*mad.gif* .Range(Cells(10, 19), Cells(10, spalteDash))
If Not IsError(Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)) Then

1.*mad.gif* = Doppelter Bezug

So ist's richtig:

With Sheets("Dashboard")
If Not IsError(Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)) Then
zRStPos = Application.Match(CDbl(zRStart), .Range(.Cells(10, 19), .Cells(10, spalteDash)), 0)
End If
End With

Und noch einer:

zRStPos = Application.Match(CDbl(zRStart), .Range(.Cells(10, 19*mad.gif* ), .Cells(10, spalteDash)), 0)

*mad.gif* = Wenn ich erst bei 19 anfange zu zählen kann zRStPos nicht wie erwartet 21 (gemäß des Spalten-Index in der das Datum steht) sein sondern 3! Also entweder zRStPos + 18 oder ab der ersten Spalte zählen.

Wie anfangs vermutet alles Leichtsinnsfehler.
Aber doch wieder was gelernt.

Danke an alle Helfenden!

Gruß,
Frank

Office: Datum in Zeile finden und Spalten-Index zurückgeben

Datum in Zeile finden und Spalten-Index zurückgeben

Datum in Zeile finden und Spalten-Index zurückgeben

Datum in Zeile finden und Spalten-Index zurückgeben

Datum in Zeile finden und Spalten-Index zurückgeben - Similar Threads - Datum Zeile Spalten

Zeile in Bereich mit Datum füllen

Wenn ein Datum zwischen 2 Daten liegt dann schreibe in Zeile

VBA: Datum automatisch hinzufügen nach Übertrag

Kleinstes Datum finden und Zeile ausgeben

Ganze Zeile farbig färben, wenn in Spalte ein Datum steht

Zählen einer anderen Zeile bei Abgleich eines Datums und Wort in einem Bereich

Wenn Datum erreicht, Wert aus Zeile kopieren, der nicht mehr verändert werden kann