Office: d'Hondt'sche Aufteilung

Benenne folgende Funktion mit DHONDT ...

=LAMBDA(x;y;LET(b;(y+SEQUENZ(ZEILEN(y))%-1%%)/SEQUENZ(;x);NACHZEILE(KGRÖSSTE(b;x)<=b;LAMBDA(a;SUMME(--a)))))

... und verwende B2#: =DHONDT(A1;A2:A4) für
A1: 5
A2:A4: 120;50;40
--> B2#: 3;1;1 als Aufteilung von A1: 5

Achtung: Die Aufteilung hängt im Grenzfalle von der Anordnung der Werte in A2:A4 ab! Aufsteigend sortiert bedeutet z.B.: Größere Anteile werden bevorzugt, u.u.
_____________________________________________________________________
Hier noch ein anderes Verfahren:

Benenne folgende Funktion mit HARE.NIEMEYER.HQ1 ...

=LAMBDA(Gesamtsitze;Einzelstimmen;LET(e;Einzelstimmen;g;Gesamtsitze;
s;e/SUMME(e)*g;
t;KÜRZEN(s);
u;REST(s;1)+SEQUENZ(ZEILEN(e))%%%;
v;KGRÖSSTE(u;SEQUENZ(g-SUMME(t)));
w;XVERWEIS(u;v;v;0;0;-2)=u;
t+w))

... und verwende B2#: =HARE.NIEMEYER.HQ1(A1;A2:A4) für
A1: 5
A2:A4: 120;50;40
--> B2#: 3;1;1 als Aufteilung von A1: 5

Wikipedia: ...HQ1 wird in Italien verwendet, ...HQ2 in Litauen und ...HQ3 in der Schweiz. Ich beschränke mich hier auf ...HQ1.

Bei z.B. A1: 202 ergeben sich verschiedene Sitzverteilungen zwischen D'Hondt und Hare.

Hier ein Rechnungsbeispiel B2:D6: (4 Pos.: netto/MwSt19/brutto, einzeln und als Summe)
100,10 19,02 119,12
100,10 19,02 119,12
100,20 19,04 119,24
100,20 19,04 119,24
400,60 76,11 476,71
wo MwSt19 und Brutto für die Summenzeile von der Nettosumme aus errechnet werden. Man sieht, dass dann die roten Spaltensummen falsch sind.

Wird nun C2:C5 durch C2#: =HARE.NIEMEYER.HQ1(C6/1%;B2:B5/1%)% oder =DHONDT(C6/1%;B2:B5/1%)% ersetzt, ergibt sich:
100,10 19,02 119,12
100,10 19,02 119,12
100,20 19,03 119,23
100,20 19,04 119,24
400,60 76,11 476,71
Ein MwSt-Cent wird also abgezogen, damit die Summenzeile mit der Summe der Einzelzeilen übereinstimmt. Hinweis: Die Funktion transformiert von €-Cent-Beträgen in Ganzzahlen und zurück.