Office: Datum und Zeit aus einer Zelle extrahieren

Moin zusammen,
ich habe einen Datenexport gemacht und aus diesem eine Tabelle gemacht.
Jetzt habe ich aber als Datum eine Angabe die aus Datum und Zeit in einer Zelle besteht.
Beispiel: 2024-01-08 16:56:04

Ich möchte jetzt in einer Zelle das Datum und in einer Zelle die Zeit haben, ich gehe einmal davon aus, dass dies möglich ist.
Ich würde mich über Eure Hilfe sehr freuen.

 

Hallo,

du hast ein Leerzeichen (Blank) zwischen Datum und Uhrzeit. Datum ist der vordere Teil; Zeit der hintere Teil:
=DATWERT(TEIL(A2; 1; FINDEN(" "; A2;1) - 1))
=ZEITWERT(TEIL(A2; FINDEN(" "; A2;1) + 1; 9))
beide Zellen nach Wunsch formatieren.

Gruß Sigi

 

Hallo,

wenn du in Zelle A1 deine Beispieldaten hast:
in Zelle B1: =GANZZAHL(A1) und diese formatieren mit TT.MM.JJJJ
in Zelle C1: =A1-B1 und diese formatieren mit hh:mm:ss

 

Euch Beiden ganz viel Dank, super schnell und hilfreich!
Zwei Anmerkungen:
Siggi: Deine Formeln haben wunderbar funktioniert. Ich bin ja Anfänger und möchte natürlich auch die Formeln verstehen. Könntest Du, natürlich nur wenn Du die Zeit hast, einmal erläutern wie sich die Formel aufbaut? DATWERT und ZEITWERT leuchtet mir ein, die "" Sorgen vermutlich dafür, dass die Zelle leer bleibt wenn Datum oder Zeit nicht gefunden werden. Aber ;-) was macht die "1" hinter A2; und was die "-1" bzw. 9?
Schon jetzt vielen Dank.
Anton: Vielen Dank, dass Du auch so schnell geantwortet hast. Deine Formel funktioniert bei mir aber nicht. Die Extraktion "Datum" funktioniert, Zeit aber nicht. Hier erhalte ich die Meldung: Inkonsistente berechnete Spaltenformel. Sicher mache ich irgendetwas falsch .

 

Hallo,

davon, dass du deine Daten als Texte vorliegen hast, hattest du nichts geschrieben.
Außerdem wenn du Excel365 hast, geht es auch so:
Formel in B1: =WERT(TEXTVOR(A1;" "))
Formel in C1: =WERT(TEXTNACH(A1;" "))

 

Wenn das Datum tatsächlich als Text vorliegt (ganz schlechte Idee!!), dann reicht bei aktuellem Excel eine einzige Formel:
=TEXTTEILEN(A1;" ")
bzw. wenn es danach ein echtes Datum/Uhrzeit sein soll:
=--TEXTTEILEN(A1;" ")

Und wenn in A1 kein Text sondern ein echter Zeitstempel steht, dann bekommt man alternativ zu Anton die Uhrzeit in C1 auch mit =REST(A1;1)

 

Hallo Ahnungsloser,

s. Mappe mit Erklärung.

Gruß Sigi

 

Und noch eine Möglichkeit:
=GANZZAHL(--A1)
=REST(--A1;1)

PS: merke gerade, dass die Formel von Anton (also ohne die doppelten Minus-Zeichen in der Formel hier) doch wunderbar funktioniert. Auch wenn in A1 ein Text steht!

 

Euch allen noch einmal vielen, vielen Dank für Eure Mühe. Problem ist somit gelöst.