Office: (Office 2010) DO WHILE vs FOR Schleife

Hallo,

Ich habe ein größeres Makro mit einer Laufzeit von ca 5 Stunden.
Dabei wird eine Tabelle mit bis zu 250000 Einträgen durchlaufen und die erste Spalte ist immer befüllt.
Deshalb habe ich es mit

Do While IsEmpty(Worksheets("Berechnung").Cells(COUNTER, 1)) = False
COUNTER=COUNTER+1
loop

probiert.
Bei ca 37000 Durchläufen bekomme ich aber eine Fehlermeldung, Überlauf.
Deshalb benutze ich momentan eine For-Schleife die aber den Nachteil hat
dass ich sie entweder für jeden Durchlauf ändere oder dass Sie halt ab
und zu 50000 leere Zeilen abruft.

Weiss jemand wieso die DO WHILE Schleife nicht funktioniert?
Gibt es Alternativen?

Danke

 

Hi, der Fehler bei den 37000 kommt daher, dass die Variable "Counter" als Integer deklariert ist, wenn du diese als Long deklarierst, sollte das Problem nicht auftauchen.

 

Hallo,

Alternativen dazu, die funktionieren und möglicherweise schneller sind:
Mit SET, DO UNTIL:

Code:

Dim COUNTER As Long
Dim Ws As Worksheet
Set Ws = Worksheets("Berechnung")
COUNTER = 1
Do Until IsEmpty(Ws.Cells(COUNTER,1))
'  ...
  COUNTER = COUNTER +1
Loop

oder mit WITH, FOR und EXIT FOR:

Code:

Dim COUNTER As Long
With Worksheets("Berechnung")
  For COUNTER = 1 To 500000
    If IsEmpty(.Cells(COUNTER,1)) Then Exit For
    '  ...
  Next COUNTER
End With

oder möglicherweise auch mit WITH, FOR EACH und EXIT FOR:

Code:

Dim ZELLE As Range
With Worksheets("Berechnung")
  For Each ZELLE In .Columns("A").Cells
    If IsEmpty(ZELLE) Then Exit For
    '  ...
  Next ZELLE
End With

Anmerkungen:
1) Sobald COUNTER Werte über 32767 enthalten soll, muss sie zwingend als LONG deklariert werden.
2) Ich würde auf alle Fälle die Referenz auf das Worksheet aus der Schleife herausziehen, also vor Schleifenstart 1x auswerten lassen, statt sie in der Schleife 500000x auswerten zu müssen. - Die Variante mit WITH funktioniert natürlich auch mit dem DO UNTIL-LOOP.
3) Bei einer DO...LOOP-Schleife würde ich die DO-UNTIL...LOOP-Version nehmen, damit erspart man sich auch 500000x die Auswertung einer Negation in der einen oder anderen Form.
4) Was dann letztendlich schneller ist, das hängt natürlich entscheidend davon ab, was anstelle des 3-Punkte-Kommentars im Echtprogramm zu stehen kommt.

 

Hi,

zur Ursache deines Überlauf-Fehler hast du ja bereits die Antwort bekommen.

Das "Problem" bei einer For-Schleife besteht darin, dass du zuerst die letzte belegte Zeile ermitteln musst - dann läuft sie unabhängig von einer fest vorgegebenen Zeilenanzahl:

Code:

Sub IfSchleife()
    Dim lngZeile As Long
    Dim lngLetzte As Long
    ' letzte belegte Zeile in Spalte A
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 1)), Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
    For lngZeile = 1 To lngLetzte
        '... hier dein Code was gemacht werden soll
    Next lngZeile
End Sub

Bis später,
Karin