Office: Diagramm: benutzerdefinierter Fehlerindikator über Makro

Hallo,

ich generiere ein Balkendiagramm über ein Makro, möchte aber gleichzeitig für das Diagramm benutzerdefinierte Fehlerindikatoren zuweisen.
Also neben der Spalte mit den eigentlichen Werten gibt es eine mit den jeweiligen Fehlern. Diese Spalte soll als Wertebereich für "benutzerdefinierte Fehlerindikatoren" im Diagramm verwendet werden.

Per Aufzeichnen und manuell zuweisen wird kein entsprechender Code im Makro hinterlegt, so komme ich also nicht zum Ziel.
Wie kann man sowas per Makro realisieren?

 

Hi,

versuche es mal nach diesem Prinzip:

Code:

    With ActiveSheet.ChartObjects(1).Chart
        .SeriesCollection(1).ErrorBar Direction:=xlY, Include:= _
            xlPlusValues, Type:=xlCustom, Amount:=Range("C1:C7")
    End With

Bis später,
Karin

 

Vielen Dank, das funktioniert soweit. Und wenn ich die selben Werte auch noch mal in negativer Richtung darstellen möchte?

 

Hi,

Code:

    With ActiveSheet.ChartObjects(1).Chart
        .SeriesCollection(1).ErrorBar Direction:=xlY, Include:=xlBoth, _
            Type:=xlCustom, Amount:="=" & ActiveSheet.Name & "!R1C2:R7C2", _
            MinusValues:="=" & ActiveSheet.Name & "!R1C2:R7C2"
    End With

Bis später,
Karin

 

Danke für die Antworten, Karin!

Den letzten Code durchschaue ich jetzt noch nicht ganz, daher habe ich Probleme diesen auf variable Zellbezüge umzuformulieren.

Also statt "!R1C2:R7:C" in etwa "Range(Cells(4, 7), Cells(eende, 7))".
Einfach ersetzen, mit und ohne Anführungsstriche / Ausrufezeichen funktioniert hier nicht.

 

Hi,

R = Row und C = Column. Folglich nach diesem Prinzip:

Code:

"!R4C7:R" & intEndzeile & "C7"

Ich habe es jetzt noch mal in Excel2007 getestet - dort ist es möglich, die Bereichszuweisung direkt zu machen, in den Vorgängerversionen leider nicht - dort muss bei Anzeige sowohl der positiven als auch der negativen Abweichungen die R1C1-Schreibweise verwendet werden.

In Excel2007 würde der Cdoe so aussehen:

Code:

    With ActiveSheet.ChartObjects(1).Chart
        .SeriesCollection(1).ErrorBar Direction:=xlY, Include:=xlBoth, _
            Type:=xlCustom, Amount:=Range(Cells(4, 7), Cells(intEndzeile, 7)), _
            MinusValues:=Range(Cells(4, 7), Cells(intEndzeile, 7))
    End With

Bis später,
Karin

 

Wunderbar, vielen lieben Dank!
Jetzt tut es genau was es soll.

Liebe Grüße
Holger