Office: Datumsformat und nicht den Datumswert als Dateiname speichern

Burleypacker · 2. Dezember 2014

Hallo MS-Office_User!

Ich habe mir ein kleines Makro zusammen gestellt, was mir das aktive Arbeitsblatt als PDF Datei und mit einen bestimmten Dateinamen speichern soll, der aus 2 Zellen im Arbeitsblatt ausgelesen wird.
In diesem Code speichere ich mein Arbeitsblatt erstmal nur auf den Desktop des aktiven Userprofil´s.
Soweit so gut...

Code:

Sub AlsPDFspeichern()

Dim pdfName As String

With ActiveSheet

pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & _
.Range("C11") & "_" & .Range("A25") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

End With

If pdfName = "Falsch" Then Exit Sub

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Leider habe ich jetzt noch ein Problem und hoffe hier Hilfe zu finden. *wink.gif*

Der Dateiname besteht aus 2 Werten (2 Zellen).
1.) "C11" (Vorname und Nachname)
2.) "A25" (Monatsname...Format "MMMM")

Der Monatsname wird immer aktualisiert und ergibt sich aus ein Datum in einer anderen Zelle. Das Problem was ich jetzt habe ist, dass er mir beim Speichern nicht das Format ausgibt, (bsp. November) sondern das komplette Datum (04.11.2014). So steht es nämlich in der anderen Zelle.
Gibt es eine Möglichkeit, dass er im .Range("A25") nicht den Wert ausliest, sondern das Format?

Derzeitiger Speichername: Max Mustermann_04.11.2014
Soll Speichername: Max Mustermann_November

Ich würde mich über jede Hilfe und Tipp´s freuen!
Bis dahin noch einen angenehmen Tag... *Smilie

MfG
Burleypacker

:)

RPP63 · 4. Dezember 2014

Hallo!
Du musst das Datum in einen String mit Deinem gewünschten Format umwandeln.
Ungetestet:
Code:

pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & _
.Range("C11") & "_" & Format(.Range("A25"), "MMMM") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, Ralf

Burleypacker · 4. Dezember 2014

Hallo Ralf!

Danke für die schnelle und unkomplizierte Lösung! Hat wunderbar geklappt und ist sehr simpel und logisch! *wink.gif*

Vielleicht gibt es noch etwas wobei Ihr mir helfen könnt.

Derzeit speichere ich die Dateien in 1 Ordner...bleiben wir hier einfach bei \Desktop\

Besteht die Möglichkeit, nach einem Ordner suchen zu lassen, der genau den selben Namen hat, wie ein Wert einer bestimmten Zelle ("C11")(Vorname Nachname)

Mein Ziel ist es, wenn ich in "C11" Max Mustermann auswähle, soll er die PDF Datei unter \Desktop\Max Mustermann\.......pdf speichern.
Ist das in meinem Code einfach einfügbar?

Code:

Sub PDFAbrechnung()

Dim pdfName As String

With ActiveSheet

pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & _
.Range("C11") & "_" & Format(.Range("A24"), "MMMM") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

End With

If pdfName = "Falsch" Then Exit Sub

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False

ActiveWindow.ScrollWorkbookTabs Position:=xlFirst
Sheets("SAP").Select
Range("C11").Select

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Über erneute Hilfe würde ich mich sehr freuen! *biggrin.gif*

MfG
Burleypacker

RPP63 · 4. Dezember 2014

Hi!
Ich sach mal Toyota (nichts ist unmööööglich) ...
Zunächst mal musst Du mittels Dir() prüfen, ob der Ordner bereits existiert.
Falls nicht, muss ihn VBA mittels MkDir erstellen.
Als Beispiel (jetzt getestet):
Code:

Sub SpeichernAlsPDF()
Dim SuchPfad As String, ZielOrdner As String, pdfName As String
With ActiveSheet
SuchPfad = Environ("USERPROFILE") & "\Desktop\" & .Range("C11")
ZielOrdner = .Range("C11")
If Not Dir(SuchPfad, vbDirectory) = ZielOrdner Then
MkDir SuchPfad
End If
pdfName = Application.GetSaveAsFilename(SuchPfad & "\" & _
Format(.Range("A25"), "MMMM") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")
If pdfName = "Falsch" Then Exit Sub
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, Ralf

Burleypacker · 4. Dezember 2014

Hallo Ralf,

so, ich habe mir den Code jetzt übernommen und mal in Ruhe angesehen.
Erstens...DANKE sehr für deine großartige Hilfe!!! *happy Das klappt zu 100% und ist ganz genau das, was ich wollte.
Super auch, daß du mir den Code schon so angepasst hast, daß er die PDF Datei auch nur mit dem Monat speichert.

Zweitens...Ich habe den Code verstanden und werde ihn weiterhin in anderen Tabellen verwenden!

Somit wäre dieser Thread fertig und ich danke für die schnelle und konstruktive Hilfe!!!

MfG
Burleypacker

Burleypacker · 4. Dezember 2014

Hallo nochmal,

jetzt muss ich doch nochmal was fragen...geht diese Zielordnersuche und Erstellung auch für 2 Ordner (1 Unterordner und 1 Zielordner)

Code:

SuchPfad = Environ("USERPROFILE") & "\Desktop\" & .Range("C11") & .Range("A1")
ZielOrdner = .Range("C11") & .Range("A1")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

\Desktop\Max Mustermann\2014\.....pdf

Oder werden Unterordner noch anders deklariert?

Kann es leider gerade nicht prüfen...

mfG
Burleypacker

RPP63 · 4. Dezember 2014

Hi!
Dies:

Kann es leider gerade nicht prüfen...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

hat Dich gerade nochmal gerettet ...*cool.gif*
Ich werde Dir jetzt mal keine Lösung schreiben, sondern Dich auf den richtigen Weg führen *eek.gif*
Dies:
Code:

SuchPfad = Environ("USERPROFILE") & "\Desktop\" & .Range("C11") & .Range("A1")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

führt zum Suchpfad:
Code:

\Desktop\Max Mustermann2014
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

dito: ZielOrdner = .Range("C11") & .Range("A1")
Du möchtest aber:
Code:

\Desktop\Max Mustermann\2014
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Na, klingelt es?*Smilie
(Nur als Tipp am Rande: Du musst Dich durch die evtl. nicht vorhandenen Verzeichnisebenen hangeln)

Gruß, Ralf

RPP63 · 4. Dezember 2014

Und dem Spielkind in mir geschuldet, hier mal "unsichtbarer" Code (ich sach nur #FAF6F6, der aber dennoch markiert werden kann):
Code:

Sub SpeichernAlsPDF()
Dim SuchPfad As String, ZielOrdner As String, pdfName As String
With ActiveSheet
SuchPfad = Environ("USERPROFILE") & "\Desktop\" & .Range("C11")
ZielOrdner = .Range("C11")
If Not Dir(SuchPfad, vbDirectory) = ZielOrdner Then
MkDir SuchPfad
End If
SuchPfad = SuchPfad & "\" & .Range("A1")
ZielOrdner = ZielOrdner & "\" & .Range("A1")
If Not Dir(SuchPfad, vbDirectory) = ZielOrdner Then
MkDir SuchPfad
End If
pdfName = Application.GetSaveAsFilename(SuchPfad & "\" & _
Format(.Range("A25"), "MMMM") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")
If pdfName = "Falsch" Then Exit Sub
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, Ralf

Superingo2 · 4. Dezember 2014

Hallo Ralf,

das nenne ich mal professionelle Hilfe mit Witz.
*grins *grins *grins
*yelrotflmao *yelrotflmao *yelrotflmao
*boah *boah *boah
*lachen *lachen *lachen
*hands *hands *hands *hands
*biggrin.gif* *biggrin.gif* *biggrin.gif* *biggrin.gif*
Ich kann mich kaum halten vor lachen.
Danke für die Rettung diese Tages!

Aller beste Grüße
Ingo

RPP63 · 4. Dezember 2014

Hi Ingo!
Da sage ich doch herzlichen Dank für Dein (verstecktes) Lob! *Smilie

Gruß und einen schönen Tag,
Ralf

Burleypacker · 4. Dezember 2014

Hi Ralf,

Wiedermal einen großen Dank für deine Hilfe. Also muss ich jeden weiteren Ordner oder Unterordner in einem extra SuchPfad deklarieren. *stupid

Und ich habe erstmal nur das "\" zwischen die & .Range("...") Funktion gesetzt...hat natürlich nicht geklappt... *tongue.gif*

Jetzt klappt alles super und ich muss nicht weiter an diesem Speichern-Projekt rumbasteln! *five

Vielen Dank und mfG *hands
Burleypacker

Burleypacker · 5. Dezember 2014

Jetzt komm ich mir langsam echt mies vor... *frown.gif*

Jetzt habe ich den richtigen Speicherort angeben können und wollte den zu erstellenden Ordner auch in ein Format setzen, da dieser auch aus einer Zelle mit einem Datum entstehen soll. Nur soll diesmal nur das Jahr angezeigt und als Format übernommen werden. Ich beziehe den Wert aus der selben Zelle, die auch die PDF-Datei benennen soll.

Hier der überarbeitete Code...

Code:

Sub PDFAbrechnung()

Dim SuchPfad As String, ZielOrdner As String, pdfName As String

With ActiveSheet

SuchPfad = Environ("Z:") & "\Documents\SAP-Kurier-Transport\Abrechnungen\" & .Range("C11")
ZielOrdner = .Range("C11")

If Not Dir(SuchPfad, vbDirectory) = ZielOrdner Then
MkDir SuchPfad
End If

SuchPfad = SuchPfad & "\" & Format(.Range("A24"), "JJJJ")
ZielOrdner = ZielOrdner & "\" & Format(.Range("A24"), "JJJJ")
If Not Dir(SuchPfad, vbDirectory) = ZielOrdner Then
MkDir SuchPfad
End If

pdfName = Application.GetSaveAsFilename(SuchPfad & "\" & _
Format(.Range("A24"), "MMMM") & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

If pdfName = "Falsch" Then Exit Sub

.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False

End With

ActiveWindow.ScrollWorkbookTabs Position:=xlFirst
Sheets("SAP").Select
Range("C11").Select

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Leider übernimmt er das Format nicht, sondern setzt mir das "JJJJ" als Ordnername. Kann man hier kein Format verwenden oder hab ich wieder was falsch gemacht? *stupid

Z:\Documents\SAP-Kurier-Transport\Abrechnungen\Max Mustermann\JJJJ\...pdf

Ich brauche mal wieder Eure Hilfe... *am verzweifeln* *sos

MfG
Burleypacker

Burleypacker · 10. Dezember 2014

*sos Kann hier vielleicht noch jemand helfen? *sos

chris-kaiser · 11. Dezember 2014

Hi,

statt JJJJ
würde ich YYYY einsetzen.

Burleypacker · 15. Dezember 2014

*stupid Englisch...so hat es natürlich geklappt...

Office: Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern

Datumsformat und nicht den Datumswert als Dateiname speichern - Similar Threads - Datumsformat Datumswert Dateiname

Datumsformat

Leider falsches Datumsformat - sortieren möglich?

Erbitte komplizierte Formel Wenn,dann oder wenn dies, dann

Access Datumsformat

Datumsformat in Englisch

[Excel 2016] Diagramm: Skalierung y-Achse Monatsanfang und Datumsformat

Standardformat umwandeln von z.B. 2/20/2018 in Datumsformat 20.02.218