Office: (Office 365) Diagrammdaten dynamisch erzeugen

Hallo fmeyer,

habe deine Datei mal so weit verändert, dass du sehen kannst, was ich unter einer dynamischen Datei verstehe. Auf dem Blatt Daten werden alle Zählerstände fortlaufend eingetragen. Auf dem Blatt Monatsablesung kannst du in der Zeile 1, ganz rechts, neben der Spalte AA, auf das kleine Dreieck drücken, das sichtbar wird, wenn der Zeilenbereich markiert ist. Es öffnet sich eine Liste mit den Jahreszahlen von 2024 bis 2026. Dort klickst du auf das gewünschte Jahr, die dazugehörigen Daten und Diagramme werden angezeigt. Die Jahresliste kannst du auf dem Blatt Parameter beliebig erweitern. Das Programm übernimmt das automatisch. Ebenso werden neue Zeilen auf dem Blatt Daten erkannt und berücksichtigt. Falls du dazu Fragen hast, meldest du dich einfach noch einmal.

 

Hallo @Klaus-Dieter

ich habe meine Datenstruktur jetzt dank wirklich klasse Hilfe von @Onur fertig - stelle sie mal rein.

Wie du das Diagramm aufgebaut hast, ist genau so, wie ich es möchte. Ich habe mir das mal angeschaut, da geht ja viel über den Namensmanager, wie ich gesehen habe. Da hab ich noch keine Erfahrungen drin.

Könntest du mir deine Vorgehensweise mal genauer erklären? Ich würde gerne, dass ich in der Überschriftszeile auch dieses Dropdown habe, das gefällt mir sehr - aber vllt ohne, dass ich das über eine zusätzliche Tabelle "Parameter" definieren müsste. Wie ich das hinkriege, weiß ich. Gibt es ne Möglichkeit, das dieses Dropdownfeld dynamisch aus der Datentabelle erzeugt wird?

 

Hallo Fabian,

die Seite Parameter ist nicht zwingend erforderlich, das mache ich nur wegen der Übersichtlichkeit. Der eigentliche Trick liegt darin, dass diese Liste eine formatierte Tabelle ist, wo der Tabellenbereich mit einem Namen versehen ist, auf den man referenzieren kann. Das hat zur Folge, dass diese Liste verändert oder erweitert werden kann, und diese Veränderungen stehen sofort für die Datenüberprüfung zur Verfügung. (Auch das hat mit dynamisieren zu tun). In diesem Fall kannst du also neue Jahreszahlen hinzufügen, oder alte, die nicht mehr relevant sind, entfernen.

 

Aber es ist

Ja das kenne ich und habe ich auch schonmal gebaut...
Aber gibt es eine Möglichkeit, dass dieses Dropdownfeld aus den Datumwerten erzeugt wird und wenn ja, wie?

Den Rest aus deiner Vorlage müsste ich ja nur kopieren und auf meine o. g. Tabelle versuchen anzupassen und dabei mit dem Namensmanager wieder dazuzulernen :)

 

Hallo,

ich vermute mal, dass du nur das Startjahr in den Tabellen Spalten O:S auswählen willst. Wenn ja, würde ich in deinem Fall die verbundenen Zellen auflösen, in O1 das Startjahr 2023 eintragen, den Text in P1 eintragen P:S selektieren, über Auswahl zentrieren und die Tabellenausgabe mit einer LAMBDA bauen.

Da brauchts dann nur minimale Anpassung. Das ist besser als diesen doch eher aus der Zeit gefallenen Formelwulst.
Man könnte den Summenkram noch mit in die LAMBDA einbauen. Da du aber bisher hartnäckig diese Dinge von Anton und mir ignoriert hast, gibts erst mal nur dies:
Formel in Zelle O2: =AusgabeMaximlwerte(A:A;C:C;O1)
Namensmanager: Name: AusgabeMaximlwerte
Formel:

Code:

=LAMBDA(BereichDatum;BereichAuswertung;AbJahr;LET(xC; SEQUENZ(12;1;1;1);xD;{"";"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"};xE; SEQUENZ(1;4;AbJahr;1);xF;MATRIXERSTELLEN(ZEILEN(xC);SPALTEN(xE);LAMBDA(r;c;MAXWENNS(BereichAuswertung;BereichDatum; ">=" & DATUM(INDEX(xE; c); INDEX(xC; r); 1);BereichDatum; "<"  & DATUM(INDEX(xE; c); INDEX(xC; r)+1; 1))));HSTAPELN(xD;VSTAPELN(xE;xF))))

Mit =AusgabeMaximlwerte(A:A;C:C;O1) kannst du dann jeder Ausgabe entsprechend anpassen. In deinem Fall braucht es nur noch statt C:C einfach für die nächste Tabelle E:E ...

Wenn du nun ein anderes Startjahr für den 4 Jahreszeitraum deiner Auswertung haben möchtest brauchst du nur in O1 das Startjahr zu ändern.

Ins Tabellenblatt einbauen schaffst du sicherlich selbst, so ich dein Ansinnen überhaupt richtig verstanden habe.
Was ich ganz bestimmt nicht mache, ist ein Formel Sammelsurium hier zu hinterlassen. Dafür gibt es die neuen Technologien wie es Luschi bereits angedeutet hatte.
Fast Vergessen: Um #Überlauf! zu verhindern, musst du den spillenden Bereich (Zellen in den Auswertungen) freiräumen.

Gruß Uwe

 

Nicht allzu ernst nehmen:
Statt
{"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"}
geht auch
TEXT(SEQUENZ(12;;30;30);"MMM")
Edit, noch kürzer
TEXT(SEQUENZ(12)*30;"MMM")
Das vermaledeite ""; am Anfang:
{"";"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"}
Bekomme ich auch nur mit Klimmzügen hin:
TEXTTEILEN(TEXTKETTE(TEXT(SEQUENZ(12)*30;"-MMM"));;"-")
Das ist aber immer noch kürzer (59 statt 76 Zeichen).

Aber dies bitte nur als ergänzenden Hinweis sehen.

Gruß Ralf

 

Ich Depp!
VSTAPELN("";TEXT(SEQUENZ(12)*30;"MMM"))
39 Zeichen statt der ursprünglichen 76
{"";"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"}

	A	B
1
2	Jan	Jan
3	Feb	Feb
4	Mrz	Mrz
5	Apr	Apr
6	Mai	Mai
7	Jun	Jun
8	Jul	Jul
9	Aug	Aug
10	Sep	Sep
11	Okt	Okt
12	Nov	Nov
13	Dez	Dez
14	77	40

Zelle	Formel
A1	={"";"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"}
B1	=VSTAPELN("";TEXT(SEQUENZ(12)*30;"MMM"))
A14	=LÄNGE(FORMELTEXT(A1:B1))

 

Hallo Ralf,

na klar kann man das auch so bauen. Wenigstens mal noch einer der sich noch mit so was abgibt. Man kann auch den Rest, der noch unten dran ist gleich mit verwursten. Aber ich vermute es ist "vergebliche Liebesmüh".
VBA ist kaum mehr was Interessantes in den Foren drunter also geht es eben jetzt bei mir mit so was weiter.

Gruß und schönes Wochenende alles Miteinander
Uwe

 

Mein Vorschlag für

VSTAPELN("";TEXT(SEQUENZ(12)*30;"MMM"))

EDIT: Mist, war ich zu langsam...

 

Ja, Helmut.
Ich hatte diese Lösung ja in #22 gepostet und mich selbst mit Recht als Depp bezeichnet, weil ich auch erst später darauf kam.

 

hier mal noch mit den 2 nachfolgenden unten dran:

Code:

=LET(xA; A:A;
    xB;C:C;
    xC; SEQUENZ(12;1;1;1);
    xD;{"";"Jan";"Feb";"Mrz";"Apr";"Mai";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dez"};
    xE; SEQUENZ(1;4;O1;1);
    xF;MATRIXERSTELLEN(
        ZEILEN(xC);
        SPALTEN(xE);
        LAMBDA(r;c;
            MAXWENNS(
                xB;
                xA; ">=" & DATUM(INDEX(xE; c); INDEX(xC; r); 1);
                xA; "<"  & DATUM(INDEX(xE; c); INDEX(xC; r)+1; 1)
            )
        )
    );
xG;HSTAPELN(xD;VSTAPELN(xE;xF));
xH;HSTAPELN("Summe";SUMME(INDEX(xF;;1));SUMME(INDEX(xF;;2));SUMME(INDEX(xF;;3));SUMME(INDEX(xF;;4)));
xI;HSTAPELN("Ø Mon.";INDEX(xH;;2)/12;INDEX(xH;;3)/12;INDEX(xH;;4)/12;INDEX(xH;;5)/12);
VSTAPELN(xG;xH;xI)
)

Die Matrix für xD; zu ändern oder so wie ursprünglich einfach wieder mit Monatszahlen zu haben überlasse ich jeden seiner Vorstellung.

Gruß Uwe