Office: Datum vor 1900-nächster Geburtstag

Helfe beim Thema Datum vor 1900-nächster Geburtstag in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo Excel-Gemeinde, die Altersberechnung, wenn das Geburtsdatum vor 1900 liegt, habe ich hinbekommen. An der Berechnung des nächsten... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von florian-112, 2. Mai 2009.

  1. florian-112 Erfahrener User

    Datum vor 1900-nächster Geburtstag


    Hallo Excel-Gemeinde,

    die Altersberechnung, wenn das Geburtsdatum vor 1900 liegt,
    habe ich hinbekommen.

    An der Berechnung des nächsten Geburtstags und des Altes dann,
    scheitere ich leider und bitte um eure Hilfe.

    Meine Tabelle seht ihr hier:
    http://www.file-upload.net/download-1616484/Gebtg-test.xls.html

    Vielen Dank schon mal.
    Gruß florian
     
    florian-112, 2. Mai 2009
    #1
  2. Exl121150 Erfahrener User
    Hallo Florian,

    hier die etwas länglichen Formeln:
    Zelle C3: Alter in vollen Jahren am heutigen Tag:
    =WENN($A3="";"";DATEDIF(WENN(ISTTEXT($A3);DATWERT(ERSETZEN($A3;LÄNGE($A3)-3;4;1900));$A3);HEUTE();"y")+WENN(ISTTEXT($A3);1900-RECHTS($A3;4);0))

    Zelle E3: Falls bereits gestorben: Alter in vollen Jahren am Todesdatum:
    =WENN(ODER($A3="";$D3="");"";DATEDIF(WENN(ISTTEXT($A3);DATWERT(ERSETZEN($A3;LÄNGE($A3)-3;4;1900));$A3);$D3;"y")+WENN(ISTTEXT($A3);1900-RECHTS($A3;4);0))

    Zelle F3: Nächster Geburtstag (ab heutigem Tag):
    =WENN($A3="";"";DATWERT(WENN(ISTTEXT($A3);LINKS($A3;LÄNGE($A3)-4);TEXT($A3;"TT.MM."))&(JAHR(HEUTE())+(TEXT(HEUTE();"MMTT")>=TEXT(WENN(ISTTEXT($A3);DATWERT(ERSETZEN($A3;LÄNGE($A3)-3;4;1900));$A3);"MMTT")))))

    Zelle G3: Alter in Jahren zum Datum F3:
    =WENN($A3="";"";$C3+1)
     
    Exl121150, 2. Mai 2009
    #2
  3. florian-112 Erfahrener User
    Hallo Exl121150,
    vielen Dank für deine Hilfe.
    Die Formeln passen super.

    Gruß florian
     
    florian-112, 2. Mai 2009
    #3
  4. florian-112 Erfahrener User

    Datum vor 1900-nächster Geburtstag

    Hallo,
    ich noch mal zu dem Thema.
    Die Formeln von Exl121150 sind ok.
    Ein kleines Problem ergibt sich jedoch noch.
    Wenn das Todesdatum auch vor 1900 liegt, kommt Fehler "#Wert!" beim Alter am Todestag.

    Vielleicht hat da noch jemand eine Lösung.
    Vielen Dank schon mal.

    Gruß florian
     
    florian-112, 2. Mai 2009
    #4
  5. Exl121150 Erfahrener User
    Hallo Florian,

    um die Formeln durch die zusätzliche Behandlung des Todesdatums nicht total unübersichtlich werden zu lassen,

    1) definiere zuerst einmal 4 Namen:
    1a) Stelle dazu die aktive Zelle irgendwo in Zeile 3 des Arbeitsblattes
    1b) Wähle im Excel-Menü: Einfügen > Namen > Namen definieren... , sodass das Dialogfenster 'Namen definieren' erscheint.
    1c) In dieses gib ins Feld 'Namen in der Arbeitsmappe' Folgendes ein: Tabelle1!GEB1900
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($A3);DATWERT(ERSETZEN($A3;LÄNGE($A3)-3;4;1900));DATUM(1900;MONAT($A3);TAG($A3)))
    Klicke auf den Schalter 'Hinzufügen'.
    1d) Gib ferner ins Feld 'Namen in der Arbeitsmappe' ein: Tabelle1!GEBDF1900
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($A3);1900-RECHTS($A3;4);1900-JAHR($A3))
    Klicke auf den Schalter 'Hinzufügen'.
    1e) Gib ferner ins Feld 'Namen in der Arbeitsmappe' ein: Tabelle1!TOD1900
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($D3);DATWERT(ERSETZEN($D3;LÄNGE($D3)-3;4;1900));DATUM(1900;MONAT($D3);TAG($D3)))
    Klicke auf den Schalter 'Hinzufügen'.
    1f) Gib ferner ins Feld 'Namen in der Arbeitsmappe' ein:Tabelle1!TODDF1900
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($D3);1900-RECHTS($D3;4);1900-JAHR($D3))
    Klicke auf den Schalter 'Hinzufügen'.
    Nachdem jetzt die 4 Namen definiert sind, klicke auf Schalter 'Ok', damit sich das Fenster schließt.

    2) Dadurch vereinfacht sich jetzt die Formeleingabe:
    Zelle C3: Alter in vollen Jahren am heutigen Tag:
    =WENN(A3="";"";DATEDIF(GEB1900;HEUTE();"y")+GEBDF1900)
    Zelle E3: Falls bereits gestorben: Alter in vollen Jahren am Todesdatum:
    =WENN(ODER($A3="";$D3="");"";DATEDIF(GEB1900;TOD1900;"y")+GEBDF1900-TODDF1900)
    Zelle F3: Nächster Geburtstag (ab heutigem Tag):
    =WENN($A3="";"";DATWERT(TEXT(GEB1900;"TT.MM.")&(JAHR(HEUTE())+(TEXT(HEUTE();"MMTT")>=TEXT(GEB1900;"MMTT")))))
    Zelle G3: Alter in Jahren zum Datum F3:
    =WENN($A3="";"";$C3+1)
    wie bereits gehabt.

    3) Diese 4 definierten Namen sind so konstruiert, dass sie nicht nur für die Zeile 3 gelten, sondern auch in allen nachfolgenden Zeilen (mit gleichem Spaltenaufbau) verwendet werden können.
     
    Exl121150, 2. Mai 2009
    #5
  6. florian-112 Erfahrener User
    Hallo Exl121150,
    du bist einfach super :!: :!: :!:
    Deine Lösung ist perfekt.
    Das hätte ich mit meinem bescheidenen Anfängerwissen alleine nie geschafft.
    Du hast mir sehr geholfen!!!
    Vielen lieben Dank für deine Hilfe.

    Gruß Florian
     
    florian-112, 2. Mai 2009
    #6
  7. florian-112 Erfahrener User
    Hallo Exl121150,

    da bin ich noch einmal.
    Ich möchte dich nicht neven und überbeanspruchen,
    aber ich möchte dich über einen Fehler informieren.

    Beim Alter am Todestag kommt #ZAHL! wenn der Monat des Todesdatum vor dem Monat des Geburtsdatum liegt. Bei Daten vor und nach 1900.

    Beisp. Gebtag 04.07.1907 Ttag 07.03.1987

    Gruß Florian
     
    florian-112, 2. Mai 2009
    #7
  8. Exl121150 Erfahrener User

    Datum vor 1900-nächster Geburtstag

    Hallo Florian,

    Du hast recht, es erscheint unter bestimmten Bedingungen der Fehler #ZAHL! in Spalte E.
    Urschache des Fehlers ist die Datumsdifferenz-Funktion DATEDIF(AnfDat;EndeDat;Einheit). Diese erwartet offenbar stets, dass 'AnfDat' vor 'EndeDat' liegt, ansonsten kommt es zu einem Fehler.
    Meine beiden Namen 'GEB1900' und 'TOD1900' bilden (wie die Bezeichnung schon sagen will) das Geburtsdatum und das Todesdatum auf das Jahr 1900 ab, während die beiden Namen 'GEBDF1900' und 'TODDF1900' die jeweilige Jahresdifferenz zum Jahr 1900 ermitteln. Dadurch wird zB. das Geburtsdatum '10.08.1890' auf GEB1900='10.08.1900' und der Todestag '09.08.1899' auf TOD1900='09.08.1900' abgebildet, was in der Jahresdifferenzfunktion DATEDIF("10.08.1900";"09.08.1900";"y") den Fehler verursacht.
    Um den Fehler zu beseitigen, genügt es, den Todestag nicht auf das Jahr 1900, sondern auf das Jahr 1901 abzubilden.

    1a) Stelle dazu die aktive Zelle irgendwo in Zeile 3 des Arbeitsblattes
    1b) Wähle im Excel-Menü: Einfügen > Namen > Namen definieren... , sodass das Dialogfenster 'Namen definieren' erscheint
    1c) Wähle den Namenseintrag 'TOD1900' aus und klicke den Schalter 'Löschen'
    1d) Wähle den Namenseintrag 'TODDF1900' aus und klicke den Schalter 'Löschen'
    1e) Gib ferner ins Feld 'Namen in der Arbeitsmappe' ein: Tabelle1!TOD1901
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($D3);DATWERT(ERSETZEN($D3;LÄNGE($D3)-3;4;1901));DATUM(1901;MONAT($D3);TAG($D3))) Klicke auf den Schalter 'Hinzufügen'.
    1f) Gib ferner ins Feld 'Namen in der Arbeitsmappe' ein:Tabelle1!TODDF1901
    im Feld 'Bezieht sich auf:' gib Folgendes ein:
    =WENN(ISTTEXT($D3);1901-RECHTS($D3;4);1901-JAHR($D3))
    Klicke auf den Schalter 'Hinzufügen'.
    Nachdem jetzt wieder die 4 Namen definiert sind, klicke auf Schalter 'Ok', damit sich das Fenster schließt.

    2) Dadurch vereinfacht sich jetzt die Formeleingabe:
    Zelle E3: Falls bereits gestorben: Alter in vollen Jahren am Todesdatum:
    =WENN(ODER($A3="";$D3="");"";DATEDIF(GEB1900;TOD1901;"y")+GEBDF1900-TODDF1901)

    3) Ich habe im Vorhergehenden die geänderten Stellen blau gekennzeichnet und hoffe, dass damit sämtlichen Tücken entfernt sind.

    4) Eine persönliche Bemerkung zum Schluss: Da Du offenbar Florian heißt und morgen im Kalender der Hl. Florian steht, möchte ich Dir (so wie es in Österreich teilweise noch Brauch ist) zum Namenstag alles Gute wünschen.
    -- aus St. Florian b. Linz in Oberösterreich.
     
    Exl121150, 3. Mai 2009
    #8
  9. florian-112 Erfahrener User
    Hallo Exl121150,

    deine neue Version funktioniert jetzt fehlerfrei. :!:

    Du hast dir sehr viel Mühe gemacht und Zeit investiert.
    Dafür bedanke ich mich recht herzlich bei dir.

    Vielen lieben Dank auch für deine persönlichen Glückwünsche.

    Liebe Grüße aus Göttingen in Niedersachsen
    florian
     
    florian-112, 3. Mai 2009
    #9
Thema:

Datum vor 1900-nächster Geburtstag

Die Seite wird geladen...
  1. Datum vor 1900-nächster Geburtstag - Similar Threads - Datum 1900 nächster

  2. Datum filtern...

    in Microsoft Excel Hilfe
    Datum filtern...: Hallo zusammen, ich habe eine Tabelle und in der ersten Spalte befindet sich das Datum. Der Zeitraum bewegt sich vom 01.01.2020 bis zum 31.12.2039 (jedes Datum ==> eine Zeile). Nun würde mich...
  3. Tabellenübersicht aus mehreren Tabellen nach Datum sortieren

    in Microsoft Excel Hilfe
    Tabellenübersicht aus mehreren Tabellen nach Datum sortieren: Hallo, ich habe eine Tabelle für die Autowartung erstellt und möchte nun eine Übersichtseite als "Deckblatt" erstellen auf dem man alle wichtigen Daten sehen kann. Es gibt für alles auf einem...
  4. Feiertage ohne Wochenende zählen

    in Microsoft Excel Hilfe
    Feiertage ohne Wochenende zählen: Hallo Zusammen Während ich das Thema geschrieben habe, konnte ich eine Lösung finden. *:D* Habe das Thema aber trotzdem gepostet, falls jemand auf dasselbe Problem stossen sollte bzw. jemand die...
  5. VBA: Datum automatisch hinzufügen nach Übertrag

    in Microsoft Excel Hilfe
    VBA: Datum automatisch hinzufügen nach Übertrag: Hallo zusammen, ich habe ein Makro gebaut, welches die Daten aus dem Tabellenblatt Bestellformular kopiert und diese in ein anderes Tabellenblatt (Bestellhistorie) überträgt, wobei zusätzlich in...
  6. Feldauswahl - neu Spalte mit Datumauswahl

    in Microsoft Outlook Hilfe
    Feldauswahl - neu Spalte mit Datumauswahl: Hallo, ich habe in Outlook 365 eine Aufgabenliste mit benutzerdefinierten Spalten angelegt. Nun möchte ich eine Spalte mit der selben Funktion wie die vorhandene Spalte Startdatum hinzufügen. Bei...
  7. Datum vor 1900 wird als Negative Zahl dargestellt

    in Microsoft Excel Hilfe
    Datum vor 1900 wird als Negative Zahl dargestellt: Habe eine Mitgliedertabelle als alter Zeit, darin sind Geburtsdaten eingetragen, die bei einigen Mitgliedern als negative Zahl dargestellt wird z.B. (-1745). Ich weiß, dass diese Personen dann vor...
  8. Datum vor 1900

    in Microsoft Excel Hilfe
    Datum vor 1900: WinXP Prof. SP2 Office XP Hallo zusammen, ich habe in meiner Geburtstagsliste ein Datum Vor 1900. Wie kann ich das Datum zum sortieren teilen? =DATUM(;MONAT(A1);TAG(A1)) ??? Das...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden