Office: (Office 365) Datumswerte auflisten

Hi
Ich suche eine Spillformel die mir die Datumswerte von-bis auflistet.
Beispieldatei mit Wunschergebnis anbei.
VG Charly

 

Moin,

das Datum für die nächsten 31 Tage untereinander aufgelistet:
=TEXT(SEQUENZ(31;1;HEUTE();1);"TT.MM.JJJJ")

Oder nicht als Text, dafür die Zellen danach als Datum formatiert:
SEQUENZ(31;1;HEUTE();1)

oder, die nächsten 12 Wochen ab heute, wochenweise (pro Woche eine Zeile):
=TEXT(SEQUENZ(12;7;HEUTE();1);"TT.MM.JJJJ")

 

Moin!
Ich taste mich mal heran:
In F2: =SEQUENZ(1;B2-A2+1;A2)
herunterziehen …
In D2: =ZUSPALTE(F:.XFD;1)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J
1	von	bis		Wunsch
2	02.01.2025	05.01.2025		02.01.2025		45659	45660	45661	45662
3	03.02.2025	03.02.2025		03.01.2025		45691
4	09.04.2025	11.04.2025		04.01.2025		45756	45757	45758
5				05.01.2025
6				03.02.2025
7				09.04.2025
8				10.04.2025
9				11.04.2025
10

Zelle	Formel
D2	=ZUSPALTE(F:.XFD;1)
F2	=SEQUENZ(1;B2-A2+1;A2)
F3	=SEQUENZ(1;B3-A3+1;A3)
F4	=SEQUENZ(1;B4-A4+1;A4)

Man müsste mal schauen, ob es auch ohne die Hilfsspalten geht.

Frohe Weinacht!
Ralf

 

Hallo Charly,
in Wunschzelle:

Code:

=LET(xA; A2:B4;xB; INDEX(xA;;1); xC; INDEX(xA;;2);xD; MIN(xB); xE; MAX(xC); xF; SEQUENZ(xE - xD + 1; 1; xD; 1);xG;MMULT( --(xF>=MTRANS(xB)) *--(xF<=MTRANS(xC)); SEQUENZ(ZEILEN(xB)));xZ;FILTER(xF; xG>0);EINDEUTIG(VSTAPELN(xZ);WAHR;WAHR))

oder benutzerdefinierte Formel:
in Namensmanager:
Name:Zeiträume
Formel:

Code:

=LAMBDA(DatumsBereiche;LET(xB;INDEX(DatumsBereiche;;1);xC;INDEX(DatumsBereiche;;2);xD;MIN(xB);xE;MAX(xC);xF;SEQUENZ(xE - xD + 1; 1; xD; 1);xG;MMULT( --(xF>=MTRANS(xB)) *--(xF<=MTRANS(xC)); SEQUENZ(ZEILEN(xB)));xZ;FILTER(xF; xG>0);EINDEUTIG(VSTAPELN(xZ);WAHR;WAHR)))

Aufruf in Zelle: =Zeiträume(A2:B4)

Gruß Uwe

 

Zur Ergänzung:
Man kann xA oder DatumsBereiche mit Filter <>"" einlesen oder du machst ein Listobjekt daraus. Dann braucht man da nicht mehr dran rum zu schrauben. Das solltest du eigentlich selbst entscheiden.
Ich kann nur mit den Möglichkeiten von O2024 so was bauen. Deshalb ist es nur eine von diversen Lösungsmöglichkeiten dies dynamisch zu halten. In O365 gibt es einige Funktionen, wo dies effizienter und kompakter zu bauen geht.

 

Ich hab dann auch mal gebastelt …
(war durchaus etwas tricky)

Code:

=LET(
    ZR; SEQUENZ(MAX(B:B) - MIN(A:A) + 1; ; MIN(A:A));
    f; NACHZEILE(ZR; LAMBDA(x; SUMMENPRODUKT((x >= A:.A) * (x <= B:.B))));
    FILTER(ZR; f)
)

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D
1	von	bis
2	02.01.2025	05.01.2025		02.01.2025
3	03.02.2025	03.02.2025		03.01.2025
4	09.04.2025	11.04.2025		04.01.2025
5				05.01.2025
6				03.02.2025
7				09.04.2025
8				10.04.2025
9				11.04.2025

Zelle	Formel
D2	=LET(ZR;SEQUENZ(MAX(B:B)-MIN(A:A)+1;;MIN(A:A)); f;NACHZEILE(ZR;LAMBDA(x;SUMMENPRODUKT((x>=A:.A)*(x<=B:.B)))); FILTER(ZR;f))

 

Ich hab jetzt gerade gesehen, dass ich vergessen hatte VSTAPELN() rauszunehmen. Bei der Anfrage kann man auch auf EINDEUTIG() verzichten, da keine Überschneidungen enthalten sind. In diesem Zusammenhang hatte ich mir schon vor einiger Zeit mal zu diesem Thema deutlich aufwändiger diese LET zusammengebaut.

Gruß Uwe

 

Ich danke allen die sich mit meiner Frage beschäftigt haben.
Die letzte Formel von Ralf ist perfekt und einfach verstehen.
Vielen Dank und frohe Weihnachten allen.

Leider hab ich keine Ahnung, wie man ein "gefällt mir" vergibt.

 

Hi,

hab da letzthin auch mal was gebastelt, ohne Nachzeile/Lambda:

 

Hi Edgar
Klasse
Vielen Dank
VG Charly

 

Sehr schön!
Durch den SVERWEIS(…;2;1) müssen die Zeiträume aber zwingend aufsteigend sortiert sein.
Gut, dies sollte ohnehin üblich sein, aber ich wollte nur mal kurz den mahnenden Finger zeigen.

Gruß Ralf

 

Hallo Ralf,

hast mal wieder recht. Dann so:

Code:

=LET(xa;SORTIEREN(B:.C);xb;SEQUENZ(MAX(xa)-MIN(xa)+1;;MIN(xa));FILTER(xb;xb<=SVERWEIS(xb;xa;2;1)))

 

Isch gebe auch noch 'nen Dreier dazu:
meine UDF etwas kompakter:

Code:

=LAMBDA(DatumsBereiche;LET(xA;INDEX(DatumsBereiche;;1);xB;INDEX(DatumsBereiche;;2);xC;SEQUENZ(MAX(xB)-MIN(xA)+1;1;MIN(xA));FILTER(xC;MMULT(--(xC>=MTRANS(xA))*--(xC<=MTRANS(xB));SEQUENZ(ZEILEN(xA)))>0)))

Ob die effizienter ist keine Ahnung. Das ist eben mit den Möglichkeiten von O2024 nur so möglich. Ralf seine heb ich mir auf, falls ich doch noch auf die Idee komme mir O365 zuzulegen.

Gruß Uwe