Office: Diagramm bereich festlegen

Frozen_Heaven · 8. Februar 2015

Hallo Zusammen,

ich benötige wieder einmal eure Hilfe:

Ich möchte aus einem Tabellenblatt ein Diagramm erzeugen. Der Diagramm Bereich sollte variabel sein, da sich die Anzahl der Zeilen und auch der Spalten ändert.

ich habe folgenden Code geschrieben:
Code:

Sub Generate_Graph()

'******************Variablen deklarieren*******************
Dim i As Integer
Dim k As Integer

'********************Bereich festlegen*********************
i = Worksheets("Auswertung").Range("A9").End(xlDown).Row
k = Worksheets("Auswertung").Cells(8, Columns.Count).End(xlToLeft).Column

MsgBox "Zeile: " & i & " Spalte: " & k

'********************Grafik generieren*********************
ThisWorkbook.Charts.Add After:=Worksheets("Auswertung")

With ActiveChart
.ChartType = xlXYScatterLinesNoMarkers
.Name = "Graph_MOL_PRL"
.PlotArea.Interior.Color = RGB(218, 218, 218)
.SetSourceData Worksheets("Auswertung").Range(Cells(8, 1), Cells(i, k))
.HasTitle = True
.ChartTitle.Text = "XXX"
.HasLegend = True
.Legend.Position = xlBottom
.Axes(xlValue).HasTitle = True
.Axes(xlValue).AxisTitle.Text = "Leistung"
.Axes(xlValue).TickLabels.NumberFormatLocal = "#.##0,00"
.Axes(xlCategory).TickLabels.Orientation = xlUpward
.Axes(xlCategory).HasTitle = True
.Axes(xlCategory).AxisTitle.Text = "ZEIT"

End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich bekomme immer folgende Fehlermeldung:
Laufzeitfehler 1004: Die Methode Cells für das Objekt _Global ist fehlgeschlagen.

Woran kann das liegen?

:)

xlph · 10. Februar 2015

Hallo,
Code:

.SetSourceData Worksheets("Auswertung").Range(Worksheets("Auswertung").Cells(8, 1), Worksheets("Auswertung").Cells(i, k))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...ergänzen.

Frozen_Heaven · 10. Februar 2015

Vielen Dank!

Beverly · 10. Februar 2015

Hi,

da du das Diagrammblatt schon erstellt hast, ist der Bezug zum Ausgangstabellenbltt nicht mehr vorhanden - deshalb der Fehler. Wenn du das Diagramm zuerst im Tabellenblatt erstellst und dann in ein Diagrammblatt umwandelst, tritt dieser Fehler nicht auf (angenommen wird, das Tabelle "Auswertung" die aktive Tabelle ist bei Codeausführung):

Code:

Sub Generate_Graph()

'******************Variablen deklarieren*******************
Dim i As Integer
Dim k As Integer
Dim chrDia As Chart
'********************Bereich festlegen*********************
i = Range("A9").End(xlDown).Row
k = Cells(8, Columns.Count).End(xlToLeft).Column

MsgBox "Zeile: " & i & " Spalte: " & k

'********************Grafik generieren*********************
Set chrDia = ActiveSheet.ChartObjects.Add(0, 0, 0, 0).Chart
With chrDia
' .ChartType = xlXYScatterLinesNoMarkers
.Parent.Name = "Graph_MOL_PRL"
.PlotArea.Interior.Color = RGB(218, 218, 218)
.SetSourceData Range(Cells(8, 1), Cells(i, k))
.HasTitle = True
.ChartTitle.Text = "XXX"
.HasLegend = True
.Legend.Position = xlBottom
.Axes(xlValue).HasTitle = True
.Axes(xlValue).AxisTitle.Text = "Leistung"
.Axes(xlValue).TickLabels.NumberFormatLocal = "#.##0,00"
.Axes(xlCategory).TickLabels.Orientation = xlUpward
.Axes(xlCategory).HasTitle = True
.Axes(xlCategory).AxisTitle.Text = "ZEIT"
.Location Where:=xlLocationAsNewSheet
End With
Charts(1).Move after:=Worksheets("Auswertung")
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: Diagramm bereich festlegen

Diagramm bereich festlegen

Diagramm bereich festlegen

Diagramm bereich festlegen

Diagramm bereich festlegen - Similar Threads - Diagramm bereich festlegen

Diagramm excel - Achsenoptionen

Diagramm

Vereinfachtes Gantt-Diagramm mit Kalenderwochen und Jahren

Nullen in Diagramm nicht anzeigen

Diagramm als Vollbild?

Diagramm Bereich erweitern

Vertikale Sekundärachse, direkt unter der vertikalen Primärachse