Office: DBMITTELWERT-Funktion

DBMITTELWERT-Funktion
Excel für Microsoft 365 Excel für Microsoft 365 für Mac Excel für das Web Excel 2019 Excel 2016 Excel 2019 für Mac Excel 2013 Excel 2010 Excel 2007 Excel 2016 für Mac Excel für Mac 2011 Excel Starter 2010 Mehr... Weniger In diesem Artikel werden die Formelsyntax und die Verwendung der Funktion DBMITTELWERT in Microsoft Excel beschrieben.

Beschreibung
Liefert den Mittelwert aus den Werten eines Felds (einer Spalte) mit Datensätzen in einer Liste oder Datenbank, die den von Ihnen angegebenen Bedingungen entsprechen.

Syntax
DBMITTELWERT(Datenbank;Datenbankfeld;Suchkriterien)

Die Syntax der Funktion DBMITTELWERT weist die folgenden Argumente auf:

• Datenbank     ist der Zellbereich, aus dem die Liste oder Datenbank besteht. Eine Datenbank ist eine Liste verwandter Daten, in der Zeilen mit verwandten Informationen Datensätze und Datenspalten Felder bilden. Die erste Zeile der Liste enthält Beschriftungen für die einzelnen Spalten.
  
  
• Datenbankfeld     gibt an, welche Spalte in der Funktion verwendet wird. Geben Sie die Spaltenbeschriftung zwischen Anführungszeichen ein, z. B. als "Alter" oder "Ertrag", oder eine Zahl, die die Position der Spalte in der Liste darstellt: 1 für die erste Spalte, 2 für die zweite Spalte usw.
  
  
• Suchkriterien     ist der Zellbereich, der die angegebenen Bedingungen enthält. Sie können jeden Bereich verwenden, der mindestens eine Spaltenbeschriftung und eine Zelle unter der Beschriftung zum Angeben der Bedingung enthält.
  
  

Hinweise

• Für das Argument Suchkriterien können Sie jeden Bereich verwenden, der mindestens eine Spaltenbeschriftung und eine Zelle unter der Beschriftung zum Angeben der Bedingung enthält.
  
  Enthält beispielsweise der Bereich G1:G2 in G1 die Spaltenbeschriftung "Einkommen" und in G2 den Betrag 10.000, können Sie diesem Bereich den Namen "GesuchtesEinkommen" zuweisen und diesen Namen innerhalb einer Datenbankfunktion als Argument Suchkriterien verwenden.
  
  
• Obwohl der Kriterienbereich überall im Arbeitsblatt ermittelt werden kann, sollten Sie ihn unter der Liste platzieren. Wenn Sie der Liste weitere Informationen hinzufügen, werden die neuen Informationen der ersten Zeile unter der Liste hinzugefügt. Wenn die Zeile unter der Liste nicht leer ist, können die neuen Informationen nicht von Excel hinzugefügt werden.
  
  
• Stellen Sie sicher, dass der Kriterienbereich die Liste nicht überlappt.
  
  
• Wenn ein Vorgang über eine komplette Spalte in einer Datenbank ausgeführt werden soll, fügen Sie im Kriterienbereich unter den Spaltenbeschriftungen eine Leerzeile ein.
  
  

Beispiele
Kopieren Sie die Beispieldaten in der folgenden Tabelle, und fügen Sie sie in Zelle A1 eines neuen Excel-Arbeitsblatts ein. Um die Ergebnisse der Formeln anzuzeigen, markieren Sie sie, drücken Sie F2 und dann die EINGABETASTE. Im Bedarfsfall können Sie die Breite der Spalten anpassen, damit alle Daten angezeigt werden.

Baum	Höhe	Alter	Ertrag	Gewinn	Höhe
=Apfel	>3				<5
=Birne
Baum	Höhe	Alter	Ertrag	Gewinn
Apfel	5,5	20	14	105
Birne	3,5	12	10	96
Kirsche	4	14	9	105
Apfel	4,5	15	10	75
Birne	2,75	8	8	76,8
Apfel	2,5	9	6	45
Formel	Beschreibung	Ergebnis
=DBMITTELWERT(A4:E10;"Ertrag";A1:B2)	Der Mittelwert der Erträge von Apfelbäumen mit einer Höhe von über 3 m.	12
=DBMITTELWERT(A4:E10;3;A4:E10)	Der Mittelwert des Alters aller Bäume in der Datenbank.	13

Beispiele für Kriterien

• Wenn Sie ein Gleichheitszeichen in eine Zelle eingeben, kennzeichnen Sie, dass Sie eine Formel eingeben möchten. Wenn Sie Text anzeigen möchten, der ein Gleichheitszeichen enthält, setzen Sie den Text und das Gleichheitszeichen in Anführungszeichen (wie im folgenden Beispiel):
  
  "=Davolio"
  
  Auf gleiche Weise verwenden Sie Anführungszeichen, wenn Sie einen Ausdruck (eine Kombination aus Formeln, Operatoren und Text) eingeben und möchten, dass das Gleichheitszeichen von Excel angezeigt wird, statt in einer Berechnung verwendet zu werden. Beispiel:
  
  =''= Eingabe ''
  
  Wobei Eingabe der Text oder Wert ist, den Sie suchen möchten. Beispiel:
  
  

Ihre Eingabe in die Zelle	Auswertung und Anzeige in Excel
="=Davolio"	=Davolio
="=3000"	=3000

• Beim Filtern von Textdaten unterscheidet Microsoft Excel nicht zwischen Groß- und Kleinschreibung. Sie können jedoch für eine Suche, bei der Groß- und Kleinschreibung berücksichtigt wird, eine Formel verwenden. Sie finden ein Beispiel weiter unten in diesem Artikel unter Filtern nach Text unter Berücksichtigung der Groß-/Kleinschreibung.
  
  

Die folgenden Abschnitte enthalten Beispiele für komplexe Kriterien.

Mehrere Kriterien in einer Spalte
Boolesche Logik:     (Verkäufer = "Davolio" ODER Verkäufer = "Buchanan")

Geben Sie die Kriterien untereinander in separate Zeilen ein, um Zeilen zu finden, die mehreren Kriterien für eine Spalte entsprechen.

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (B1:B3) alle Zeilen an, bei denen die Spalte "Verkäufer" (A8:C10) Zeilen mit dem Eintrag "Davolio" oder "Buchanan" enthält.

	A	B	C
1	Typ	Verkäufer	Umsatz
2		=Davolio
3		=Buchanan
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Mehrere Kriterien in mehreren Spalten, wobei alle Kriterien als "Wahr" ausgewertet werden
Boolesche Logik:     (Typ = "Naturprodukte" UND Umsatz > 1000)

Geben Sie alle Kriterien in derselben Zeile des Kriterienbereichs ein, um Zeilen zu finden, die mehreren Kriterien in mehreren Spalten entsprechen.

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (A1:C2) alle Zeilen an, bei denen die Spalte "Typ" den Eintrag "Naturprodukte" und die Spalte "Umsatz" (A9:C10) einen Wert größer als 1000 € enthält.

	A	B	C
1	Typ	Verkäufer	Umsatz
2	=Naturprodukte		>1000
3
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Mehrere Kriterien in mehreren Spalten, wobei beliebige Kriterien als "Wahr" ausgewertet werden können
Boolesche Logik:     (Typ = "Naturprodukte" ODER Verkäufer = "Davolio")

Geben Sie die Kriterien in verschiedene Zeilen des Kriterienbereichs ein, um Zeilen zu finden, die mehreren Kriterien in mehreren Spalten entsprechen, bei denen ein beliebiges Kriterium als "Wahr" ausgewertet wird.

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (A1:B3) alle Zeilen an, bei denen die Spalte "Typ" den Eintrag "Naturprodukte" oder die Spalte "Verkäufer" (A8:C10) den Eintrag "Davolio" enthält.

	A	B	C
1	Typ	Verkäufer	Umsatz
2	=Naturprodukte
3		=Davolio
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Mehrere Kriteriengruppen, wobei jede Gruppe Kriterien für mehrere Spalten enthält
Boolesche Logik:     ( (Verkäufer = "Davolio" UND Umsatz > 3000) ODER (Verkäufer = "Buchanan" UND Umsatz > 1500) )

Geben Sie jede Kriteriengruppe in separaten Zeilen ein, um Zeilen zu finden, die mehreren Kriteriengruppen entsprechen.

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (B1:C3) Zeilen an, bei denen die Spalte "Verkäufer" (A9:C10) den Eintrag "Davolio" enthält und der Umsatz mehr als 3.000 € beträgt. Außerdem werden die Zeilen angezeigt, die in der Spalte "Verkäufer" den Eintrag "Buchanan" enthalten und deren Umsatz mehr als 1.500 € beträgt.

	A	B	C
1	Typ	Verkäufer	Umsatz
2		=Davolio	>3000
3		=Buchanan	>1500
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Mehrere Kriteriengruppen, wobei jede Gruppe Kriterien für eine Spalte enthält
Boolesche Logik:     ( (Umsatz > 6000 UND Umsatz < 6500 ) ODER (Umsatz < 500) )

Geben Sie mehrere Spalten mit der gleichen Spaltenüberschrift an, um Zeilen zu finden, die mehreren Kriteriengruppen entsprechen, wobei jede Gruppe Kriterien für eine Spalte enthält.

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (C1:D3) alle Zeilen an, bei denen die Spalte Umsatz (A8:C10) Werte zwischen 6.000 und 6.500 und Werte kleiner als 500 enthält.

	A	B	C	D
1	Typ	Verkäufer	Umsatz	Umsatz
2			>6000	<6500
3			<500
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Kriterien für die Suche nach Textwerten, bei denen nur einige Zeichen übereinstimmen
Führen Sie einen oder mehrere der folgenden Schritte aus, um Textwerte zu suchen, bei denen nur einige Zeichen übereinstimmen:

• Geben Sie ein oder mehrere Zeichen ohne ein Gleichheitszeichen (=) ein, um in einer Spalte Zeilen mit einem Textwert zu finden, der mit diesen Zeichen beginnt. Wenn Sie z. B. den Text "Dav" als Kriterium eingeben, findet Microsoft Excel "Davolio," "David" und "Davis".
  
  
• Verwenden Sie ein Platzhalterzeichen.
  
  Die folgenden Platzhalterzeichen können als Vergleichskriterien verwendet werden.
  
  

Bedeutung	Gefundene Zeichen
? (Fragezeichen)	Ein beliebiges einzelnes Zeichen Die Eingabe "Schmi?d" gibt z. B. "Schmied" und "Schmild" zurück
* (Sternchen)	Eine beliebige Anzahl von Zeichen Die Eingabe "*ost" gibt z. B. "Nordost" und "Südost" zurück
~ (Tilde), gefolgt von ?, * oder ~	Fragezeichen, Sternchen oder Tilde Beispiel: gj91~? findet "gj91?"

Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (A1:B3) Zeilen an, bei denen der Eintrag in der Spalte "Typ" als Anfangszeichen "Fl" und der Eintrag in der Spalte "Verkäufer" (A7:C9) als zweites Zeichen "u" enthält.

	A	B	C
1	Typ	Verkäufer	Umsatz
2	Ich
3		=?u*
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Kriterien, die als Ergebnis einer Formel erstellt werden
Sie können auch einen berechneten Wert, der von einer Formel als Ergebnis zurückgegeben wird, als Suchkriterium verwenden. Es ist wichtig, dass Sie Folgendes berücksichtigen:

• Die Formel muss als WAHR oder FALSCH ausgewertet werden.
  
  
• Da Sie eine Formel verwenden, geben Sie diese wie üblich ein. Geben Sie den Ausdruck nicht wie folgt ein:
  
  =''= Eingabe ''
  
  
• Sie dürfen als Kriterienbeschriftung keine Spaltenbeschriftung verwenden. Geben Sie entweder keinen Wert für die Kriterienbeschriftung ein, oder verwenden Sie eine Beschriftung, die nicht mit einer Spaltenbeschriftung in dem Bereich übereinstimmt ("Berechneter Mittelwert" und "Genaue Übereinstimmung" in den folgenden Beispielen).
  
  Wenn Sie eine Spaltenbeschriftung in der Formel anstelle eines relativen Zellbezugs oder eines Bereichsnamens verwenden, zeigt Excel einen Fehlerwert wie #Name an? oder #WERT! in der Zelle, die das Kriterium enthält. Sie können diesen Fehler ignorieren, da er keine Auswirkungen auf die Filterung des Bereichs hat.
  
  
• Die Formel, die Sie für das Kriterium verwenden, muss für den Verweis auf die entsprechende Zelle in der ersten Zeile einen Relativer Bezug verwenden (C7 und A7 in den folgenden Beispielen).
  
  
• Alle anderen Bezüge in der Formel müssen absolute Bezüge sein.
  
  

Die folgenden Unterabschnitte zeigen bestimmte Beispiele für Kriterien, die als das Ergebnis einer Formel definiert werden.

Filtern nach Werten, die über dem Mittelwert aller Werte in dem Datenbereich liegen
Im folgenden Datenbereich (A6:C10) zeigt der Kriterienbereich (D1:D2) Zeilen an, bei denen die Spalte "Umsatz" (A8:C10) einen Wert enthält, der größer ist als der Mittelwert aller Umsatzwerte (C7:C10). In der Formel bezieht sich "C7" auf die gefilterte Spalte (C) der ersten Zeile des Datumsbereichs (7).

	A	B	C	D
1	Typ	Verkäufer	Umsatz	Berechneter Mittelwert
2				=C7>MITTELWERT($C:$C)
3
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

Filtern nach Text unter Berücksichtigung der Groß-/Kleinschreibung
Im Datenbereich (A6: D10) zeigt der Kriterienbereich (D1: D2) Zeilen an, die in der Spalte Typ den Wert "Produce" enthalten, indem Sie die exakte Funktion verwenden, um eine Suche mit Groß-/Kleinschreibung durchzuführen (A10: C10). In der Formel bezieht sich "a7" auf die gefilterte Spalte (A) der ersten Zeile des Datenbereichs (7).

	A	B	C	D
1	Typ	Verkäufer	Umsatz	Genaue Übereinstimmung
2				=IDENTISCH(A7;"Naturprodukte")
3
4
5
6	Typ	Verkäufer	Umsatz
7	Getränke	Suyama	5122 €
8	Fleischwaren	Davolio	450 €
9	Naturprodukte	Buchanan	6328 €
10	Naturprodukte	Davolio	6544 €

:)