Office: Doppelklick simulieren

ASt. · 24. August 2010

Hallo,

ich habe ein Tabellenblatt erstellt und auf diesem eine Schaltfläche platziert.
Ist es möglich, bei einem Klick auf diese Fläche einen Doppelklick auf eine Zelle (in diesem Fall M9) auszuführen?

Hintergrund ist dieser, dass ich ein Makro habe, welches eine Dateiauswahl ermöglicht sobald man auf die Zelle M9 doppelklickt und diese dann in ein anderes Tabellenblatt läd. Wegen der Übersichtlichkeit möchte, der jenige für den die Datei bestimmt ist, eine Schaltfläche haben und darauf klicken.

Nun bekomme ich das Makro nicht auf den Button umgeschrieben und dachte mir evtl. gibts eine Möglichkeit Exxcel zu sagen "Wenn ich auf den Button klicke führe bitte einen Doppelklick auf Zelle M9 aus!"

evtl. kann jemand das Makro auch auf den Button umschreiben, hab es versucht aber was brauchbares ist leider nicht rumgekommen

hier mal das makro was auf den button gesetzt werden müsste

Code:

Option Explicit

Const cstrSheetName As String = "Input" 'Name der Tabelle nach Import
Const cstrImportName As String = "Gesamtliste Zuschläge" 'Name des zu importierenden Blattes

Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim objWb As Workbook
Dim strFile As String
Dim lngCalc As Long

If Target.Address(0, 0) = "M9" Then 'Zelladresse anpassen
On Error GoTo ErrExit

Cancel = True

GMS

'Dateiauswahl
strFile = Application.GetOpenFilename("Excel Dateien (*.xls; *.xlsx; *.xlsm)," & _
"*.xls; *.xlsx; *.xlsm")

If strFile = CStr(False) Then GoTo ErrExit

Target = ""

'Bereits vorhandene Tabelle löschen
If SheetExist(cstrSheetName) Then ThisWorkbook.Sheets(cstrSheetName).Delete

'Datei öffnen
Set objWb = Workbooks.Open(strFile)

'Tabelle kopieren
objWb.Sheets(cstrImportName).Copy after:=ThisWorkbook.Sheets(1)

'Datei schliessen
objWb.Close False

'Importierte Tabelle benennen
ThisWorkbook.Sheets(2).Name = cstrSheetName

'Dateiname in Zelle eintragen
Target = strFile

replaceRefError

Me.Activate
End If

ErrExit:

GMS True

Set objWb = Nothing
End Sub

Private Function SheetExist(ByVal sheetName As String, Optional Wb As Workbook) As Boolean
Dim wks As Worksheet
On Error GoTo ERRORHANDLER
If Wb Is Nothing Then Set Wb = ThisWorkbook
For Each wks In Wb.Worksheets
If wks.Name = sheetName Then SheetExist = True: Exit Function
Next
ERRORHANDLER:
SheetExist = False
End Function

Private Sub replaceRefError()
Dim objSh As Worksheet, rng As Range

For Each objSh In ThisWorkbook.Worksheets
On Error Resume Next
Set rng = objSh.UsedRange.SpecialCells(xlCellTypeFormulas)
On Error GoTo 0
If Not rng Is Nothing Then
rng.Replace What:="#Ref!", Replacement:="'" & cstrSheetName & "'!", _
LookAt:=xlPart
End If
Set rng = Nothing
Next

End Sub

Public Sub GMS(Optional ByVal Modus As Boolean = False)

Static lngCalc As Long

With Application
.ScreenUpdating = Modus
.EnableEvents = Modus
.DisplayAlerts = Modus
.EnableCancelKey = IIf(Modus, 1, 0)
If Not Modus Then lngCalc = .Calculation
If Modus And lngCalc = 0 Then lngCalc = -4105
.Calculation = IIf(Modus, lngCalc, -4135)
.Cursor = IIf(Modus, -4143, 2)

End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wäre auch an der Doppelklick-Methode interessiert.

Gruß
ASt.

:)

ransi · 25. August 2010

HAllo

"Wenn ich auf den Button klicke führe bitte einen Doppelklick auf Zelle M9 aus!"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Versuch mal so:
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub CommandButton1_Click()
Worksheet_BeforeDoubleClick Range("M9"), True
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Address = "$M$9" Then MsgBox "Mach was"
End Sub

ransi

ASt. · 26. August 2010

perfekt

Danke!

Office: Doppelklick simulieren

Doppelklick simulieren

Doppelklick simulieren

Doppelklick simulieren - Similar Threads - Doppelklick simulieren

Doppelklick in Tabelle auf Smartphone

VBA Textbox macht was sie will

Text Formatverlust nach Doppelklick

Formular mit bestimmten Datensatz durch Doppelklick öffnen

Makro durch Doppelklick auf Zelle starten

zwei Klicks bei Anmeldung

VBA - Excel Tabelle in PPT durch Doppelklick in Excel öffnen